i-tunes gallery - problemi ad adattarlo...

[paololosco]

ciao.

Ho problemi nell'utilizzare lo script (bellissimo peraltro) di Julius "i-tunes gallery" o meglio...

farlo funzionare, ok... adattarlo al mio stage... ok...

la mia prima esigenza (alla quale sono riuscito facilmente a fare fronte) era quella di, mantenendo il bel movimento di distorsione, portare l'immagine in primo piano ad essere grande quanto tutto lo stage.

Però, di conseguenza, avrei bisogno di una thumb gallery che mi porta in primo piano l'immagine cliccata, mantenendo il movimento... spero di essermi spiegato... comunque posto tutto il codice (le modifiche che sono riuscito a fare finora sono anche le uniche cose di cui ho capito qualcosa...)

e ringrazio anticipatamente chiunque mi dia qualche dritta...

_root.aaa.swapDepths(3002);
_root.info.swapDepths(3000);
import flash.display.*;
import flash.geom.*;
var root:MovieClip = this;
var loadedAll:Boolean;
var distance:Number;
var maxSlide:Number = 100;
var deleteMinDistance:Number = 0;
var deleteMaxDistance:Number = 500;
var doubleClickRegister:Number = 500;
var frontCDWidth:Number = 704;
var frontCDHeight:Number = 382;
var shelveCDHeight:Number = 165;
var shelveCDWidth:Number = 120;
var shelveCDSpacing:Number = 50;
var centerDistance:Number = 200;
var albumEase:Number = 5;
var angle:Number = 8;
var fadePoint:Number = 680;
var fadeDist:Number = 50;
var current:Number = 3;
var centerX:Number = 490;
var centerY:Number = 190;
var clickDelay:Number = 750;
var scrollBarStart:Number = 20;
var scrollerDelay:Number = 150;
var scrollBarStop:Number = scrollBar.scroller._width+31;
var reflectionSpace:Number = 2;
var reflectionAlpha:Number = 50;
var reflectionRotation:Number = 90;
var reflectionFocalPointRatio:Number = 0.3;
var reflectionFillType:String = "linear";
var reflectionSpreadMethod:String = "pad";
var reflectionInterpolationMethod:String = "RGB";
var infostruc:Array = [];
var reflectionColors:Array = [0x000000, 0x000000];
var reflectionAlphas:Array = [100, 0];
var reflectionRatios:Array = [0, 0xFF];
var myMO:Object = {};
var myKO:Object = {};
var xmlData:XML = new XML();
Mouse.addListener(myMO);
Key.addListener(myKO);
MovieClip.prototype.setSides = function(x1:Number, y1:Number, x2:Number, y2:Number, x3:Number, y3:Number, x4:Number, y4:Number):Void  {
	this.px1 = x1;
	this.py1 = y1;
	this.px2 = x2;
	this.py2 = y2;
	this.px3 = x3;
	this.py3 = y3;
	this.px4 = x4;
	this.py4 = y4;
};
MovieClip.prototype.DistortImage = function(ptexture, vseg:Number, hseg:Number) {
	if (ptexture instanceof BitmapData) {
		this.texture = ptexture;
	} else if (ptexture instanceof MovieClip) {
		this.texture = new BitmapData(ptexture._width, ptexture._height);
		this.texture.draw(ptexture);
	}
	this._vseg = vseg || 0;
	this._hseg = hseg || 0;
	this._w = this.texture.width;
	this._h = this.texture.height;
	this._aMcs = [];
	this._p = [];
	this._tri = [];
	this.init();
};
MovieClip.prototype.setTransform = function(x0:Number, y0:Number, x1:Number, y1:Number, x2:Number, y2:Number, x3:Number, y3:Number):Void  {
	this.w = this._w;
	this.h = this._h;
	this.dx30 = x3-x0;
	this.dy30 = y3-y0;
	this.dx21 = x2-x1;
	this.dy21 = y2-y1;
	l = this._p.length;
	while (--l>-1) {
		this.point = this._p[l];
		var gx = (this.point.x-this._xMin)/this.w;
		var gy = (this.point.y-this._yMin)/this.h;
		var bx = x0+gy*(this.dx30);
		var by = y0+gy*(this.dy30);
		this.point.sx = bx+gx*((x1+gy*(this.dx21))-bx);
		this.point.sy = by+gx*((y1+gy*(this.dy21))-by);
	}
	this.render();
};
MovieClip.prototype.init = function(Void):Void  {
	this._p = [];
	this._tri = [];
	this.w2 = this._w/2;
	this.h2 = this._h/2;
	this._xMin = this._yMin=0;
	this._xMax = this._w;
	this._yMax = this._h;
	this._hsLen = this._w/(this._hseg+1);
	this._vsLen = this._h/(this._vseg+1);
	for (ix=0; ix<this._hseg+2; ix++) {
		for (iy=0; iy<this._vseg+2; iy++) {
			x = ix*this._hsLen;
			y = iy*this._vsLen;
			this._p.push({x:x, y:y, sx:x, sy:y});
		}
	}
	for (ix=0; ix<this._vseg+1; ix++) {
		for (iy=0; iy<this._hseg+1; iy++) {
			this.p0 = this._p[iy+ix*(this._hseg+2)];
			this.p1 = this._p[iy+ix*(this._hseg+2)+1];
			this.p2 = this._p[iy+(ix+1)*(this._hseg+2)];
			this.addTriangle(this.p0, this.p1, this.p2);
			this.p0 = this._p[iy+(ix+1)*(this._vseg+2)+1];
			this.p1 = this._p[iy+(ix+1)*(this._vseg+2)];
			this.p2 = this._p[iy+ix*(this._vseg+2)+1];
			this.addTriangle(this.p0, this.p1, this.p2);
		}
	}
	this.render();
};
MovieClip.prototype.addTriangle = function(p0:Object, p1:Object, p2:Object):Void  {
	this.tMat = {};
	this.u0 = p0.x;
	this.v0 = p0.y;
	this.u1 = p1.x;
	this.v1 = p1.y;
	this.u2 = p2.x;
	this.v2 = p2.y;
	this.tMat.tx = -this.v0*(this._w/(this.v1-this.v0));
	this.tMat.ty = -this.u0*(this._h/(this.u2-this.u0));
	this.tMat.a = this.tMat.d=0;
	this.tMat.b = this._h/(this.u2-this.u0);
	this.tMat.c = this._w/(this.v1-this.v0);
	this._tri.push([p0, p1, p2, this.tMat]);
};
MovieClip.prototype.render = function(Void):Void  {
	this.ih = 1/this._h;
	this.iw = 1/this._w;
	var c:MovieClip = this;
	c.clear();
	this.sM = {};
	this.tM = {};
	var l:Number = this._tri.length;
	while (--l>-1) {
		a = this._tri[l];
		this.p0 = a[0];
		this.p1 = a[1];
		this.p2 = a[2];
		this.tM = a[3];
		this.sM.a = (this.p1.sx-(this.x0=this.p0.sx))*this.iw;
		this.sM.b = (this.p1.sy-(this.y0=this.p0.sy))*this.iw;
		this.sM.c = (this.p2.sx-this.x0)*this.ih;
		this.sM.d = (this.p2.sy-this.y0)*this.ih;
		this.sM.tx = this.x0;
		this.sM.ty = this.y0;
		this.sM = concat(this.sM, this.tM);
		c.beginBitmapFill(this.texture, this.sM, false, false);
		c.moveTo(this.x0, this.y0);
		c.lineTo(this.p1.sx, this.p1.sy);
		c.lineTo(this.p2.sx, this.p2.sy);
		c.endFill();
	}
};

.. continua

[paololosco]

continua...

function init(Void):Void {
	for (var i in infostruc) {
		loader.gradient_mc.removeMovieClip();
		loader.attachMovie("default", "art", 1);
		this["_bmd"+i] = new BitmapData(loader._width, loader._height);
		this["_ref"+i] = new BitmapData(loader._width, loader._height);
		this["_bmd"+i].draw(loader);
		var mc:MovieClip = loader.createEmptyMovieClip("gradient_mc", loader.getNextHighestDepth());
		matrix = new Matrix();
		matrix.createGradientBox(loader._width, loader._height, reflectionRotation/180*Math.PI, 0, 0);
		mc.beginGradientFill(reflectionFillType, reflectionColors, reflectionAlphas, reflectionRatios, matrix, reflectionSpreadMethod, reflectionInterpolationMethod, reflectionFocalPointRatio);
		mc.moveTo(0, 0);
		mc.lineTo(0, loader._height);
		mc.lineTo(loader._width, loader._height);
		mc.lineTo(loader._width, 0);
		mc.lineTo(0, 0);
		mc.endFill();
		this["_ref"+i].draw(loader);
	}
	for (var i:Number = count=0; count<Stage.width-(centerDistance*2); count += shelveCDSpacing, i++) {
		var cArt:MovieClip = this.createEmptyMovieClip("art"+this.getNextHighestDepth(), this.getNextHighestDepth());
		var rArt:MovieClip = this.createEmptyMovieClip("reflection"+(this.getNextHighestDepth()-1), this.getNextHighestDepth());
		rArt.id = cArt.id=rArt.cid=cArt.cid=Number(i)+1;
		cArt.DistortImage(this["_bmd"+cArt.id]);
		controlTheObject(cArt);
		rArt.DistortImage(this["_ref"+cArt.id]);
		controlTheObject(rArt);
		tmask = mask.duplicateMovieClip("_mask"+cArt.id, this.getNextHighestDepth(), {_x:mask._x, _y:mask._y});
		rmask = mask.duplicateMovieClip("_rmask"+cArt.id, this.getNextHighestDepth(), {_x:mask._x, _y:mask._y});
		cArt.setMask(tmask);
		rArt.setMask(rmask);
	}
	distance = Number(i);
	mask.removeMovieClip();
	fscreen.swapDepths(1102);
	loader.removeMovieClip();
	loadNext();
	updateInfo();
}
function concat(m1, m2):Object {
	var mat = {};
	mat.a = m1.c*m2.b;
	mat.b = m1.d*m2.b;
	mat.c = m1.a*m2.c;
	mat.d = m1.b*m2.c;
	mat.tx = m1.a*m2.tx+m1.c*m2.ty+m1.tx;
	mat.ty = m1.b*m2.tx+m1.d*m2.ty+m1.ty;
	return mat;
}
function updateInfo():Void {
	info = infostruc[current-1].info;
	author = infostruc[current-1].auth;
	displayAlternArt(infostruc[current-1].art, artDisplay._width-1, artDisplay._height-1);
	scrollBar.scroller._x = scrollBarStart+((current-1)/(infostruc.length-1)*(scrollBar._width-scrollBarStop));
}
function validateOk(target:MovieClip):Boolean {
	return Math.abs(Math.min(Math.max((target._x-target.x)/albumEase, -maxSlide), maxSlide)) == maxSlide;
}
function controlTheObject(mc):Void {
	if (mc._name.indexOf("reflection") == -1) {
		mc.onPress = function():Void  {
			if (getTimer()-this.pressTime<=doubleClickRegister && this.pressTime) {
				/// Things to come...
			}
			this.pressTime = getTimer();
			current = this.cid+1;
			updateInfo();
		};
	}
	mc.onEnterFrame = function():Void  {
		if (Math.abs(this._x-this.x)>1) {
			if (this._name.indexOf("reflection") == -1) {
				this._y = centerY;
				if (this._x>=centerX+centerDistance) {
					this.swapDepths(Stage.width-this._x);
					this.setSides(-(shelveCDWidth/2), -(shelveCDHeight/2)+((Math.sin(angle*Math.PI/180)*frontCDWidth)), -(shelveCDWidth/2)+shelveCDWidth, -(shelveCDHeight/2), -(shelveCDWidth/2)+shelveCDWidth, shelveCDHeight/2, -(shelveCDWidth/2), (shelveCDHeight/2)-((Math.sin(angle*Math.PI/180)*frontCDWidth)));
				} else if (this._x<=centerX-centerDistance) {
					this.swapDepths(this._x);
					this.setSides(-(shelveCDWidth/2), -(shelveCDHeight/2), -(shelveCDWidth/2)+shelveCDWidth, -(shelveCDHeight/2)+(Math.sin(angle*Math.PI/180)*frontCDWidth), -(shelveCDWidth/2)+shelveCDWidth, (shelveCDHeight/2)-(Math.sin(angle*Math.PI/180)*frontCDWidth), -(shelveCDWidth/2), shelveCDHeight/2);
				} else if (this._x>centerX-centerDistance && Math.floor(this._x)<centerX && !validateOk(this)) {
					this.swapDepths(1002);
					var sum:Number = shelveCDWidth+((this._x-(centerX-centerDistance))/centerDistance*(frontCDWidth-shelveCDWidth));
					var sum2:Number = angle-((this._x-(centerX-centerDistance))/centerDistance*angle);
					var sum3:Number = shelveCDHeight+((this._x-(centerX-centerDistance))/centerDistance*(frontCDHeight-shelveCDHeight));
					this.setSides(-(sum/2), -(sum3/2), -(sum/2)+sum, -(sum3/2)+((Math.sin(sum2*Math.PI/180)*frontCDWidth)), -(sum/2)+sum, (sum3/2)-((Math.sin(sum2*Math.PI/180)*frontCDWidth)), -(sum/2), sum3/2);
				} else if (this._x<centerX+centerDistance && Math.ceil(this._x)>centerX && !validateOk(this)) {
					this.swapDepths(1003);
					var sum:Number = shelveCDWidth+(((centerX+centerDistance)-this._x)/centerDistance*(frontCDWidth-shelveCDWidth));
					var sum2:Number = angle-(((centerX+centerDistance)-this._x)/centerDistance*angle);
					var sum3:Number = shelveCDHeight+(((centerX+centerDistance)-this._x)/centerDistance*(frontCDHeight-shelveCDHeight));
					this.setSides(-(sum/2), -(sum3/2)+((Math.sin(sum2*Math.PI/180)*frontCDWidth)), -(sum/2)+sum, -(sum3/2), -(sum/2)+sum, sum3/2, -(sum/2), (sum3/2)-((Math.sin(sum2*Math.PI/180)*frontCDWidth)));
				} else if (!validateOk(this)) {
					this.setSides(-(frontCDWidth/2), -(frontCDHeight/2), -(frontCDWidth/2)+frontCDWidth, -(frontCDHeight/2), -(frontCDWidth/2)+frontCDWidth, frontCDHeight/2, -(frontCDWidth/2), frontCDHeight/2);
				}
			} else {
				this._yscale = -100;
				if (this._x>=centerX+centerDistance) {
					this._y = centerY+shelveCDHeight+reflectionSpace;
					this.swapDepths(-(Stage.width-this._x));
					this.setSides(-(shelveCDWidth/2), -(shelveCDHeight/2)+(Math.sin(angle*Math.PI/180)*frontCDWidth), -(shelveCDWidth/2)+shelveCDWidth, -(shelveCDHeight/2), -(shelveCDWidth/2)+shelveCDWidth, shelveCDHeight/2, -(shelveCDWidth/2), (shelveCDHeight/2)+((Math.sin(angle*Math.PI/180)*frontCDWidth)));
				} else if (this._x<=centerX-centerDistance) {
					this._y = centerY+shelveCDHeight+reflectionSpace;
					this.swapDepths(-(this._x+333));
					this.setSides(-(shelveCDWidth/2), -(shelveCDHeight/2), -(shelveCDWidth/2)+shelveCDWidth, -(shelveCDHeight/2)+((Math.sin(angle*Math.PI/180)*frontCDWidth)), -(shelveCDWidth/2)+shelveCDWidth, (shelveCDHeight/2)+(Math.sin(angle*Math.PI/180)*frontCDWidth), -(shelveCDWidth/2), shelveCDHeight/2);
				} else if (this._x>centerX-centerDistance && this._x<centerX && !validateOk(this)) {
					this.swapDepths(1004);
					var sum:Number = shelveCDWidth+((this._x-(centerX-centerDistance))/centerDistance*(frontCDWidth-shelveCDWidth));
					var sum2:Number = angle-((this._x-(centerX-centerDistance))/centerDistance*angle);
					var sum3:Number = shelveCDHeight+((this._x-(centerX-centerDistance))/centerDistance*(frontCDHeight-shelveCDHeight));
					this._y = centerY+sum3+reflectionSpace;
					this.setSides(-(sum/2), -(sum3/2), -(sum/2)+sum, -(sum3/2)+((Math.sin(sum2*Math.PI/180)*frontCDWidth)), -(sum/2)+sum, (sum3/2)+((Math.sin(sum2*Math.PI/180)*frontCDWidth)), -(sum/2), sum3/2);
				} else if (this._x<centerX+centerDistance && this._x>centerX && !validateOk(this)) {
					this.swapDepths(1005);
					var sum:Number = shelveCDWidth+(((centerX+centerDistance)-this._x)/centerDistance*(frontCDWidth-shelveCDWidth));
					var sum2:Number = angle-(((centerX+centerDistance)-this._x)/centerDistance*angle);
					var sum3:Number = shelveCDHeight+(((centerX+centerDistance)-this._x)/centerDistance*(frontCDHeight-shelveCDHeight));
					this.setSides(-(sum/2), -(sum3/2)+((Math.sin(sum2*Math.PI/180)*frontCDWidth)), -(sum/2)+sum, -(sum3/2), -(sum/2)+sum, sum3/2, -(sum/2), (sum3/2)+((Math.sin(sum2*Math.PI/180)*frontCDWidth)));
					this._y = centerY+sum3+reflectionSpace;
				} else if (!validateOk(this)) {
					this._y = centerY+frontCDHeight+reflectionSpace;
					this.setSides(-(frontCDWidth/2), -(frontCDHeight/2), -(frontCDWidth/2)+frontCDWidth, -(frontCDHeight/2), -(frontCDWidth/2)+frontCDWidth, frontCDHeight/2, -(frontCDWidth/2), frontCDHeight/2);
				}
			}
		}
		this.DistortImage(this._name.indexOf("reflection")>-1 ? this._parent["_ref"+this.cid] : this._parent["_bmd"+this.cid]);
		if (this._x<deleteMinDistance && this._parent["_ref"+(this.cid+distance)]) {
			this.cid += distance;
			this._x = deleteMaxDistance;
			controlTheObject(this);
		}
		if (this._x>deleteMaxDistance && this._parent["_ref"+(this.cid-distance)]) {
			this.cid -= distance;
			this._x = deleteMinDistance;
			controlTheObject(this);
		}
		if (this.cid+1>current) {
			this.x = (centerX+((this.cid+1-current)*shelveCDSpacing))+centerDistance;
		} else if (this.cid+1<current) {
			this.x = (centerX+((this.cid+1-current)*shelveCDSpacing))-centerDistance;
		} else {
			this.x = centerX+((this.cid+1-current)*shelveCDSpacing);
		}
		this._x -= Math.min(Math.max((this._x-this.x)/albumEase, -maxSlide), maxSlide);
		if (this._x<fadeDist) {
			this._alpha = (this._x/fadeDist*100)-(this._name.indexOf("reflection")>-1 ? reflectionAlpha : 0);
		} else if (this._x>fadePoint-fadeDist) {
			this._alpha = ((fadePoint-this._x)/fadeDist*100)-(this._name.indexOf("reflection")>-1 ? reflectionAlpha : 0);
		} else {
			this._alpha = 100-(this._name.indexOf("reflection")>-1 ? reflectionAlpha : 0);
		}
		this.setTransform(this.px1, this.py1, this.px2, this.py2, this.px3, this.py3, this.px4, this.py4);
	};

... continua e finisce...

[paololosco]

...finisce...

}
function next():Void {
	if (current<infostruc.length) {
		current += 1;
	}
	updateInfo();
}
function previous():Void {
	if (current>1) {
		current -= 1;
	}
	updateInfo();
}
function displayAlternArt(art, width:Number, height:Number):Void {
	artDisplay.attachMovie(art, "artwork", 1);
	artDisplay.artwork._width = width;
	artDisplay.artwork._height = height;
}
function loadNext(dir:String):Void {
	if (!loadedAll) {
		var num:Number = current-1;
		while (infostruc[num].loaded && num<infostruc.length) {
			num++;
		}
		if (num>=infostruc.length) {
			var num:Number = current-1;
			while (infostruc[num].loaded && num>0) {
				num--;
			}
			if (num<=0) {
				
				loadedAll = true;
			}
		}
		var newLoad:MovieClip = this.createEmptyMovieClip("artLoad"+num, this.getNextHighestDepth());
		newLoad._alpha = 0;
		var mc:Object = {};
		mc.number = num;
		var artLoader:MovieClipLoader = new MovieClipLoader();
		artLoader.addListener(mc);
		artLoader.loadClip("./"+infostruc[num].art, newLoad);
		mc.onLoadError = function(target:MovieClip) {
			loadNext();
		};
		mc.onLoadInit = function(target:MovieClip) {
			root["_bmd"+this.number] = new BitmapData(target._width, target._height);
			root["_ref"+this.number] = new BitmapData(target._width, target._height);
			root["_bmd"+this.number].draw(target);
			var mc:MovieClip = target.createEmptyMovieClip("gradient_mc", target.getNextHighestDepth());
			matrix = new Matrix();
			matrix.createGradientBox(target._width, target._height, reflectionRotation/180*Math.PI, 0, 0);
			mc.beginGradientFill(reflectionFillType, reflectionColors, reflectionAlphas, reflectionRatios, matrix, reflectionSpreadMethod, reflectionInterpolationMethod, reflectionFocalPointRatio);
			mc.moveTo(0, 0);
			mc.lineTo(0, target._height);
			mc.lineTo(target._width, target._height);
			mc.lineTo(target._width, 0);
			mc.lineTo(0, 0);
			mc.endFill();
			root["_ref"+this.number].draw(target);
			infostruc[this.number].loaded = true;
			target.removeMovieClip();
			loadNext();
		};
	}
}
xmlData.onLoad = function(success:Boolean):Void  {
	if (success) {
		for (var i:Number = -1; this.childNodes[0].childNodes[++i]; ) {
			var cNode:XMLNode = this.childNodes[0].childNodes[i].childNodes;
			infostruc.push({art:cNode[0].childNodes, info:unescape(cNode[1].childNodes), auth:unescape(cNode[2].childNodes), loaded:false});
		}
		loadStat = "";
		init();
	} else {
		loadStat = "There was an error loading that data, sorry.";
	}
};
myMO.onMouseWheel = function(delta:Number):Void  {
	if (delta>0) {
		next();
	} else if (delta<=0) {
		previous();
	}
};
myKO.onKeyDown = function():Void  {
	if (Key.isDown(Key.RIGHT)) {
		next();
	} else if (Key.isDown(Key.LEFT)) {
		previous();
	}
};
scrollBar.scroller.onPress = function():Void  {
	dist = this._parent._xmouse-this._x;
	this.onMouseMove = function():Void  {
		tmp = 1+Math.ceil(((this._parent._xmouse-dist)-scrollBarStart)/(scrollBar._width-scrollBarStop)*(infostruc.length-1));
		if (tmp>infostruc.length) {
			tmp = infostruc.length;
		}
		if (tmp<1) {
			tmp = 1;
		}
		current = tmp;
		updateInfo();
	};
};
scrollBar.scroller.onRelease = scrollBar.scroller.onReleaseOutside=function ():Void {
	stopDrag();
	delete this.onMouseMove;
};
scrollBar.left.onPress = function():Void  {
	previous();
	shifter = setInterval(previous, scrollerDelay);
};
scrollBar.right.onPress = function():Void  {
	next();
	shifter = setInterval(next, scrollerDelay);
};
scrollBar.onMouseUp = function():Void  {
	clearInterval(shifter);
};
scrollBar.onMouseDown = function():Void  {
	if (this.hitTest(_xmouse, _ymouse, true) && !this.left.hitTest(_xmouse, _ymouse, true) && !this.right.hitTest(_xmouse, _ymouse, true)) {
		if (this._xmouse<this.scroller._x) {
			previous();
			shifter = setInterval(previous, clickDelay);
		}
		if (this._xmouse>this.scroller._x+this.scroller._width) {
			next();
			shifter = setInterval(next, clickDelay);
		}
	}
};
fscreen.onPress = function():Void  {
	fscommand("fullscreen", !(this._currentframe-1));
	this.gotoAndStop(!(this._currentframe-1)+1);
};
xmlData.ignoreWhite = true;
xmlData.load(fileXml);
this.createEmptyMovieClip("loader", this.getNextHighestDepth());
mask._alpha = 0;
scrollBar.scroller._y = 0;
scrollBar.swapDepths(1101);

[paololosco]

up... nessuno?

[and80]

penso che sarà molto difficile che qualcuno si prenda la briga di leggere quel codice, senza riferimenti precisi
il thread scritto in questo modo è inutile, meglio che metti un riferimento a chi voglia vedere il codice direttamente dalla sorgente da cui hai scaricato la galleria