Tracciamento di una linea da un quadratino ad un altro

[cristal]

Salve,
suppondo di avere 2 quadratini (ad esempio istanziati come movie clip: Q1 e Q2), come potrei fare, dopo aver premuto un pulsante, per fare in modo che una linea parta da un quadratino e vada a collegarsi con l'altro quadratino?

bisogna tener conto che i quadratini sono mobili e possono muoversi nello stage.

grazie mille.

[§elva]

cosi va bene?
http://img526.imageshack.us/my.php?i....swf&width=320
ti spiego un po' come ho fatto

_root.startTrace = false;  //indica se bisogna tracciare la linea.. 
_root.Q1.onPress = function() {   //per rendere i quadrattini draggabili...
    this.startDrag(true);
};
_root.Q2.onPress = function() {
    this.startDrag(true);
};
_root.Q1.onRelease = function() {
    this.stopDrag();
};
_root.Q2.onRelease = function() {
    this.stopDrag();
};
_root.traccia.onRelease = function() {   //azione eseguita al release del pulsante instanziato 
    _root.startTrace = true;             //"traccia".. setta a true la variabile per permettere    
};                                                   //di tracciare la linea

_root.onEnterFrame = function() {       //traccia la linea in continuazione
    if (startTrace) {
        _root.createEmptyMovieClip("linea", 0);
        with (_root.linea) {
            lineStyle(1, 0x000000, 100);
            moveTo(_root.Q1._x, _root.Q1._y);
            lineTo(_root.Q2._x, _root.Q2._y);
        }
    }
}; 

[cristal]

mitico!!! si proprio questo!

sto cercando di riprodurlo, ma non riesco. i quadratini sono pulsanti o movie clip?

[§elva]

puoi usare tranquillamente dei movie clip..
ricordati di istanziarli però!

se vuoi puoi mandarmi la tua mail in messaggio privato e te lo spedisco!..

ora però vado a nanna!

[cristal]

si li ho istanziati, ma ho un problema e cioè che al rilascio del mouse il quadratino continua a seguire la freccia.


se puoi mandarmelo, ti ho mandato la mail in mp. davvero mille grazie!

continuerò qui la discussione per lo sviluppo di questo filmato che voglio fare.

[cristal]

Ciao, ho provato ad editare il file, ma come ho cambiato il quadratino in un pallino e vado a premere sul pallino, purtroppo al rilascio del mouse il pallino rimane attaccato.


l'ho messo qui:
http://www.oltrecalcio.com/prove2/

grazie ancora

[Anderoli]

hai usato startDrag con il parametro true nella voce lockcenter, quindi trascini il clip dal suo centro, solo che il cerchio blu non è al centro del clip.

centralo e tutto si risolverà

[§elva]

se lo centri al rilascio si bloccherà come ha detto anderoli, e vedrai anche la linea che congiunge i due movieclip proprio al loro centro

[cristal]

ah ho capito, quindi devo mettere i pallini nella stessa identica posizione dei quadratini. ora va!

Senti, ora vorrei fare un passo avanti:
per fare in modo che una pallina (o il quadratino ) possa muoversi solo lungo un asse verticale di lunghezza finita e non in posizioni generiche dello spazio, dovrei impostare che il parametro _y associato alla pallina durante lo StartDrag sia compreso in un range di valori?

grazie ancora :master:

[§elva]

http://img441.imageshack.us/my.php?i....swf&width=320
io ho modificato lo script in questo modo:

startTrace = false;
down = false;                        //indica se il pulsante sinistro viene premuto
ymin = 25;                            //y minima che può raggiungere Q2  
ymax = 170;                         //y massima
_root.Q1.onPress = function() {
    this.startDrag(true);
};
_root.Q2.onPress = function() {
    _root.down = true;        //il pulsante viene premuto
};
_root.Q2.onEnterFrame = function() {
    if (_root.down) {                       //se il pulsante è premuto
        this._y = _root._ymouse;   //setta la proprietà y di Q2 uguale all y del mouse
        if (this._y<=ymin) {          //limita lo scorrimento del quadrato
            this._y = ymin;
        }
        if (this._y>=ymax) {
            this._y = ymax;
        }
    }
};
_root.Q1.onRelease = function() {
    this.stopDrag();
};
_root.Q2.onRelease = function() {     
    _root.down = false;                      //il pulsante non è premuto
};
_root.Q2.onReleaseOutside = function() {
    _root.down = false;
};
_root.traccia.onRelease = function() {
    _root.startTrace = true;
};
_root.onEnterFrame = function() {
    if (startTrace) {
        _root.createEmptyMovieClip("linea", 0);
        with (_root.linea) {
            lineStyle(1, 0x000000, 100);
            moveTo(_root.Q1._x, _root.Q1._y);
            lineTo(_root.Q2._x, _root.Q2._y);
        }
    }
};