[AspJpeg] Difficoltà per la trasparenza

**SoloWiFi** · 27-10-2017, 17:40

Ho un problema nel creare un fondo trasparente per un PNG.

Spiego a parole nel miglior modo possibile. Non credo ci sia bisogno di listati.

Il lavoro parte da delle immagini JPG di diverse dimensioni. Le devo standardizzare ad una dimensione precisa. Es. 800x600
Quindi ridimensiono mantenendo l'aspetto ratio. Questo non mi porta sempre alla dimensione che desidero.
Per ovviare a ciò creo prima una immagine vuota a 800x600 a fondo bianco
Successivamente sovrascrivo l'immagine JPG ridimensionata centrandola.
Salvo in PNG e mi trovo l'immagine corretta ma ho i bordi bianchi. ... ovvio!

Vorrei creare l'immagine di base trasparente e non bianca ma non riesco a farlo.
In pratica mi serve una 800x600 trasparente dove poi sovrascrivo centrata l'immagine JPG.

Dovrei lavorare con i livelli Alpha ma non ci ho capito granchè.

**Vincent.Zeno** · 27-10-2017, 18:15

già consultato il manuale?
http://www.aspjpeg.com/manual_10.html#10_3

**SoloWiFi** · 27-10-2017, 21:32

Si, certo ma non mi ha funzionato.
Domani cercherò di capire meglio con quel l'esempio del cerchio e del quadrato.
Non è molto chiaro.

**Vincent.Zeno** · 27-10-2017, 23:27

da quel che ho capito dovresti fare così:
crei l'immagine jpg 780x580
la trasformi in png
la incolli su una base trasparente png da 800x600

**SoloWiFi** · 28-10-2017, 12:35

Niente da fare!
Non ci riesco!

**Vincent.Zeno** · 28-10-2017, 12:49

ma la procedura ti pare logica? procedi per passi

ora non ho tempo di verificare e testare ma il concetto mi pare abbastanza semplice, dovresti riuscire

**SoloWiFi** · 28-10-2017, 12:59

il problema è che devo partire da un jpg
più tardi o lunedi metto qualche riga per commentarla

**Vincent.Zeno** · 28-10-2017, 13:02

quindi la prima difficoltà e trasformare il jpg in png?

**Vincent.Zeno** · 28-10-2017, 13:16

se è questa, lo script di base risolve (ho verificato):

codice:

Set Jpeg = Server.CreateObject("Persits.Jpeg")
Jpeg.Open Server.MapPath("immaginejpg.jpg")

' Output as PNG
Jpeg.PNGOutput = True

' Save
Jpeg.Save Server.MapPath("immaginepng.png")

**SoloWiFi** · 28-10-2017, 16:39

FATTO!!!!
... non è stata una passeggiata. Nel manuale non si capisce una mazza!

codice:

<%
Path="/public/"
BaseW=800
BaseH=600

' creo i 3 oggetti che mi serviranno
Set JpegImg = Server.CreateObject("Persits.Jpeg") ' conterrà l'immagine JPG
Set JpegAlpha = Server.CreateObject("Persits.Jpeg") ' conterrà il livello di trasparenza
Set JpegFinal = Server.CreateObject("Persits.Jpeg") ' conterrà l'immagine con trasparenza

JpegImg.Open Server.MapPath(Path&"test.jpg") ' carico l'immagine che devo lavorare
JpegFinal.New BaseW, BaseH ' creo struttura per immagine finale

' inserisco l'immagine al centro delal struttura finale
JpegFinal.Canvas.DrawImage (JpegFinal.Width - JpegImg.Width)/2, (JpegFinal.Height - JpegImg.Height)/2, JpegImg

JpegAlpha.New BaseW, BaseH, &HFFFFFF ' creo il livello per la trasparenza a fondo bianco "Importante bianco"

' Calcolo le coordinate per l'area che non dovrà essere trasparente (al centro) 
W1=(BaseW - JpegImg.Width)/2
H1=(BaseH - JpegImg.Height)/2
W2=W1+JpegImg.Width
H2=H1+JpegImg.Height

JpegAlpha.Canvas.DrawBar W1, H1, W2, H2 ' creo un rettangolo con le coordinate 
JpegAlpha.ToGrayscale (0) ' applico scala di grigio
JpegFinal.SetAlpha JpegAlpha, true ' applico la trasparenza nell'area fuori dal rettangolo (false la applica all'interno)

JpegFinal.PNGOutput = True ' prepara per il salvataggio PNG

JpegFinal.Save Server.MapPath(Path&"out.png") ' salva su disco 
%>

<body bgcolor="#99CC66">
<img src="out.png">
</body>

Discussione: [AspJpeg] Difficoltà per la trasparenza

Strumenti discussione

Ricerca discussione

Visualizza

[AspJpeg] Difficoltà per la trasparenza

Permessi di invio