[VB6] Inviare email tramite Lotus Notes

[mcolombo72]

Ciao a tutti,
ho creato un'applicazione in VB6, che crea dei file che dovranno essere poi elaborati da un'istituzione statale.
I file devono arrivare ad una casella di posta ben definita, per cui dovrei implementare la mia applicazione con un pulsante che attivi il client di posta.
Il problema è che devo usare Lotus Notes.....
Qualcuno sa dirmi come "scatenare" questo client tramite VB6?

Grazie 1000

[wallrider]

se non hai la necessità di allegare files in automatico puoi provare col protocollo mailto

setta Notes come client predefinito poi esegui questa stringa con shellexecute

mailto:indirizzo@server.dom?subject=prova&body=fun ziona!

io ricordo che cominciai una cosa simile ma poi mi sono arreso

[mcolombo72]

in effetti sto impazzendo.....e non riesco a venirne fuori....ti ringrazio....faccio così...
gli allegati li inserirà un utente....

[hannibal/p]

se hai lotus notes installato sulla macchina di sviluppo, torverai trai riferimenti di progetto di vb6, Lotus Notes Automation Classes..............
e da li..........
Buon lavoro.

[mcolombo72]

Ciao hannibal/p,
grazie innanzitutto...in effetti avevo inserito tra i riferimenti la classe di Lotus.....
il problema è che non so come usarla.......cercavo dei frammenti di codice che potessero aiutarmi......tra le altre cose, l'eseguibile finale dovrà girare su dei pc dove il client di posta per alcuni è outlook, per altri lotus notes.....

[mcolombo72]

.....alla fine ce l'ho fatta....!!!!
vi allego del codice nel caso servisse a qualcuno...

Public Function fInvioLotus(sOggetto As String) As Boolean
On Error GoTo err_fInvioLotus
Dim session As Object
Dim doc As Object
Dim rtf As Object

fInvioLotus = False
Set session = CreateObject("Notes.NotesSession")
Set db = session.GetDatabase("", "")
Call db.OPENMAIL
Set doc = db.CreateDocument
With doc
.Form = "Memo"
.SaveMessageOnSend = True
.SendTo = "mcolombo.consdsi@duomo.it"
.Subject = sOggetto
Set rtf = .CreateRichTextItem("Body")
Call rtf.AppendText("Con la presente si allega quanto in oggetto. Distinti saluti")
.Send (False)
End With
Set rtf = Nothing
Set doc = Nothing
Set db = Nothing
Set session = Nothing

fInvioLotus = True
Exit Function

err_fInvioLotus:
fInvioLotus = False
MsgBox Err.Description
End Function


ciao ciao

[PaoloDallari]

Ciao,
ho seguito con interesse il vostro post in quanto la cosa coinvolgerà anche me a breve,
non ho capito l'istruzione

db = session.GetDatabase("", "")
Db cos'è? un tipo object, dove lo hai dichiarato?

grazie, ciao

[mcolombo72]

sorry...hai ragione.....ho fatto un copia e incolla in velocità...
ecco la funzione "finale"

Public Function fInvioLotus(sOggetto As String, sIndirizzo As String) As Boolean
On Error GoTo err_fInvioLotus
Dim session As Object
Dim doc As Object
Dim rtf As Object
Dim db As Object

fInvioLotus = False
Set session = CreateObject("Notes.NotesSession")
Set db = session.GetDatabase("", "")
Call db.OPENMAIL
Set doc = db.CreateDocument
With doc
.Form = "Memo"
.SaveMessageOnSend = True
.SendTo = "xxxxx@xxxx.it"
.Subject = sOggetto
Set rtf = .CreateRichTextItem("Body")
Call rtf.AppendText("Con la presente si allega quanto in oggetto.")
Call rtf.AddNewLine(2)
Call rtf.AppendText("Distinti saluti.")
Call rtf.AddNewLine(3)
Call rtf.EmbedObject(1454, "", sIndirizzo, "Attachment")
.Send (False)
End With
Set rtf = Nothing
Set doc = Nothing
Set db = Nothing
Set session = Nothing

fInvioLotus = True
Exit Function

err_fInvioLotus:
fInvioLotus = False
MsgBox Err.Description
End Function



ciao ciao

[PaoloDallari]

Ok !
ciao