Proteggere pagina di area riservata

[ubbicom]

Ciao, ho creato seguento le lezioni di html.it un'area riservata dove si accede tramite login e password; sin qui tutto bene, ma mi sono accorto che se digito correttamente sulla barra degli indirizzi di explorer il percorso di pagina che sta dentro l'area riservata (dunque che solo chi si identifica dovrebbe consultare) si apre senza chiedere login e password, come mi organizzo per proteggere tutte queste pagine protette (meglio da proteggere?)
Grazie

[Roby_72]

Dopo aver controllato user e password devi attivare una variabile di sessione che inserirai poi in cima a tutte le pagine che vuoi proteggere.
Dubito che le lezioni non ti abbiano fornito queste indicazioni.

Roby

[ubbicom]

Originariamente inviato da Roby_72
Dopo aver controllato user e password devi attivare una variabile di sessione che inserirai poi in cima a tutte le pagine che vuoi proteggere.
Dubito che le lezioni non ti abbiano fornito queste indicazioni.

Roby

Sicuramente me le hanno fornite ma non le ho capite bene...
questa è la pagina di verifica login e password:

<%
	' Dichiarazione variabili
	dim intTest
		intTest="0"
	'Verifico se manca il nome utente
	if request.form("user")="" or request.form("code")="" then
		response.redirect "a_ris.asp?Id=1"
	end if

	' Apro il database
	dim strCode
		strCode="innovatel"
	dim n_user
		n_user=replace(request.form("user"),"'","''")
	dim n_code
		n_code=replace(request.form("code"),"'","''")
	

	Set Conn=Server.CreateObject("ADODB.Connection") 

	strConn="driver={Microsoft Access Driver (*.mdb)}; " 
	strConn=strConn & " DBQ=" & Server.MapPath("user_reg.mdb") 
	strConn=strConn & ";pwd=" & strCode

	Conn.Open strConn
	sql = "SELECT * FROM user WHERE name='"&n_user&"'  AND code='"&n_code&"'"
	Set rs = Server.CreateObject("ADODB.Recordset")

	rs.Open sql, conn ,3,3
	
	'verifico che esista davvero

	if rs.eof then
		intTest="1"
	else
		intTest="2"
	end if

	'chiudo il database
	rs.Close
	set rs = Nothing
	conn.Close 
	set conn = Nothing
	
	'avvviso ke il nome è già presente
	if intTest="1" then
		response.redirect "a_ris.asp?Id=2"
	else
		response.redirect "pag_ris.asp"
	end if
%>

dove devo prevedere la variabile di sessione?

[Roby_72]

'avvviso ke il nome è già presente
	if intTest="1" then
		response.redirect "a_ris.asp?Id=2"
	else
session("admin") = "1" 		response.redirect "pag_ris.asp"
	end if

In tutte le pagine riservate, all'inizio farai:

<%
if session("admin") <> "1" then
response.redirect("esci.asp")
end if
%>

Roby

[ubbicom]

Mille grazie, eccezionale !!!!