leggere un file .ini

[effervescenza]

come si fa? che referenze ci vogliono? aiutatemi xchè è tutta la mattina che cerco - invano -...

[allejo]

Ma che problema hai???????
Spiegati meglio!

[effervescenza]

in pratica devo leggere un file .ini da codice vb. Come devo fare a livello di codice? posso usare le API? Che funzioni ho a disposizione? Devo aggiungere determinate librerie nelle references?

[xegallo]

dal momento che un file ini è simile a un file txt
puoi aprirlo sequenziale

[pasaran]

esiste un'api apposta. Appena ho la possibilita' te la invio.

Permette di accedere sia in lettura che in scrittura direttamente all'elemento che ti interessa senza fare di volta in volta il ciclo di lettura del file .ini.

[sebamix]

Esempio tratto da AllAPI:

Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Private Sub Form_Load()
    'KPD-Team 1999
    'URL: http://www.allapi.net/
    'E-Mail: KPDTeam@Allapi.net
    Dim Ret As String, NC As Long
    'Write the setting to the file (c:\test.ini) under
    '   Project1 -> Keyname
    WritePrivateProfileString App.Title, "KeyName", "This is the value", "c:\test.ini"
    'Create a buffer
    Ret = String(255, 0)
    'Retrieve the string
    NC = GetPrivateProfileString(App.Title, "KeyName", "Default", Ret, 255, "C:\test.ini")
    'NC is the number of characters copied to the buffer
    If NC <> 0 Then Ret = Left$(Ret, NC)
    'Show our string
    MsgBox Ret
    'Delete the file
    Kill "c:\test.ini"
End Sub

[xegallo]

Originariamente inviato da pasaran
esiste un'api apposta. Appena ho la possibilita' te la invio.

Permette di accedere sia in lettura che in scrittura direttamente all'elemento che ti interessa senza fare di volta in volta il ciclo di lettura del file .ini.

Declare Function WritePrivateProfileString Lib "kernel32" _
    Alias "WritePrivateProfileStringA" (ByVal lpApplicationName _
    As String, ByVal lpKeyName As Any, ByVal lpString As Any, _
    ByVal lpFileName As String) As Long
Declare Function GetPrivateProfileString Lib "kernel32" Alias _
    "GetPrivateProfileStringA" (ByVal lpApplicationName As String, _
    ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal _
    lpReturnedString As String, ByVal nSize As Long, ByVal _
    lpFileName As String) As Long
Public Function INIRead(File As String, Section As String, _
        Item As String) As String
    Dim sBuf As String, iRC As Integer
    sBuf = Space(255)
    iRC = GetPrivateProfileString(Section, Item, "Not Found", sBuf, 255, File)
    sBuf = Left$(sBuf, iRC)
    If StrComp(sBuf, "Not Found") = 0 Then
        INIRead = vbNullString
    Else
        INIRead = sBuf
    End If
End Function

Public Sub INIWrite(File As String, Section As String, _
        Item As String, ItemValue As String)
    WritePrivateProfileString Section, Item, ItemValue, File
End Sub

[pasaran]

Qualcuno ha gia' provveduto prima di me.

Ciao