Campo memo query non visualizzato

[abellos]

Ciao,
ho un problema a cui non riesco venire a capo, ho il codice seguente funziona senza problemi ma nel contenuto di dettaglio_scansioni manca il valore di RSex("PrimoDidescNota") che viene visualizzato correttamente nella variabile dettaglio.
Il campo in questione e' di tipo memo, non ricevo errori semplicemente manca quell'informazione, non capisco il motivo perche' le linee sono uguali.
mi sapete dare una mano?

SQLEx2 = "SELECT richieste.tmpRichiesta, Tipo_mov.codmov, Tipo_mov.descrizioneMov, gest_arch.pratica, DateValue([dataRichiesta]) AS DataRich, DateValue([dataEva]) AS DataEvas, utenti.ubicazioneUBI, utenti.Cognome, utenti.Nome, First(gest_note.descNota) AS PrimoDidescNota, Tipo_mov.prezzo, Sum(gest_img.Npagina) AS SommaDiNpagina FROM ((((richieste INNER JOIN Tipo_mov ON richieste.codMov = Tipo_mov.codmov) INNER JOIN gest_arch ON richieste.codDoc = gest_arch.coddoc) INNER JOIN utenti ON richieste.codUtente = utenti.codUtente) LEFT JOIN gest_note ON (richieste.codDoc = gest_note.codDoc) AND (richieste.codNota = gest_note.codNota)) LEFT JOIN gest_img ON gest_arch.coddoc = gest_img.coddoc WHERE (((richieste.dataEva) Between #8/25/2022# And #9/22/2022 23.59.59#)) GROUP BY richieste.tmpRichiesta, Tipo_mov.codmov, Tipo_mov.descrizioneMov, gest_arch.pratica, DateValue([dataRichiesta]), DateValue([dataEva]), utenti.ubicazioneUBI, utenti.Cognome, utenti.Nome, Tipo_mov.prezzo ORDER BY richieste.tmpRichiesta;"


set RSex = conn.execute( SQLEx2 )


if not RSex.EOF then
    dettaglio = ""
    dettaglio_scansioni = ""


    tmpValori = Split(valori, "|")
    
    while not RSex.EOF


        giorni_eva = GiorniLavorativi(RSex("dataRich") , RSex("dataEvas") ,"" ) - 1
        
        i = 0
        visualizza_valori = ""
        while i <= UBound(tmpValori)
            
            visualizza_valori = visualizza_valori & RSex( CSTR( tmpValori(i)) ) &"-"
            
            i = i + 1
        wend
        visualizza_valori = left(visualizza_valori,len(visualizza_valori)-1)




        dettaglio = dettaglio & RSex("tmpRichiesta") & vbtab & RSex("descrizioneMov") & vbtab & visualizza_valori & vbtab & RSex("dataRich") & vbtab & RSex("dataEvas") & vbtab & giorni_eva & vbtab & RSex("ubicazioneUBI") & vbtab & RSex("Cognome") & " " & RSex("Nome") & vbtab & RSex("PrimoDidescNota") & vbTab & RSex("prezzo") & vbcrlf
        
        'if RSex("codMov") = 19 then
        dettaglio_scansioni = dettaglio_scansioni & RSex("tmpRichiesta") & vbtab & RSex("descrizioneMov") & vbtab & visualizza_valori & vbtab & RSex("dataRich") & vbtab & RSex("dataEvas") & vbtab & giorni_eva & vbtab & RSex("ubicazioneUBI") & vbtab & RSex("Cognome") & " " & RSex("Nome") & vbtab & RSex("PrimoDidescNota") & vbTab & RSex("prezzo") & vbcrlf
        'end if
        RSex.movenext
    wend
else
    dettaglio = "Nessun movimento nel periodo selezionato"
end if

[Vincent.Zeno]

il database è access, vero?

se non ho letto letto male lo script...
qui si presenta la stranezza del campo "memo" stampato tramite recordset:
non si sa per quale motivo ma lo si può stampare solo una volta.

la soluzione al problema sta nell'inserire il valore in una variabile di comodo, esempio:

varPrimoDidescNota=RSex("PrimoDidescNota")
e ti stampi dove vuoi la variabile varPrimoDidescNota invece di RSex("PrimoDidescNota")

[abellos]

si access, ah ecco mi sembrava di essere scemo a leggere le due righe e non capire cosa cambiasse.
grazie

[Vincent.Zeno]

mi sembrava di essere scemo

non sei l'unico