[ACCESS] visualizzare report in base a menu a discesa.

[d-force]

Ciao a tutti!

Spero di non essere OT, perchè è più un problema di programmazione in VBA...Eventualmente chiedo gentilmente di spostarmi nel forum appropriato.

Siamo in ACCESS.

Ho realizzato una maschera che contiene un menù a discesa in cui sono elencate due promozioni:

- verde
- rosso

(Il menu a discesa prende le vosi da una tabelle tbl Promozioni)

Ora ho un bottone che visualizza un report con i dati inseriti della maschera.

Vorrei che il bottone cmdReport visualizzasse i report in base alla voce scelta nel menù a discesa.

Se ho scelto 'rosso' dorebbe visualizzare il rptRosso se invece non scelgo niente dovrebbe visualizzare un report standard rptStandard.

Ho provato a scrivere queste righe di codice con l'enunciato Select ma ho bassissime conoscienze di VBA, così chiedo un votro gentile aiuto:

Private Sub CmdViewVoucher_Click()
    Select Case cboPromozione.Text
        Case "Rosso"
            DoCmd.OpenReport "rptRosso", acPreview, "", " [IDPrenotazioni]=[Forms]![FormPrenotazioni]![IDPrenotazioni]"
        Case "verde"
            DoCmd.OpenReport "rptVerde", acPreview, "", " [IDPrenotazioni]=[Forms]![FormPrenotazioni]![IDPrenotazioni]"
        Case Else
            DoCmd.OpenReport "rptVoucher2", acPreview, "", " [IDPrenotazioni]=[Forms]![FormPrenotazioni]![IDPrenotazioni]"
    End Select
End Sub

Grazie in anticipo per il vostro aiuto!

d-force

[longline]

Sembra Ok. Qual è il problema?

[d-force]

Non funziona,

dice:

errore di run time 2185

Impossibile fare riferimento ad una proprietà o ad un metodo per un controllo a meno che non abbia lo stato attivo.

Vorrei che il pulsante cmdViewVoucher visualizzasse il report in base alla selezione scelta nel menù a discesa...

d-force

[fabio309]

per caso quando hai scritto il criterio [IDPrenotazioni]=[Forms]![FormPrenotazio
ni]![IDPrenotazioni]
hai usato il wizard?
te lo chiedo perchè mi è capitata spesso questa situazione: creazione automatica criteri, se scelgo forms--> "tutte le maschere" funziona, mentre se scelgo forms--> "maschere caricate" non va e mi da il tuo stesso errore

[d-force]

E' da un poò di tempo che ho fatto questo sript, ma credo di aver usato il wizard...

Si può trovare na soluzione?

Il problema è che io non sono pratico di VBA...

d-force

[longline]

Prova così:

Private Sub CmdViewVoucher_Click()
    Dim idPren as Long
    idPren = Me.IDPrenotazioni
    Select Case cboPromozione.Text
        Case "Rosso"
            DoCmd.OpenReport "rptRosso", acPreview, "", " [IDPrenotazioni]=" & idPren
        Case "verde"
            DoCmd.OpenReport "rptVerde", acPreview, "", " [IDPrenotazioni]=" & idPren
        Case Else
            DoCmd.OpenReport "rptVoucher2", acPreview, "", " [IDPrenotazioni]=" & idPren
    End Select
End Sub

[longline]

O, ancora meglio:

Private Sub CmdViewVoucher_Click()
    Dim strFiltro as String
    strFiltro = "[IDPrenotazioni]= " & Me.IDPrenotazioni
    Select Case cboPromozione.Text
        Case "Rosso"
            DoCmd.OpenReport "rptRosso", acPreview, "", strFiltro
        Case "verde"
            DoCmd.OpenReport "rptVerde", acPreview, "", strFiltro 
        Case Else
            DoCmd.OpenReport "rptVoucher2", acPreview, "",  strFiltro
    End Select
End Sub

[d-force]

provo subito....

[d-force]

Viene lo stesso errore...

con il debug evidenzia questa riga

Select Case cboPromozione.Text

Cos'è che può dargli noia...? :master:

[longline]

Modifica così allora:

Private Sub CmdViewVoucher_Click()
    Dim strFiltro as String
    Dim strValore as String
    strFiltro = "[IDPrenotazioni]= " & Me.IDPrenotazioni
    strValore = cboPromozione
    Select Case strValore
        Case "Rosso"
            DoCmd.OpenReport "rptRosso", acPreview, "", strFiltro
        Case "verde"
            DoCmd.OpenReport "rptVerde", acPreview, "", strFiltro 
        Case Else
            DoCmd.OpenReport "rptVoucher2", acPreview, "",  strFiltro
    End Select
End Sub