passaggio comandi tra classi

[mr.smile]

Non riesco a capire con in AS3 si faccia a fare questa cosa:
ho una classe main con una funzione "update"
in questa classe costruisco un oggetto della funzione "menu"
posso all'interno di menu chiamare la funzione "update"?
Credo proprio di sì, ma come?

Vin ringrazio...

[Kaneda81]

Il procedimento più pulito per fare quello che chiedi è far dispacciare a menù un evento, che intercetti dalla main e all'handler chiami la funzione update.
In alternativa dovresti fare la funzione update nella main pubblica, e poi ricavarti una referenza della main dal menù (var main:MovieClip = this.parent as MovieClip) e chiamare main.update(); ma è un modo osceno.

Ti faccio l'esempio del primo metodo che ti dicevo io.

Document Class

package
{
    import flash.display.*;
    import flash.events.*;
    
    public class Main extends MovieClip
    {
        private var menu:MyMenu;
        
        public function Main()
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event = null):void
        {
            if (e) removeEventListener(Event.ADDED_TO_STAGE, init);
            
            menu = new MyMenu();
            addChild(menu);
            menu.addEventListener(MyMenu.UPDATE, update);
        }
        
        private function update(e:Event = null):void
        {
            trace("update!");
        }
    }
} 

Classe associata al menu

package
{
    import flash.display.*;
    import flash.events.*;
    
    public class MyMenu extends MovieClip
    {
        public static const UPDATE:String = "update";
        
        public function MyMenu()
        {
            addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            
            bottone.addEventListener(MouseEvent.CLICK, onClick);
        }
        
               // al click del bottone la classe dispaccia l'evento.
        private function onClick(e:MouseEvent):void
        {
            dispatchEvent(new Event(MyMenu.UPDATE));
        }
    }
} 

Praticamente quando viene cliccato il bottone (nome istanza bottone) dentro a menù, menù dispaccia l'evento che viene intercettato nella main, e viene così chiamata la funzione update (alla quale dai il null di default come parametro, così la puoi chiamare anche in maniera diretta nel corso della tua applicazione).

[mr.smile]

Grazie Kaneda81, interessante come soluzione!
Per quale ragione però usare gli init? Per purezza della soluzione oppure è strutturale... mi sfugge!

Grazie comunque per l'interessante risposta!

[Kaneda81]

Per essere sicuro che il tuo oggetto abbia un valido riferimento allo stage.
Sopratutto quando la tua classe è associata ad una clip in libreria è praticamente obbligatorio mettere un listener all'ADDED_TO_STAGE, in caso contrario otterresti degli errori.

[jjletho]

ancora più semplice è rendere la funzione pubblica

public function update():void 
        {           
  trace("update!");     
        } 

poi per passre la main al menu è molto più semplice

menu = new MyMenu(this); 

nel menu converti il this

private var myMain:*;
...
public function MyMenu(_main)
myMain=_main; 

e così hai la main dentro la classe menu senza fare parent e lazzi vari

poi puoi tranquillamente chiamare la funzione pubblica, da menu e dalle altre classe se ti serve

myMain.update(); 

[Kaneda81]

Per essere più semplice lo è, ma non è molto corretto dal punto di vista OOP (dove è raro dichiarare funzioni pubbliche, a meno di lavorare anche con le interfacce).
Sarebbe più semplice anche dichiarare direttamente le variabili come public, così ci puoi accedere come ti pare ... però i getter & setter li hanno inventati apposta.

Cmq, by the way, nel tuo esempio la variabile myMain non ha bisogno di essere tipizzata universalmente, dato che sarà sempre di tipo MovieClip (nel caso lavori con Flash). Volendo puoi anche non passarlo il main come paramentro, dato che telo ricavi con un this.parent as MovieClip.

[jjletho]

a livello teorico hai perfettamente ragione ma basta analizzare il codice di qualche classe tween, tweenmax, caurina ecc.. per rendersi conto di quanto siano comode le funzioni pubbliche.

Fra l'altro in questo esempio la main la ricavi certamente da da un this.parent ma se tu dovessi passare un bottone istanziato nella main come lo ricavi? è molto più semplice passarlo per poi poterlo utilizzare.

In vecchio post che nn trovo spiegavo ad un utente come utilizzare il dispatch di eventi personalizzati, sistema che io uso abbondantemente con le classi loader per caricare xml o file esterni a catena. Ma chi usa flash da tempo come me (versione 3) sa perfettamente che il puro OOP a volte va scavalcato utilizzando sistemi meno formali ma più funzionali.

poi ognuno si gestisce a suo modo e quasto è chiaro

[Kaneda81]

Assolutamente si
E' chiaro anche che dipende dalle esigenze, sotto deadline stringenti e alla 230esima modifica che ti chiede il cliente mandi a putt... i canoni OOP e vai di metodi pubblici, basta che funziona e basta che ti levi di torno quel lavoro.
Unica cosa è sempre meglio sottolineare le best practice, a maggior ragione a fronte di una richiesta di spiegazione o aiuto, così uno sceglie la strada che vuole seguire con cognizione di causa.

Happy coding

[jjletho]

hai ragione

sicuro che una buona classe scritta correttamente è sicuramente riutilizzabile molto meglio di una scritta tanto per far funzionare

c'è anche da dire che importando la classe si aprono ancora altre possibilità