invio mail tramite form

[alasque]

Ciao a tutti,

ho un form nel quale raccolgo dei dati e poi mando una mail a me ed una alla persona che si è iscritta.
il tutto è gestito da questa porzione di script che non funziona più in seguito al cambio di SMTP:

CODICE:

<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->


<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<%
'============Linkbruttocane su specifiche MSDN================
'* il corpo finale del messaggio contiene tutti i campi *
'* inseriti nella pagina html, in pratica puoi mettere *
'* tutti i campi che ti servono nel modulo di invio senza *
'* fare altre configurazioni aggiuntive. *
'================================================= ============


DIM corpoMessaggio, numeroCampi, invioA, invioAC, invioDa, nomeDominio, indirizzoIp, modulo, browserSistemaOperativo


'* voce da modificare con il proprio indirizzo email

invioA = "xxxxxxxxxxx@gmail.com"
invioAC = Request.Form("email")


'* voce da modificare con un indirizzo email che funga da mittente:
'* in caso di errore riceverete notifica a questo indirizzo un MAILER-DAEMON
'* dato che cdosys supporta questa notifica

invioDa = "xxxxxxxxxxx@gmail.com"


'------------fine modifiche necessarie------------------


nomeDominio = Request.ServerVariables("HTTP_HOST")
indirizzoIp = Request.ServerVariables("REMOTE_ADDR")
modulo = Request.ServerVariables("HTTP_REFERER")
browserSistemaOperativo = Request.ServerVariables("HTTP_USER_AGENT")


'*rilevo i campi del form



FOR numeroCampi = 1 TO (Request.Form.Count() - 1)
IF NOT Request.Form(numeroCampi) = "" THEN
corpoMessaggio = corpoMessaggio & vbCrLf & Request.Form.Key(numeroCampi) & " = " & Trim(Request.Form(numeroCampi))
END IF
NEXT


'* creo gli oggetti cdosys sul server e li gestisco

DIM iMsg, Flds, iConf


Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
Flds(cdoSendUsingMethod) = cdoSendUsingPort
Flds(cdoSMTPServer) = "smtp.gmail.com"
Flds(cdoSMTPServerPort) = 25
Flds(cdoSMTPAuthenticate) = cdoAnonymous ' 0
Flds.Update
With iMsg
Set .Configuration = iConf
.To = invioA
.CC = invioAC
.From = Request.Form("email")
.Sender = invioDa
.Subject = "Richiesta News da " & nomeDominio
.TextBody = "Ciao " & Request.Form("nome")

ora che voglio inviare tramite smtp.gmail.com non funziona più.
potete aiutarmi? grazie

[Vincent.Zeno]

non funziona più in seguito al cambio di SMTP

ora che voglio inviare gmail non funziona più.

ovvero? cosa hai cambiato?

cos'è che vuoi inviare?

sii più preciso.

[alasque]

ho aggiornato la richiesta

[alasque]

ho cambiato smtp.aruba.it in smtp.gmail.com

[Vincent.Zeno]

***togli dal primo post il nome reale delle tua casella

Set Flds = objConfig.Fields


        Flds("http://schemas.microsoft.com/cdo/configuration/urlgetlatestversion") = True


        Flds("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        
        'questo qui sotto non usarlo, serve se gestisci anche il server di posta
        'Flds("http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory") = "c:\inetpub\mailroot\pickup"


        Flds("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"


        Flds("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465


        Flds("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1


        Flds("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1


        Flds("http://schemas.microsoft.com/cdo/configuration/sendusername") = "nomecasella@gmail.com" '<-- tua email


        Flds("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "password" '<-- tua password


        Flds.Update

[alasque]

quel post non me lo fa più modificare, non capisco perchè ed ora non riesco a togliere i miei riferimenti

[alasque]

mi dice:

Microsoft VBScript runtime error '800a01a8'
Object required: 'objConfig'
/News_m_invio.asp, line 48

[Vincent.Zeno]

mi dice:

Microsoft VBScript runtime error '800a01a8'
Object required: 'objConfig'
/News_m_invio.asp, line 48

riporta tutto il codice, non posso tirare ad indovinare

per la rimozione faccio io la segnalazione

[alasque]

<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->


<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<%
'============Linkbruttocane su specifiche MSDN================
'* il corpo finale del messaggio contiene tutti i campi *
'* inseriti nella pagina html, in pratica puoi mettere *
'* tutti i campi che ti servono nel modulo di invio senza *
'* fare altre configurazioni aggiuntive. *
'================================================= ============


DIM corpoMessaggio, numeroCampi, invioA, invioAC, invioDa, nomeDominio, indirizzoIp, modulo, browserSistemaOperativo


'* voce da modificare con il proprio indirizzo email

invioA = "xxx@gmail.com"
invioAC = Request.Form("email")


'* voce da modificare con un indirizzo email che funga da mittente:
'* in caso di errore riceverete notifica a questo indirizzo un MAILER-DAEMON
'* dato che cdosys supporta questa notifica

invioDa = "xxx@gmail.com"


'------------fine modifiche necessarie------------------


nomeDominio = Request.ServerVariables("HTTP_HOST")
indirizzoIp = Request.ServerVariables("REMOTE_ADDR")
modulo = Request.ServerVariables("HTTP_REFERER")
browserSistemaOperativo = Request.ServerVariables("HTTP_USER_AGENT")


'*rilevo i campi del form



FOR numeroCampi = 1 TO (Request.Form.Count() - 1)
IF NOT Request.Form(numeroCampi) = "" THEN
corpoMessaggio = corpoMessaggio & vbCrLf & Request.Form.Key(numeroCampi) & " = " & Trim(Request.Form(numeroCampi))
END IF
NEXT


'* creo gli oggetti cdosys sul server e li gestisco

DIM iMsg, Flds, iConf


Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = objConfig.Fields




Flds("http://schemas.microsoft.com/cdo/configuration/urlgetlatestversion") = True




Flds("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'questo qui sotto non usarlo, serve se gestisci anche il server di posta
'Flds("http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory") = "c:\inetpub\mailroot\pickup"




Flds("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.gmail.com"




Flds("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 465




Flds("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = 1




Flds("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1




Flds("http://schemas.microsoft.com/cdo/configuration/sendusername") = "xxx@gmail.com" '<-- tua email




Flds("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "xxx" '<-- tua password




Flds.Update

With iMsg
Set .Configuration = iConf
.To = invioA
.CC = invioAC
.From = Request.Form("email")
.Sender = invioDa
.Subject = "Richiesta News da " & nomeDominio
.TextBody = "Ciao " &""
.Send
End With
%>


<script>
document.location.replace('news_grazie.asp');
</script>

[Vincent.Zeno]

sostituisci

Set Flds = objConfig.Fields
con
Set Flds = iConf.Fields

mi pare non ci sia altro

RICORDA di usare sempre il tag CODE per postare codice sul forum, grazie