Aiutino per una piccola rettifica al seguente script

[The_Matrix]

Sul seguente forum ho trovato il seguente script che effettua una visualizzazione delle immagini presenti in una cartella.
Le immagini vengono aperte con effetto fede e quando passa alla successiva si chiude a scatto e appare l'altra.
Vi chiedo se potete pubblicare lo stesso script leggermete rettificato e cioè che esegua l'effetto fade anche alla chiusura dell'immagine visualizzata prima che carichi l'altra.

Come sempre vi ringrazio anticipatamente per l'aiuto.

var mcLoad:MovieClipLoader = new MovieClipLoader();
var mcList:Object = new Object();
mcList.onLoadError = function(target_mc:MovieClip, errorCode:String) {
	if (errorCode == "URLNotFound") {
		index = 1;
		slideShow(target_mc);
	}
};
mcList.onLoadInit = function(target_mc:MovieClip) {
	var path = this;
	index++;
	var tw:Object = new mx.transitions.Tween(target_mc, "_alpha", mx.transitions.easing.None.easeNone, 0, 100, 50, false);
};
mcLoad.addListener(mcList);
var slideShow:Function = function (target_mc:MovieClip):Void {
	mcLoad.loadClip("img/"+index+".jpg", target_mc);
};
var xPos:Number = 0;
var yPos:Number = 0;
var my_mc:MovieClip = this.createEmptyMovieClip("my_mc", 1);
my_mc._x = xPos;
my_mc._y = yPos;
var index:Number = 1;
timeToChange = 10;
slideShow(my_mc);
a = setInterval(this, "slideShow", timeToChange*1000, my_mc);

[The_Matrix]

up, please

[and80]

è il mio SlideShow in questi giorni stavo modificando il codice per fare proprio quello che dicevi... ma non ho ancora trovato il tempo di farlo... quindi ti tocca pazientare

[The_Matrix]

Appena lo completi mi puoi postare in codice, ti sarei veramente grato.

[and80]

ho modificato l'articolo

[The_Matrix]

Originariamente inviato da and80
ho modificato l'articolo

Mi potresti passare il codice? Grazie.

[crescenzo]

Originariamente inviato da The_Matrix
Mi potresti passare il codice? Grazie.

beh basta che vai sul link che ha in firma e leggi l'articolo

cmq questo quello modificato


var slideShow:Function = function (target:MovieClip, shifting:Number) {
var mclo:MovieClipLoader = new MovieClipLoader();
var mcli:Object = new Object();
var index:Number = 1;
mcli.onLoadProgress = function(target:MovieClip, lbytes:Number, tbytes:Number) {
trace("Caricamento..."+Math.floor((lbytes/tbytes)*100)+"%");
};
mcli.onLoadError = function(target:MovieClip, errorCode:String) {
if (errorCode == "URLNotFound") {
slideShow(target, shifting);
}
};
mcli.onLoadInit = function(target:MovieClip):Void {
index++;
var t:Object = new mx.transitions.Tween(target, "_alpha", mx.transitions.easing.None.easeNone, 0, 100, .5, true);
t.onMotionFinished = function() {
var a = setInterval(function () {
clearInterval(a);
var t:Object = new mx.transitions.Tween(target, "_alpha", mx.transitions.easing.None.easeNone, 100, 0, .5, true);
t.onMotionFinished = function() {
mclo.loadClip("img/"+index+".jpg", target);
};
}, shifting*1000);
};
};
mclo.addListener(mcli);
mclo.loadClip("img/"+index+".jpg", target);
};
var test:MovieClip = _level0.createEmptyMovieClip("test", 1);
slideShow(test, 5);

[The_Matrix]

Scusa la mia distrazione, pensavo che era quello vecchio.
Una sola osservazione ma per settarlo sull'obbiettivo dove intendo aprirlo devo modificare questa riga di codice

var test:MovieClip = _level0.createEmptyMovieClip("test", "");
slideShow(test, 5);

Perchè quando lo chiamo con movieclip esterno mi mostra la slide non più nella posizione che gli indico ma in alto. (non so se sono stato chiaro?)

[The_Matrix]

Originariamente inviato da crescenzo
beh basta che vai sul link che ha in firma e leggi l'articolo

cmq questo quello modificato ...

Tutto ok ho trovato dove stava il problema e ho risolto, grazie mille per l'aiuto.

praticamente ho sostituito questo codice:

var test:MovieClip = _level0.createEmptyMovieClip("test", 1);
slideShow(test, 5);

con il seguente:

var test:MovieClip = this.createEmptyMovieClip("test", 1);
slideShow(test, 5);

con il codice che mi avevi postato praticamente lo slide mi si apriva sopra le altre animazioni partento in alto a sinistra della videata e non nel punto che gli indicavo.

[and80]

se hai già un clip di destinazione sullo stage, la prima delle due righe che hai scritto nell'ultimo post, va eliminata, mentre nella seconda riga c'è il richiamo dove devi mettere in ordine il nome del clip su cui caricare le immagini esterne e la durata in secondi dello slide tra un'immagine e l'altra (n.b. nel tempo non è compreso anche l'eventuale caricamento e le dissolvenze)
perciò se il tuo clip si chiama "pippo", basta fare

slideShow(pippo, 5);

in caso di caricamenti esterni, ti consiglio di richiamare il clip con il suo percorso assoluto, ad esempio

slideShow(_root.pluto.pippo, 5);