[VB6] Aprire la finestra di dialogo "Sfoglia cartelle"

[nlazza87]

vorrei sapere come posso fare per far comparire la finestra "sfoglia cartelle" cliccando sopra un bottone all'interno di un programma vb. Cioè ho un campo testo nel quale voglio andare a memorizzare il percorso di una foto, in seguito questo percorso lo devo poi salvare sul DB.
Grazie

[oregon]

Utilizza il controllo CommonDialog

[MItaly]

Se non sbaglio le CommonDialog per VB6 non includono la finestra "Sfoglia cartelle"; se non sbaglio comunque dovrebbe esserci qualche API in shell32.dll... prova a dare un'occhiata sulla MSDN.

[oregon]

Giusto ... mi era sfuggito il fatto che ci si riferisse alle cartelle ... la API e' la SHBrowseForFolder

Un esempio, tratto da www.allapi.net

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: http://www.allapi.net/
    'KPDTeam@Allapi.net
    Dim iNull As Integer, lpIDList As Long, lResult As Long
    Dim sPath As String, udtBI As BrowseInfo

    With udtBI
        'Set the owner window
        .hWndOwner = Me.hWnd
        'lstrcat appends the two strings and returns the memory address
        .lpszTitle = lstrcat("C:\", "")
        'Return only if the user selected a directory
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With

    'Show the 'Browse for folder' dialog
    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        'Get the path from the IDList
        SHGetPathFromIDList lpIDList, sPath
        'free the block of memory
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then
            sPath = Left$(sPath, iNull - 1)
        End If
    End If

    MsgBox sPath
End Sub

[wallrider]

perfetto

però in qualche programma ho visto che veniva usata una finestra simile ma in cui compariva anche il pulsante "crea cartella"...

Si può fare?

[wallrider]

trovata scusate

http://forum.masterdrive.it/archive/...p/t-10980.html