loadMovie fa di Testa sua!!!

[StefanoV]

Salve, ennesimo problema!

ecco la funzione:

caricaImg = function(img:String, Id:Number)
{
	this["wB"+Id].createEmptyMovieClip("Limg", this["wB"+Id].getNextHighestDepth());
	this["wB"+Id].Limg._visible = false;
	loadMovie(img,this["wB"+Id].Limg);
	//this["wB"+Id].Limg._x = -63.5;
	//this["wB"+Id].Limg._y = -88.5;
	//this["wB"+Id].Limg._width = 129;
	//this["wB"+Id].Limg._height = 87;
	trace(this["wB"+Id].Limg.getBytesTotal());
	
}

ho commentato il codice della funzione perkè ci sono 2 problemi:

Il codice dovrebbe creare un MC Vuoto in this["wB"+Id] chiamato Limg - OK
Nasconde Limg - NON VA (se invece di visible uso alpha invece lo fa!)
carica in Limg la foto, ed ecco il primo problema:
- getBytesTotal di Limg da 0 sia prima che dopo il loadMovie, anche se l'img la importa e si vede!

Poi secondo problema(codice commentato):
- i parametri _width, ed _height....li ignora....(mentre se uso _xscale e _yscale funziona)

se questa funzione la metto nel movieclip che uso ora (cioè this["wB"+Id]), e la carico da qui con: this["wB"+Id].caricaImg(parametri).... e come se la funzione non esiste...non la trova!

[and80]

loadmovie è un metodo "distruttivo", sginifica che ogni volta che viene richiamato, le impostazioni iniziali date al clip su cui avviene il caricamento, vengono resettate (apparte un paio che rimangono, _alpha, _xscale e _yscale)

se vuoi impostare variazioni particolari, di posizione, dimensione ecc... al clip, allora devi aspettare che l'immagine sia completamente caricata, per farlo devi utilizzare necessariamente un preload che te lo consenta

da Flash MX 2004 a Flash 8 (AS2) abbiamo la classe MovieClipLoader, che ci consente di fare tali verifiche grazie ad una serie di metodi dedicati,
sul web e su questo stesso forum trovi tanti riferimenti a questa classe

[StefanoV]

Grazie Mille del suggerimento and80,
cmq ho risolto stamattina proprio con quella Classe...

resta solo un problema, anche al completamento del caricamento width ed height non vanno...

o meglio... impostando _width ed _height le immagini non compaiono!

ti posto il codice dell'intera funzione:

caricaImg = function(img:String, Id:Number)
{
	var mcL:MovieClipLoader = new MovieClipLoader();
	var mmm:Object = new Object();
	
	scroller.contentMain["wB"+Id].prel_img._visible = false;
	
	mcL.loadClip(img,scroller.contentMain["wB"+Id].Limg);
	
mmm.onLoadStart = function() {
	scroller.contentMain["wB"+Id].prel_img._visible = true;
	scroller.contentMain["wB"+Id].Limg._visible = false;
	scroller.contentMain["wB"+Id].prel_text.text = "";
}
	
mmm.onLoadProgress = function() {
	tot = scroller.contentMain["wB"+Id].Limg.getBytesTotal();
	car = scroller.contentMain["wB"+Id].Limg.getBytesLoaded();
	
	perc = int(car/tot * 100);
	
	var my_t:Object = new Tween(scroller.contentMain["wB"+Id].prel_img, "_width", Strong.easeOut, scroller.contentMain["wB"+Id].prel_img._width, (129 * perc) / 100, 0.5, true);
	scroller.contentMain["wB"+Id].prel_text.text = "LOADING IMAGE... "+perc+"%";
	}

mmm.onLoadComplete = function() {
	scroller.contentMain["wB"+Id].Limg._width = 129;
	scroller.contentMain["wB"+Id].Limg._height = 87;
	scroller.contentMain["wB"+Id].Limg._x = -63.5;
	scroller.contentMain["wB"+Id].Limg._y = -88.5;
	scroller.contentMain["wB"+Id].prel_text.text = "";
	scroller.contentMain["wB"+Id].prel_img._visible = false;
	scroller.contentMain["wB"+Id].Limg._visible = true;
}

mcL.addListener(mmm);
	
}

[and80]

l'ultimo metodo, quello di caricamento completato, è onLoadInit e non onLoadComplete, sostituisci e vedrai che va

[StefanoV]

Che Stupido!
Non avendo letto nessuna guida alla classe, pensavo che Init era l'inizio, poi venisse start e poi complete!

Ora Ho Corretto e Funziona Perfettamente!

Grazie 1000 and80!