[VB6] Errore Filter

[perseo74]

Buongiorno avrei il seguente quesito, programmando in vb6 io devo eseguire un filter, il codice che utilizzo è il seguente:

rsCognomeA.Filter = "[Cognome Acquirente]='" & txtCognomeAcquirente.Text & "'"

il problema è il seguente, quando faccio un filter utilizzando una stringa(contenuta in una variabile o nel textbox indicato), che contiene il carattere " ' " cioè un apostrofo, mi viene generato un errore sulla stringa sql di query perchè non riconosce il simbolo come entità della stringa ma come separatore della stringa sql, volevo chiedervi come potevo risolvere questo problema, grazie mille.Per esempio quando il textbox ha valore:

txtCognomeAcquirente.Text ="LAMA"

non mi genera nessun errore mentre quando il valore del textbox ha valore:

txtCognomeAcquirente.Text ="L'AMA"

cioè la stringa contiene il carattere ' mi genera errore potete aiutarmi Grazie

[LeleFT]

VB --> Forum "Visual Basic e .NET Framework".

Sposto.

PS: Linguaggio e versione vanno obbligatoriamente indicati nel titolo.


Ciao.

[gibra]

Devi sempre raddoppiare gli apici, per evitare che il linguaggio SQL vada in confusione.

invece di scrivere
rsCognomeA.Filter = "[Cognome Acquirente]='" & txtCognomeAcquirente.Text & "'"

devi scrivere

dim sCondizione As String 
sCondizione = Replace(txtCognomeAcquirente.Text, "'", "''")
rsCognomeA.Filter = "[Cognome Acquirente]='" & sCondizione & "'"

Ancora meglio, puoi usare una funzione che fa tutto il lavoro per te, e magari esegua anche i dovuti controlli (che adesso non fai!), e poi ti restituisca la stringa già formattata:

Public Function Apici2( Byval psStringa As String) As String
    Dim s As String
    s = Trim$(psStringa)
    If s = "" Then
        ''''MsgBox "Errore. Stringa vuota!",vbCritical
        Exit Function
    End If

    s = Replace(s, "'", "''")
    s = Chr$(39) & s & Chr$(39)

    Apici2 = s

End Function

per poi richiamarla così:

rsCognomeA.Filter = "[Cognome Acquirente]=" & Apici2(txtCognomeAcquirente.Text)

Anzi, a dire il vero sarebbe da usare così:

Dim sCondizione As String
sCondizione = Apici2(txtCognomeAcquirente.Text)
If sCondizione = "" Then
    MsgBox "Errore. Stringa vuota!", vbCritical
Else
    rsCognomeA.Filter = "[Cognome Acquirente]=" & sCondizione
End If

In questo modo, se la stringa è vuota intercetti l'errore PRIMA di usare il metodo Filter