[VB6] Lampeggiamento di punti

[melandro]

(VB6)

ciao a tutti
Con questo posso disegnare un numero di punti a piacere su una picture
e con con tasto destro li cancello.
----------
Private Sub Form_Load()
Picture1.DrawWidth = 10
Picture1.ForeColor = vbRed
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Button = 1 Then
Picture1.PSet (X, Y)

End If
End Sub
------------

questo va bene. Ma io volevo che i punti disegnati lampeggiassero.

Ho provato con

Private Sub Timer1_Timer()
picture1.pset.visible=Not picture1.pset.visible
End Sub
ma commetto errore.

qual'é la giusta sintassi?

grazie
melandro

[MItaly]

Mi spieghi questo cosa dovrebbe significare?

picture1.pset.visible=Not picture1.pset.visible

VVoVe: Un punto non è un oggetto!
Comunque ti basta sovrascrivere il punto disegnato precedentemente con uno del colore di sfondo, disegnato sempre con PSet (consiglio: non serve modificare la proprietare ForeColor del form per cambiare il colore del punto, basta passare il colore a PSet dopo le coordinate, ad esempio Me.PSet (10,10) vbRed).

[melandro]

HO capito di dover sostituire (alternativamente) il colore di sfondo.
Questo deve comunque avvenire sotto il timer?
Altrimenti non c'é lampeggiamento.

[MItaly]

Certo.

[melandro]

siamo al punto di partenza
Non trovo quale formula usare sotto il timer (che non sia visible=not visible)
Come faccio a far alternare i colori (punto, sfondo)

[MItaly]

Option Explicit
Private Type BlinkingPoint
    x As Single
    y As Single
    blinkOn As Boolean
End Type
Private Points() As BlinkingPoint

Private Sub Form_Load()
    Picture1.DrawWidth = 10
    Picture1.ForeColor = vbRed
    ReDim Points(0)
    Timer1.Enabled = False
End Sub

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
    Dim newPt As BlinkingPoint
    newPt.x = x
    newPt.y = y
    newPt.blinkOn = True
    Picture1.PSet (x, y), Picture1.ForeColor
    If Timer1.Enabled Then
        ReDim Preserve Points(UBound(Points) + 1)
    End If
    Points(UBound(Points)) = newPt
    Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
    Dim counter As Long
    For counter = LBound(Points) To UBound(Points)
        Picture1.PSet (Points(counter).x, Points(counter).y), IIf(Points(counter).blinkOn, Picture1.BackColor, Picture1.ForeColor)
        Points(counter).blinkOn = Not Points(counter).blinkOn
    Next
End Sub

[melandro]

Ti ringrazio, MyItaly.
Era quello che intendevo e cercavo di ottenere.
Era veramente un po' seria la faccenda,
non tanto semplice.


Grazie infinite.

melandro

[MItaly]

Be', dai, non è che fosse così tanto difficile!
Ciao, alla prossima!