Titoli di tutte le finestre

[PEA]

Ciao volevo sapere se c'è un modo per elencare in una matrice tutti i titoli delle finestre aperte in quel momento, in pratica mi serve una funzione che mi restituisca i titoli di ogni finestra aperta (una finestra alla volta) in modo che io li possa archiviare in una matrice

grazie

http://pea.3000.it

[chipdb]

Cerca nel forum, se ne è già parlato. Comunque c'è un API apposta che ora non ricordo, controlla su AllAPI.

Ciao

[PEA]

Scusami forse sono io che non so cercare ma ho cercato sia nel forum che su allapi ma non ho trovato quello che cercavo. Tra i post nel forum c'era qualcosa che assomigliava però dicevanon soltanto di aver trovato la soluzione (non dicevano quale) ed era solo sul 9x a me serviva pure su l'Xp. Per favore se sai qualcosa di utile dimmelo oppure mettimi l'indirizzo del post



grazie


------------------
http://pea.3000.it

[vitren54]

Crea un progetto con un form (form1) e all'interno una listbox (list1) dopo incolla il seguente codice:

Private Declare Function GetWindow Lib "user32" (ByVal hwnd As Long, ByVal wCmd As Long) As Long
Private Declare Function GetParent Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function GetWindowTextLength Lib "user32" Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long

Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2

Dim CurrWnd As Long
Dim Length As Long
Dim TaskName As String
Dim Parent As Long

Sub LoadTaskList()

    List1.Clear
    CurrWnd = GetWindow(Form1.hwnd, GW_HWNDFIRST)
    
    While CurrWnd <> 0
    
        Parent = GetParent(CurrWnd)
        Length = GetWindowTextLength(CurrWnd)
        TaskName = Space$(Length + 1)
        Length = GetWindowText(CurrWnd, TaskName, Length + 1)
        TaskName = Left$(TaskName, Len(TaskName) - 1)
        
        If Length > 0 Then
            If TaskName <> Me.Caption Then List1.AddItem TaskName
        End If
        
        CurrWnd = GetWindow(CurrWnd, GW_HWNDNEXT)
        DoEvents
        
    Wend

End Sub

Private Sub Form_Load()
    LoadTaskList
End Sub

Ciao