[VB6] Effettuare uno screenshot

[Vinniec]

Ciao,
Su msdn è scritto chiaramente che non è possibile utilizzare SendKeys per inviare {PRTSC} per effettuare uno screenshoot. Bene, allora ho gironzolato tra le API ed ho trovato PrintWindow, che però stampa in un DC.. ora, a me di stampare su una finestra o su uno schermo non mi interessa... se volessi semplicemente salvare la stampa video su file??? Magari esattamente come accade premendo il pulsante STAMP, in modo da poter agire su ClipBoard.
Suggerimenti?
Grazie

[Boolean]

questa è la dichiarazione API:

Private Declare Sub keybd_event Lib "user32" _
              (ByVal bVk As Byte, ByVal bScan As Byte, _
              ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Const VK_SNAPSHOT = &H2C

e per "simulare" la pressione del tasto STAMP usi questa istruzione

keybd_event VK_SNAPSHOT, 1, 0, 0

poi devi solo gestire l'immagine nella ClipBoard

Boolean

[Vinniec]

grazie,
ero convinto che, come per sendkeys, l'emulazione della pressione del tasto STAMP fosse inibita anche in questa funzione. Proverò così.
Thank you,

[LMondi]

Ho provato e completato il codice, gentilmente postato da Boolean.
Riprendo il post per sapere se è possibile utilizzare la tecnica di cui trattasi per stampare (naturalmente su carta). Se è possibile, vorrei sapere se è una tecnica valida e se è reperibile un tutorial.

Private Declare Sub keybd_event Lib "user32" _
              (ByVal bVk As Byte, ByVal bScan As Byte, _
              ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Const VK_SNAPSHOT = &H2C
'------------------------------------------------------
Private Sub Command1_Click()

' Pulisce la Clipboard
    Clipboard.Clear

' Elimina la bitmap dal form:
    Image1.Picture = LoadPicture()

'per "simulare" la pressione del tasto STAMP usa questa istruzione:
    keybd_event VK_SNAPSHOT, 1, 0, 0

    DoEvents

' Recupera l'immagine dalla Clipboard:
    Image1.Picture = Clipboard.GetData

' Salva l'immagine in un file:
    SavePicture Image1.Picture, App.Path & "\Prova\ProvaScreen.bmp"
' Elimina la bitmap dal form:
    Image1.Picture = LoadPicture()
End Sub

[Boolean]

Ciao LMondi,

stampare su carta, una volta ottenuta l'immagine con le istruzioni scritte nel tuo codice, è abbastanza immediato.

potrebbe essere sufficiente utilizzare il metodo PaintPicture dell'oggetto Printer.

anche senza per forza utilizzare un controllo Image sul form, puoi dichiarare una variabile oggetto stdPicture

Dim picPerStampa as stdPicture
Set picPerStampa = Clipboard.GetData

Printer.PaintPicture picPerStampa, 0, 0

in qusto modo stampi la picture a partire dalle coordinate 0, 0
e senza fare nessun adattamento alla misura del foglio, ma volendo, la sintassi completa di PaintPicture permette di impostare anche larghezza e altezza dell'immagine da stampare.

Boolean

[Vinniec]

quoto boolean!
Non credevo che l'argomento potesse interessare..
hihi..

[LMondi]

Molto interessante, però vorrei sapere se il predetto metodo è più performante rispetto a quello offerto da PrintForm i cui risultati in stampa sono deludenti soprattutto per quanto riguarda la risoluzione.
Ora farò delle prove ...

[LMondi]

Dunque ho fatto una prima stesura della routine di stampa, a dire il vero non mi soddisfa per la scarsa qualità della risoluzione, nonostante che abbia specificato 300 DPI (il max per la mia stampante, ma che di solito dà un risultato soddisfacente); poi vanno in stampa anche le barre, ecc. ... . Quale metodo si deve utilizzare per migliorare il tutto ?

Private Sub Command2_Click()
    Dim picPerStampa As StdPicture

' Imposta la gestione degli errori:
    On Error GoTo ErrorHandler
    
' Pulisce la Clipboard
    Clipboard.Clear

'per "simulare" la pressione del tasto STAMP usa questa istruzione:
    keybd_event VK_SNAPSHOT, 1, 0, 0

    DoEvents

    Set picPerStampa = Clipboard.GetData(vbCFDIB)
    
' Imposta la risoluzione di stampa su 300 DPI:
    Printer.PrintQuality = 300
' Stampa l'immagine acquisita con la Clipboard:
    Printer.PaintPicture picPerStampa, 0, 0
    
' Invia il messaggio allo spooler di termine stampa:
    Printer.EndDoc


ErrorHandler:
    If Err.Number <> 0 Then
        MsgBox "Errore durante il tentativo di stampa dell'immagine - " & "Numero errore: " & Err.Number & vbCr _
        & "Descrizione: " & Err.Description, vbCritical, "Prova di stampa dell'immagine dello schermo con Printer.PaintPicture."
        Err.Clear
        Exit Sub
    End If

End Sub

:master:

[Boolean]

ciao LMondi,

per la qualità, purtroppo non credo si possa più di tanto... tieni conto che l'immagine dello schermo è a 72 Dpi, quindi incrementare la qualità di stampa a 300 è a dir poco irrilevante

per quanto riguarda la "selezione" della stampa, puoi vedere la sintassi completa del metodo PaintPicture, che oltre a ridimemsionare l'immagine permette anche di effettuare un "ritaglio" sull'immagine sorgente:

Dim imgW as Integer
Dim imgH as Integer
imgW = Printer.ScaleX(picPerStampa, vbHimetric, vbTwips)
imgH = Printer.ScaleY(picPerStampa, vbHimetric, vbTwips)
Printer.PaintPicture picPerStampa, 0, 0 , Printer.ScaleWidth, Printer.ScaleHeight, 150, 150, imgW-300, imgH-300
Printer.EndDoc

in questo esempio viene stampata l'immagine rifilata di 150 twips per lato adattandone l'immagine allo spazio disponibile della stampante.

Boolean

[LMondi]

Grazie Boolean,
le tue spiegazioni sono molto chiare.
Ora capisco perchè il metodo è poco, per così dire, frequentato. Peccato che la risoluzione sia scadente, altrimenti il metodo sarebbe molto comodo.