Caricare una pagina php che genera un file xml

[leti]

Salve a tutti,

avrei il seguente problema, ho un menù che dev'essere generato da un file xml, e fin qui tutto ok, ma se volessi farlo generare da una pagina php che al suo interno c'è uno script genera un file xml prendendo i dati dal database è possibile?

Io pensavo di chiamare all'interno del filamto flash la pagina php come se fosse una pagina xml. Posto il codice:

GenerateMenu = function(container, name, x, y, depth, node_xml) {
    var curr_node;
    var curr_item;
    var curr_menu = container.createEmptyMovieClip(name, depth);
    
    for (var i=0; i<node_xml.childNodes.length; i++) {
        curr_item = curr_menu.attachMovie("menuitem","item"+i+"_mc", i);
        curr_item._x = x;
        curr_item._y = y + i*curr_item._height;
        curr_item.trackAsMenu = true;
        
        curr_node = node_xml.childNodes[i];
        curr_item.name.text = curr_node.attributes.name;
        
        if (node_xml.childNodes[i].nodeName == "REGIONE"){
            curr_item.node_xml = curr_node;
            curr_item.onRollOver = curr_item.onDragOver = function(){
                var x = this._x + this._width - 1;
                var y = this._y - 1;
                GenerateMenu(curr_menu, "submenu_mc", x, y, 1000, this.node_xml);
                var col = new Color(this.background);
                col.setRGB(0xf4faff);
            };
        }else{
            curr_item.arrow._visible = false;
            curr_item.onRollOver = curr_item.onDragOver = function(){
                curr_menu.submenu_mc.removeMovieClip();
                var col = new Color(this.background);
                col.setRGB(0xf4faff);
            };
        }
        
        curr_item.onRollOut = curr_item.onDragOut = function(){
            var col = new Color(this.background);
            col.setTransform({ra:100,rb:0,ga:100,gb:0,ba:100,bb:0});
        };
        
            curr_item.onRelease = function(){
            Actions[this.action](this.variables);
            CloseSubmenus();
        };
    }
};

CreateMainMenu = function(x, y, depth, menu_xml){
    GenerateMenu(this, "mainmenu_mc", x, y, depth, menu_xml.firstChild);
    mainmenu_mc.onMouseUp = function(){
        if (mainmenu_mc.submenu_mc && !mainmenu_mc.hitTest(_root._xmouse, _root._ymouse, true)){
            CloseSubmenus();
        }
    };
};
CloseSubmenus = function(){
    mainmenu_mc.submenu_mc.removeMovieClip();
};

Actions = Object();
Actions.gotoURL = function(urlVar){
    getURL(urlVar, "_blank");
};
Actions.message = function(msg){
    message_txt.text = msg;
};
Actions.newMenu = function(menuxml){
    menu_xml.load(menuxml);
};

menu_xml = new XML();
menu_xml.ignoreWhite = true;
menu_xml.onLoad = function(ok){
    // create main menu after successful loading of XML
    if (ok){
        CreateMainMenu(5, 45, 0, this);
        message_txt.text = "message area";
    }else{
        message_txt.text = "error:  XML not successfully loaded";
    }
};

menu_xml.load("menuR.php", "GET"); 

Questo è tutto spero di essermi spiegata bene

[and80]

[Mod] Ti ho modificato il messaggio aggiungendo gli appositi tag per il codice, in modo da renderlo più leggibile.

[crescenzo]

>Io pensavo di chiamare all'interno del filamto flash la pagina php come se fosse una pagina xml.

certo giusto ...e quindi qualè il problema :master: se quel menu ti funge con un file xml deve fungere anche con una pag php che genera lo stesso output

[leti]

Lo pensavo anch'io ma non carica i dati....ho anche pensato che potrebbe essere una questione di url della pagina, ma stanno entrambi nella stessa root... comunque grazie, almeno so che sono quasi sulla strada giusta!!!!

[crescenzo]

Originariamente inviato da leti
Lo pensavo anch'io ma non carica i dati....

beh vedi bene xchè io in genere uso asp e facci oproprio questo ...formatto i dati in xml e li leggo in flash...quindi se prima fungeva con xml ..vedi bene la pag php che ti restituisca lo stesso output....dell'xml

[leti]

Si infatti avete ragione FUNZIONA!!!! Purtroppo quando ci si incaponoisce su una cosa non si vede la soluzione o semplicemente l'errore più banale!!! Il mio è che non pescavo dal database corretto!!!! Comunque grazie a tutti!