Errore con CDONTS e NewMail

[Vailfox]

Ciao ragazzi,
stò creando un feedback in asp seguendo la guida asp di html.it....
ho capito bene tutto il codice, ma al momento della prova il pc mi dice:

Oggetto Server error 'ASP 0177 : 800401f3'

Impossibile eseguire il metodo Server.CreateObject

/ciao/officina Cromag/conferma_contatti.asp, line 15

Stringa dell'interfaccia non valida.

ho provato prima a locale con IIS e poi su un server windows, ma il risultato è sempre lo stesso, Vi posto il codice da me scritto, così in caso mi date una mano voi........vi prego !! Aiuto


<%
dim objEmailCli
Set objEmailCli = CreateObject("CDONTS.NewMail")

objEmailCli.BodyFormat = 0 '0=html 1=testo
objEmailCli.To = "fabrizioalongi@tiscali.it"
objEmailCli.From = "fabrizioalongi@tiscali.it"
objEmailCli.Subject = "prova"

objEmailCli.Body = "proviamo"

objEmailCli.Send

Set objEmailCli = Nothing
%>

[viki1967]

Verifica che il componente sia correttamente installato con questo script:

<%

	REM	Project:		COM Checker
	REM	Creator:		James Lindën
	REM	Date:		6/25/2001 12:14am

	'*****************************************************************

	'	COM Checker version 1.0
	'	© 2001 Ticluse Teknologi, All rights reserved.

	'	This class may be redistributed, as long as copyright and development
	'	information remain intact with class source code. Bug reports and / or
	'	comments may be directed to jlinden@intelidev.com.

	'*****************************************************************

	Dim comList(43)
		comList(0) = Array( "AB Mailer","ABMailer.Mailman" )
		comList(1) = Array( "ABC Upload","ABCUpload4.XForm" )
		comList(2) = Array( "ActiveFile","ActiveFile.Post" )
		comList(3) = Array( "ActiveX Data Object","ADODB.Connection" )
		comList(4) = Array( "Adiscon SimpleMail","ADISCON.SimpleMail.1" )
		comList(5) = Array( "ASP HTTP","AspHTTP.Conn" )
		comList(6) = Array( "ASP Image","AspImage.Image" )
		comList(7) = Array( "ASP Mail","SMTPsvg.Mailer" )
		comList(8) = Array( "ASP Simple Upload","ASPSimpleUpload.Upload" )
		comList(9) = Array( "ASP Smart Cache","aspSmartCache.SmartCache" )
		comList(10) = Array( "ASP Smart Mail","aspSmartMail.SmartMail" )
		comList(11) = Array( "ASP Smart Upload","aspSmartUpload.SmartUpload" )
		comList(12) = Array( "ASP Tear","SOFTWING.ASPtear" )
		comList(13) = Array( "ASP Thumbnailer","ASPThumbnailer.Thumbnail" )
		comList(14) = Array( "ASP WhoIs","WhoIs2.WhoIs" )
		comList(15) = Array( "ASPSoft NT Object","ASPSoft.NT" )
		comList(16) = Array( "ASPSoft Upload","ASPSoft.Upload" )
		comList(17) = Array( "CDONTS","CDONTS.NewMail" )
		comList(18) = Array( "Chestysoft Image","csImageFile.Manage" )
		comList(19) = Array( "Chestysoft Upload","csASPUpload.Process" )
		comList(20) = Array( "Dimac JMail","JMail.Message" )
		comList(21) = Array( "Distinct SMTP","DistinctServerSmtp.SmtpCtrl" )
		comList(22) = Array( "Dundas Mailer","Dundas.Mailer" )
		comList(23) = Array( "Dundas Upload","Dundas.Upload.2" )
		comList(24) = Array( "Dynu Encrypt","Dynu.Encrypt" )
		comList(25) = Array( "Dynu HTTP","Dynu.HTTP" )
		comList(26) = Array( "Dynu Mail","Dynu.Email" )
		comList(27) = Array( "Dynu Upload","Dynu.Upload" )
		comList(28) = Array( "Dynu WhoIs","Dynu.Whois" )
		comList(29) = Array( "Easy Mail","EasyMail.SMTP.5" )
		comList(30) = Array( "File System Object","Scripting.FileSystemObject" )
		comList(31) = Array( "Ticluse Teknologi HTTP","InteliSource.Online" )
		comList(32) = Array( "Last Mod","LastMod.FileObj" )
		comList(33) = Array( "Microsoft XML Engine","Microsoft.XMLDOM" )
		comList(34) = Array( "Persits ASP JPEG","Persits.Jpeg" )
		comList(35) = Array( "Persits ASPEmail","Persits.MailSender" )
		comList(36) = Array( "Persits ASPEncrypt","Persits.CryptoManager" )
		comList(37) = Array( "Persits File Upload","Persits.Upload.1" )
		comList(38) = Array( "SMTP Mailer","SmtpMail.SmtpMail.1" )
		comList(39) = Array( "Soft Artisans File Upload","SoftArtisans.FileUp" )
		comList(40) = Array( "Image Size", "ImgSize.Check" )
		comList(41) = Array( "Microsoft XML HTTP", "Microsoft.XMLHTTP" )
		comList(42) = Array( "Grafici Excel", "OWC.Chart" )
		comList(43) = Array( "ADODB Stream", "ADODB.Stream" )

	'This function was modified from the work of Rob Risner.
	'http://www.planetsourcecode.com/xq/ASP/txtCodeId.6731/lngWId.4/qx/vb/scripts/ShowCode.htm

	Function IsAvailable( comIdentity )
		On Error Resume Next
		IsAvailable = False
		Err = 0
		Set xTestObj = Server.CreateObject( comIdentity )
		If Err = 0 Then IsAvailable = True
		Set xTestObj = Nothing
		Err = 0
	End Function

	Public Function CheckCOM()
		Avail = 0
		strTxt = "<table cellpadding=3 cellspacing=3 border=0 align=center width=300>" & vbNewLine
		For Idx = LBound( comList ) To UBound( comList )
			Provider = Idx
			strTxt = strTxt & vbTab & "<tr><td width=200><font class=norm>" & comList(Idx)(0) & "</font></td>"
			strTxt = strTxt & "<td align=right width=20><font class=norm>[</font></td>"
			If IsAvailable( comList(Idx)(1) ) Then
				strTxt = strTxt & "<td align=center><font face=tahoma size=2 color=blue>Available</font></td>"
				Avail = Avail + 1
			Else
				strTxt = strTxt & "<td align=center><font class=norm>Unavailable</font></td>"
			End If
			strTxt = strTxt & "<td align=left width=20><font class=norm>]</font></td></tr>" & vbNewLine
		Next
		strTxt = strTxt & vbTab & "<tr><td colspan=4 height=30><font class=norm><font color=blue>" & Avail & "</font> of "
		strTxt = strTxt & UBound( comList ) + 1 & " supported components are available.</font></td></tr>" & vbNewLine
		CheckCOM = strTxt & "</table>" & vbNewLine
	End Function

	Response.Write( CheckCOM() )
%>

[Vailfox]

frena....frena....

aspetta, nel frà tempo che mi davi la risposta, ho girato un tantino su google, e ho notato che la libreria CDONTS su win 2003 è ormai scomparsa......
Adesso si usa la CDOSYS per fare questo tipo di lavoro.
ti ringrazio per la risposta, ma adesso il mio problema è un'altro (seppur solo a scopo istruttivo).
Ho trovato questo codice, l'ho provato e funziona, Ma mi piacerebbe capire come funzione, ovvero aver una spiegazione di ogni riga di questo codice.
Qualcuno può darmela?? Sarebbe molto importante per me.......per imparare l'arte


<%
Set objConfiguration = CreateObject("CDO.Configuration")
Set objMessage = CreateObject("CDO.Message")

With objMessage
Set .Configuration = objConfiguration
.From = "fabrizioalongi@tiscali.it"
.To = "fabrizioalongi@tiscali.it"
.Subject = "Prova"
.htmlBody ="sono server 2"
.AutoGenerateTextBody = False
.TextBody = "Prova testo"
End With
objMessage.Send
response.write "Messaggio inviato"
%>

[viki1967]

http://www.weppos.com/asp/script/scr....asp?script=15

[Vailfox]

apprezzo molto il tuo aiuto, ma non capisco perchè si deve aggiungere il numero della porta e tanto altro se a me su server aruba funziona tutto alla perfezione con il codice da me prima postato?? :master:

[viki1967]

Originariamente inviato da Vailfox
apprezzo molto il tuo aiuto, ma non capisco perchè si deve aggiungere il numero della porta e tanto altro se a me su server aruba funziona tutto alla perfezione con il codice da me prima postato?? :master:

E' un puro caso che questo codice funziona sul tuo server hosting aruba, a me invece non va (sono sempre su aruba).

Ti consiglio di leggere qui.

[Vailfox]

bene, ti dispiacerebbe postarmi allora la il codice esatto di quello che ho postato io??
Mi sarebbe molto utile........ Grazie anticipatamente

[viki1967]

<%

Const cdoSendUsingMethod        = _
	"http://schemas.microsoft.com/cdo/configuration/sendusing"
Const cdoSendUsingPort          = 2
Const cdoSMTPServer             = _
	"http://schemas.microsoft.com/cdo/configuration/smtpserver"
Const cdoSMTPServerPort         = _
	"http://schemas.microsoft.com/cdo/configuration/smtpserverport"
Const cdoSMTPConnectionTimeout  = _
	"http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
	
Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields

With Fields
	.Item(cdoSendUsingMethod)       = cdoSendUsingPort
	.Item(cdoSMTPServer)            = "tuo.server"
	.Item(cdoSMTPServerPort)        = 25
	.Item(cdoSMTPConnectionTimeout) = 10
	.Update
End With

Set objMessage = Server.CreateObject("CDO.Message")

Set objMessage.Configuration = objConfig

With objMessage
	.To       = "email@email.it"
	.From     = "email@email.it"
	.BCc      = "email@email.it"
	.Subject  = "Messaggio Automatico"
	.HtmlBody = messaggio
	.Send
End With

Set Fields = Nothing
Set objMessage = Nothing
Set objConfig = Nothing

			
			%>

[Vailfox]

Grazie per la disponibilità!!
ps:

mi sai consigliare qualche buona guida alle asp?? Tu dove lo hai appreso?? .....scusa l'invadenza :rollo:

[viki1967]

http://asp.html.it/