Problema con visualizzazione directory

[Giasti]

Ciao a tutti. Dopo aver sezionato il forum alla ricerca di argomenti inerenti la visualizzazione del contenuto di directory, ho trovato questo script che mi restitusce il contenuto in xml a flash. Funziona perfettamente tutto, però mi visualizza solo le cartelle se metto SubFolder e i files se metto Files. Vorrei fare in modo di visualizzare entrambe le cose. Essendo scarsissimo in asp, dopo evere tentato diverse soluzioni, non riesco ad ottenere il risultato. Ho provato a duplicare anche la funzione principale e altro, ma non so gestire glòi errori che ne derivano, insomma non conosco la sintassi di base. Provo a postare il codice, se gentilmente qualcuno può darmi una dritta. Grazie mille.


<%
Response.ContentType="text/xml"
Response.CacheControl = "no-cache"
Response.AddHeader "Pragma", "no-cache"
Response.Expires = -1
Response.Buffer = TRUE
function listFilesInFolder(folder)
dim out, fil, cre, lmd, nam, siz
out = "<folder>"
for each fil in folder.SubFolders
out = out & "<file"
cre = " dateCreated='" & fil.dateCreated & "'"
lmd = " tipo='" & fil.Type & "'"
nam = " nome='" & fil.Name & "'"
siz = " peso='" & fil.Size & "'"
out = out & cre & lmd & nam & siz &" />"
next
out = out + "</folder>"
listFilesInFolder = out
end function

dim fso,f
set fso = CreateObject("Scripting.FileSystemObject")
set f = fso.GetFolder(Request("target_folder"))
Response.write listFilesInFolder(f)
set f = nothing
set fso = nothing
%>

[santino83_11_04]

questo prende una cartella e stampa il contenuto in files della cartella medesima..non fa controlli nel caso in cui questa contenga altre cartelle e quindi non stampa iterativamente nulla...è un pò statico

mo vedo se trovo quello che avevo postato ad un tizio tempo fa, altrimenti continua a cercare nel forum magari lo trovi

[santino83_11_04]

mi hanno detto che funzionava...vedi un pò te:

<%

dim fso,mioAlbero



'sub di partenza
sub stampaAlbero(percorso)

apriFso()

if fso.FolderExists(percorso) then
stampaIntestazione
apri "albero"
createTree percorso
chiudi "albero"
else
toStamp "Errore nella procedura: percorso di partenza errato",99
end if

chiudiFso()
end sub

'sub ausiliaria per inizializzare fso
sub apriFso()
if not isObject(fso) then set fso=server.CreateObject("scripting.filesystemobject")
end sub

'sub ausiliaria per chiudere fso
sub chiudiFso()
if isObject(fso) then set fso=nothing
end sub


'sub di avvio creazione albero
sub createTree(percorso)
'per ogni folder che trovo richiamo createTree
dim folder,files,genitore,nomecartella


if fso.folderExists(percorso) then

'ricavo il nomecartella
nomecartella=getStr(percorso,0)
genitore=getStr(percorso,1)

apri "cartella nome=""" & nomecartella & """ parent=""" & genitore & """"

'attributo "nome",nomecartella 'opzionale
'attributo "genitore",genitore 'opzionale

set folder=fso.getFolder(percorso)
'stampo prima tutti i sottoFolder

for each subF in folder.subFolders
createTree percorso & "\" & subF.name
next

'stampo tutti i File

set files=folder.Files
conta=0
for each file in files
conta=conta+1
if conta=1 then apri "elencofile"
toStamp file.name,2
next
if conta>0 then chiudi "elencofile"

set file=nothing
set folder=nothing

chiudi "cartella"   'chiudo l'elemento cartella
else

toStamp "Errore nel percorso",99
end if
end sub

'stampo l'intestazione dell'xml
sub stampaIntestazione()
mioAlbero=mioAlbero & "<?xml version=""1.0"" encoding=""UTF-8""?>"
end sub

'stampo gli elementi (file o errori)
sub toStamp(oggetto,tipo)
dim tagApri, tagChiudi
select case tipo
case 2
tagApri="<file>"
tagChiudi="</file>"
case else
tagApri="<errore>"
tagChiudi="</errore>"
end select
mioAlbero=mioAlbero & tagApri & "<![CDATA[" & oggetto & "]]>" & tagChiudi
end sub

'apro un entita nome
sub apri(nome)
mioAlbero=mioAlbero & "<" & nome & ">"
end sub

'chiudo un entita nome
sub chiudi(nome)
mioAlbero=mioAlbero & "</" & nome & ">"
end sub

'stampo un entita nome con dentro un valore
sub attributo(nome,valore)
mioAlbero=mioAlbero & "<" & nome & "><![CDATA[" & valore & "]]>" & "</" & nome & ">"
end sub

'recupero un pezzo specifico del percorso
function getStr(stringa,numero)
dim temp,max
temp=split(stringa,"\")
max=ubound(temp)
getStr=temp(max-numero)
end function

stampaAlbero "C:\cartella_inizio"  'riempio mioAlbero

' Impostazione che setta il tipo di file in output su XML
response.ContentType = "text/xml"
response.Write mioAlbero  'stampo l'albero
%>

[Giasti]

Ti ringrazio Santino, ho visto solo ora... adesso provo
Grazie