Uso di CDonts, dov'è errore?

**Edipo** · 15-10-2006, 23:34

Ciao a tutti.
Sto utilizzando questo script per l'invio di un'email.
Cosa ha che non va?
Non restituisce alcun errore e non recapita alcuna email.
Ho fatto le prove del caso ovvero cambiando l'email del destinatario, con diversi indirizzi di diferrenti provider, ed è da settimane che tento di riuscirci ma senza risultato.

Ecco il codice:

Dim objMail
Set objMail = CreateObject("CDONTS.NewMail")

objMail.From = "info@miosito.it"

objMail.To = "miaemail@mail.it"

objMail.Subject = "Prova invio

objMail.BodyFormat = 0 ' 0 Testo; 1 HTML
objMail.MailFormat = 0 ' 0 Testo; 1 HTML

' Valore di priorità (opzionale)
objMail.Importance = 0

' Indirizzo per risposte (opzionale)
objMail.Value("Reply-To") = "miaemail@mail.it"

' Corpo del messaggio
objMail.Body = "ciao"

objMail.Send()

Set objMail = Nothing

Non vedo errori, mi aiutereste?

Grazie a quanti risponderanno

**michele.santoro** · 15-10-2006, 23:54

Intanto manca la terminazione alla riga:
objMail.Subject = "Prova invio
che deve essere
objMail.Subject = "Prova invio"
e poi sei sicuro che sul tuo server sia installato CDONTS e non CDOSYS o altro?
Lo script funziona perfettamente, ergo ...

**Edipo** · 16-10-2006, 09:43

Si ho notato l'errore di terminazione, distrazione di trascrizione

Bhè per il server, sono su un win2000s nn saprei dirti, non credi che se il componente non fosse supportato dovrebbe restituire un qualche tipo di errore?
Come faccio a sapere se lo supporta?
Grazie in anticipo.

**michele.santoro** · 16-10-2006, 12:51

Usa questo script:

codice:

<html>
<head>
<title>Server Component Checker</title>
</head>
<body>
<%

	Dim comList(54)
		comList(0) = Array( "AB Mailer","ABMailer.Mailman" )
		comList(1) = Array( "ABC Upload","ABCUpload4.XForm" )
		comList(2) = Array( "ActiveFile","ActiveFile.Post" )
		comList(3) = Array( "ActiveX Data Object","ADODB.Connection" )
		comList(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
		comList(5) = Array( "ASP HTTP","AspHTTP.Conn" )
		comList(6) = Array( "ASP Image","AspImage.Image" )
		comList(7) = Array( "ASP Mail","SMTPsvg.Mailer" )
		comList(8) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
		comList(9) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
		comList(10) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
		comList(11) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
		comList(12) = Array( "ASP Tear","SOFTWING.ASPtear" )
		comList(13) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
		comList(14) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
		comList(15) = Array( "ASPEmail","Persits.MailSender" )
		comList(16) = Array( "ASPSoft NT Object","ASPSoft.NT" )
		comList(17) = Array( "ASPSoft Upload","ASPSoft.Upload" )
		comList(18) = Array( "CDONTS","CDONTS.NewMail" )
		comList(19) = Array( "CDOSYS","CDO.Message" )
		comList(20) = Array( "Chestysoft Image","csImageFile.Manage" )
		comList(21) = Array( "Chestysoft Upload","csASPUpload.Process" )
		comList(22) = Array( "Chili!Mail","CDONTS.NewMail" )
		comList(23) = Array( "Dimac JMail","JMail.Message" )
		comList(24) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
		comList(25) = Array( "dkQMail","dkQmail.Qmail" )
		comList(26) = Array( "Dundas Mailer","Dundas.Mailer" )
		comList(27) = Array( "Dundas Upload","Dundas.Upload.2" )
		comList(28) = Array( "Dynu Encrypt","Dynu.Encrypt" )
		comList(29) = Array( "Dynu HTTP","Dynu.HTTP" )
		comList(30) = Array( "Dynu Mail","Dynu.Email" )
		comList(31) = Array( "Dynu Upload","Dynu.Upload" )
		comList(32) = Array( "Dynu WhoIs","Dynu.Whois" )
		comList(33) = Array( "Easy Mail","EasyMail.SMTP.5" )
		comList(34) = Array( "Emailtoolbox","ArclabEmailToolBox.Mailer" )
		comList(35) = Array( "File System Object","Scripting.FileSystemObject" )
		comList(36) = Array( "Geocel.Mailer","GeoCel" )
		comList(37) = Array( "IISMail","iismail.iismail.1" )
		comList(38) = Array( "JMail","Jmail.smtpmail" )
		comList(39) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
		comList(40) = Array( "Last Mod","LastMod.FileObj" )
		comList(41) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
		comList(42) = Array( "Persits ASP JPEG","Persits.Jpeg" )
		comList(43) = Array( "Persits ASPEmail","Persits.MailSender" )
		comList(44) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
		comList(45) = Array( "Persits File Upload","Persits.Upload.1" )
		comList(46) = Array( "SmartMail","aspSmartMail.SmartMail" )
		comList(47) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
		comList(48) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
		comList(49) = Array( "Image Size", "ImgSize.Check" )
		comList(50) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
		comList(51) = Array( "Grafici Excel", "OWC.Chart" )
		comList(52) = Array( "ADODB Stream", "ADODB.Stream" )
		comList(53) = Array( "VSEmail1.0","VSEmail.SMTPSendMail" )
		comList(54) = Array( "VSEmail2.0","VSEmail.SMTPSendMailEx" )


	Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=""3"" cellspacing=""0"" border=""1"" bordercolor=""#000000"" align=""center"" width=""300"">" & vbNewLine
		strTxt = strTxt & "<tr><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">COMPONENTE</font></td><td align=""center"" bgcolor=""#3399ff""><font face=""tahoma"" size=""3"" color=""#000000"">STATUS</font></td></tr>"
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=""150""><font face=""tahoma"" size=""2"" color=""#000000"">" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=""left""><font face=""tahoma"" size=""2"" color=""#000000"">[  "
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<font face=""tahoma"" size=""2"" color=""blue"">Installato</font>"
				Avail = Avail + 1
			Else
				strTxt = strTxt & "Non Installato</font>"
			End If
			strTxt = strTxt & "  <font face=""tahoma"" size=""2"" color=""#000000"">]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font face=""tahoma"" size=""2"" color=""blue"">" & Avail & "</font><font face=""tahoma"" size=""2"" color=""#000000""> su "
	strTxt = strTxt & UBound( comList ) + 1 & " componenti installati.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

<p align="center">
	<font face="Tahoma" size="2">Server Component Checker
Direttamente dal forum di html.it</font>
</p>
</body>
</html>

Mettilo nella root del sito e lancialo

**Edipo** · 16-10-2006, 20:02

CDONTS [ Installato ]
CDOSYS [ Installato ]

Qui dice tutto ok, cosa devo dedurne? Chiamo un esorcista?

**michele.santoro** · 16-10-2006, 20:25

Credo proprio che ti ci voglia un esorcista, dal momento che io ho riprovato lo script ed invia perfettamente l'e-mail.

**Edipo** · 16-10-2006, 21:02

Vabè
grazie mille santoro

alla prossima

Discussione: Uso di CDonts, dov'è errore?

Strumenti discussione

Ricerca discussione

Visualizza

Uso di CDonts, dov'è errore?

Permessi di invio