Resize di un'immagine importata FLASH 8

[ibernet]

'sera a tutti,

ho importato un'immagine esterna con questo codice:
this.foto01.loadMovie("http://www.xxxxxxxxx.com/fotohome/foto01.jpg");

avrei la necessità che quando si carica l'immagine nello stage sia di dimensioni 400x300 a prescindere dalle dimensioni dell'immagine presente nella cartella esterna

Qualcuno mi può essere d'aiuto?

grazie a tutti

Buona serata

[crescenzo]

beh ti serve un preload della foto e poi la ridimensioni
quindi cerca nel forum moviecliploader ..... trovi tante cose

[ibernet]

grazie mille.. ora cerco

[crescenzo]

ecco una cosa del genere

//preload
var mcListener:Object = new Object();
mcListener.onLoadStart = function(target_mc:MovieClip) {
    // rendo invisibile l'mc che carica l'immagine
    target_mc._alpha = 0;
    // traccio l'avvenuto richiamo dell'evento
    
};
mcListener.onLoadProgress = function(target_mc:MovieClip, bytesLoaded:Number, bytesTotal:Number) {
    // creo una variabile che rappresenta il valore percentuale del caricamento
    var percentual:Number = Math.floor((bytesLoaded/bytesTotal)*100);
    trace("Caricato "+percentual+"% dell'immagine");
};
// attivo il codice dell'evento che avverte dell'avvenuto caricamento
mcListener.onLoadComplete = function(target_mc:MovieClip) {
    trace("Attivato Evento Complete, l'immagine ha terminato il caricamento");
};
// attivo l'ultimo metodo di caricamento, quello che permette di manipolare l'immagine con le sue dimensioni e proprietà effettive
mcListener.onLoadInit = function(target_mc:MovieClip) {
    // traccio le dimensioni reali del clip in cui ho appena caricato l'immagine
    trace("Larghezza: "+target_mc._width);
    trace("Altezza: "+target_mc._height);
    newW = 400;
    newH = 300;
    target_mc._width = newW;
    target_mc._height = newH;
    target_mc._alpha = 100;        
        
        
                
        
};
// attivo il metodo di errore, utile nel caso che l'immagine non esista
mcListener.onLoadError = function(target_mc:MovieClip, errorCode:String) {
    trace("Errore, l'immagine non è stata trovata, file sconosciuto");
};
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(mcListener);
////fine preload


//richiamo il preload
mcLoader.loadClip(percorsofoto, istanzacontenitore); 

[ibernet]

Caspita grazie.. sei stato molto dettagliato..

Ho provato e funziona perfettamente il resize però ho perso il controllo delle proprietà impostate all'immagine utilizzando le interpolazioni..

Si può utilizzare lo stesso codice con qualche accorgimento per avere solo il ridimensionamento? o bisogna fare tutto tramite actionscript?

L'effetto che ho dato all'immagine è un ingresso alpha 0 e dopo 10 frame arriva a alpha 100
Così via per altre 8 immagini che si sovrappongono..

[crescenzo]

nn ho capito...sorry :master:

se vuoi dare un effetto alpha alla foto che carichi nellla funzione onlonadinit usi le tween e ci metti un effetto alhpa graduale...

[crescenzo]

ecco cosi.....quando la foto è caricata viene visualizzata con un effetto fade

Originariamente inviato da crescenzo
ecco una cosa del genere

//importo le classi tween
import mx.transitions.Tween;
import mx.transitions.easing.Regular;
//preload
var mcListener:Object = new Object();
mcListener.onLoadStart = function(target_mc:MovieClip) {
    // rendo invisibile l'mc che carica l'immagine
    target_mc._alpha = 0;
    // traccio l'avvenuto richiamo dell'evento
    
};
mcListener.onLoadProgress = function(target_mc:MovieClip, bytesLoaded:Number, bytesTotal:Number) {
    // creo una variabile che rappresenta il valore percentuale del caricamento
    var percentual:Number = Math.floor((bytesLoaded/bytesTotal)*100);
    trace("Caricato "+percentual+"% dell'immagine");
};
// attivo il codice dell'evento che avverte dell'avvenuto caricamento
mcListener.onLoadComplete = function(target_mc:MovieClip) {
    trace("Attivato Evento Complete, l'immagine ha terminato il caricamento");
};
// attivo l'ultimo metodo di caricamento, quello che permette di manipolare l'immagine con le sue dimensioni e proprietà effettive
mcListener.onLoadInit = function(target_mc:MovieClip) {
    // traccio le dimensioni reali del clip in cui ho appena caricato l'immagine
    trace("Larghezza: "+target_mc._width);
    trace("Altezza: "+target_mc._height);
    newW = 400;
    newH = 300;
    target_mc._width = newW;
    target_mc._height = newH;
    //applico la tween alla foto
    var ___TWEENFOTOGRANDE___:Tween = new Tween(target_mc, "_alpha", Regular.easeOut,0,100, 10, false);
        
        
};
// attivo il metodo di errore, utile nel caso che l'immagine non esista
mcListener.onLoadError = function(target_mc:MovieClip, errorCode:String) {
    trace("Errore, l'immagine non è stata trovata, file sconosciuto");
};
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(mcListener);
////fine preload


//richiamo il preload
mcLoader.loadClip(percorsofoto, istanzacontenitore); 

[ibernet]

ritiro il mio ultimo post..

con la modifica che mi hai riportato funziona alla grande!

grazie mille, a buon rendere!

[crescenzo]

di niente figurati..