testo che si illumina

[enoer]

Salve a tutti. Sono nuovo in Flash come nel webdesign in generale e questo è il mio primo annuncio.
Sono alle prime armi con questo programma e uso la versione 8. Ho seguito molti tutorial e tante cose le capisco ma mi manca ancora molto da scoprire.
Qui il mio primo problema:
Non riesco a creare una scritta che si illumini lentamente; ho provato creando una parola con un rettangolo dietro convertito a bottone e poi sotto up ho cambiato l`alpha e provato overlay e cose del genere ma niente da fare. Il punto è che non ho trovato alcun tutorial al riguardo.
Come si fa?

[KillerWorm]

Ciao.

Non ho capito cosa vuoi ottenere di preciso.

[enoer]

Grazie per avermi risposto ti mando un esempio: http://www.flashtemplate.us/xmlswfdemo/h2o/index.html
dopo il loading troverai sulla sinistra un indice andando sui pulsanti troverai cio che voglio ottenere.

[KillerWorm]

Capito..
Quindi potrebbe essere sufficiente un semplice effetto di trasparenza.. come tu stesso ai citato, anche se non ho capito precisamente cosa hai fatto..

L'effetto lo puoi ottenere in tanti modi.
Ad esempio con l'utilizzo della classe Tween.

Ho realizzato una piccola funzione che crea l'effetto fade utilizzando questa classe.
Ti spiego come usarla..

• Inserisci un campo di testo statico sullo stage, e imposta il carattere e il colore bianco per il testo.
  Non usare caratteri dispositivo.. ovvero i primi 3 font che sono visualizzati nel menu a tendina della casella 'carattere', altrimenti l'alpha non avrà effetto.
  Ovviamente non immpostare nemmeno "Usa caratteri dispositivo" dal menu a tendina 'Metodo di rendering caratteri', ma ad esempio imposta "Antialiasing per animazione"
  
• Seleziona il campo di testo e premi F8 per trasformarlo in simbolo. Imposta il tipo "Clip filmato"
  
• Nomina l'istanza. Dal pannello Proprietà nella casella 'nome istanza' inserisci ad esempio "item1"
  
• Per impostare un area sensibile al mouse, puoi agire in vari modi. Ad esempio tu hai utilizzato un bottone.
  Ma volendo fare una cosa più funzionale e riutilizzabile, possiamo crearla da script nella stessa funzione che utilizzeremo per l'effetto fade.
  In questo modo puoi applicare l'effetto a qualsiasi istanza senza preoccuparti di creare pulsanti vari.
  Inserisci quindi questo script sul primo frame del livello principale:
  

  import mx.transitions.Tween;
  function setLightEffect(clip:MovieClip):Void {
  	//
  	// ---- PARAMETRI DELL'EFFETTO ----
  	// durata della dissolvenza (in secondi)
  	var durata = 0.5;
  	// valore alpha iniziale
  	var iniAlpha = 60;
  	// ---------------------------------
  	//
  	// imposto il clip col valore alpha iniziale
  	clip._alpha = iniAlpha;
  	// creo un'area sensibile all'interno del clip
  	clip.createEmptyMovieClip("hit", clip.getNextHighestDepth());
  	var bnd:Object = clip.getBounds(clip);
  	with (clip.hit) {
  		beginFill(0);
  		moveTo(bnd.xMin, bnd.yMin);
  		lineTo(bnd.xMax, bnd.yMin);
  		lineTo(bnd.xMax, bnd.yMax);
  		lineTo(bnd.xMin, bnd.yMax);
  		lineTo(bnd.xMin, bnd.yMin);
  		endFill();
  		_alpha = 0;
  	}
  	// funzione richiamata dagli eventi del mouse
  	var lighting = function (clip:MovieClip, stato:Boolean):Void {
  		var end = stato ? 100 : iniAlpha;
  		clip.lightFade.stop();
  		clip.lightFade = new Tween(clip, "_alpha", mx.transitions.easing.Regular.easeOut, clip._alpha, end, durata, true);
  	};
  	// assengo la funzione agli eventi del mouse
  	clip.onRollOver = function() {
  		lighting(this, true);
  	};
  	clip.onRollOut = function() {
  		lighting(this, false);
  	};
  }
  // imposto l'effetto al clip "item1"
  setLightEffect(item1);

  L'ultima riga assegna l'effetto all'istanza in questione..

Potrai utilizzare la stessa funzione richiamandola più volte per assegnare l'effetto a più istanze.

Es:

setLightEffect(item2);
setLightEffect(menu.home);
setLightEffect(menu.portfolio);

[enoer]

funziona alla grande e riesco a seguire abbastanza l`action scipt.
Solo che ora come faccio a dirgli che è un tasto e che quando premo sopra (on release gotoandStop 2) vada ad una nuova pagina?
Scusa so che per te sono cavolate ma per me è tanto
Se intanto ti va dai un`occhiata sul mio primo sito che ho realizzato per le settimane di studio.
E realizzato al 90% in PS e 10% in html (è molto sempliciotto) e funziona solo con Explorer.
Il modo in cui è stato realizzato è assurdo (usando delle coordinate) ma perlomeno funziona.
Dell`esistenza di css c`e l`hanno detto un po tarduccio e per questo che ho usato delle mappe per creare i bottoni

[KillerWorm]

Solo che ora come faccio a dirgli che è un tasto e che quando premo sopra (on release gotoandStop 2) vada ad una nuova pagina?

Puoi utilizzare l'istanza come un bottone e quindi applicargli l'evento onRelease.

item2.onRelease = function() {
// qui ci andranno le azioni
}

Se intanto ti va dai un`occhiata sul mio primo sito che ho realizzato per le settimane di studio.

Ok.. ma il link?

[enoer]

ecco il link. Non è il sito che sto facendo ma uno piu vecchio di un mesetto fa
http://n.ethz.ch/student/danchora/INIZIO.html

[KillerWorm]

Carino.. ma graficamente lo trovo un po' pesante..

Considera comunque sempre l'idea di creare siti crossbrowser.
Studia meglio i css..

Buon lavoro.