[vb6] verificare se un' applicazione è attiva

[arcadia]

Ho un eseguibile fatto in c++ (trovato in rete) che mi elabora dei dati ed il risultato me lo scrive in output su un file di testo. Nello specifico mi apre una connessione verso un lettore smart-card e mi legge le LABEL della chiave privata(che mi servirà per firmare digitalmente) da una smart-card per la firma digitale.
Ora....se conoscessi c++ di questo eseguibile ne farei una dll da inserire in visual basic, ma non conosco c++ quindi non mi resta che leggere l' informazione che mi serve dal file .txt.

Come posso, in vb6, lanciare il .exe fatto in c++ (questo lo so), e aspettare finchè questa non abbia finito il suo compito...e solo allora andarmi a leggere questo file .txt?

[xegallo]

Private Const PROCESS_QUERY_INFORMATION = &H400
Private Const STATUS_PENDING = &H103&

Private Declare Function OpenProcess Lib "kernel32" _
    (ByVal dwDesiredAccess As Long, _
    ByVal bInheritHandle As Long, _
    ByVal dwProcessId As Long) As Long

Private Declare Function GetExitCodeProcess Lib "kernel32" _
    (ByVal hProcess As Long, lpExitCode As Long) As Long

Private Declare Function CloseHandle Lib "kernel32" _
    (ByVal hObject As Long) As Long

Private Sub ShellAndWait(sFile As String, Visualizzazione As Long)
Dim hProcess As Long
Dim ProcessId As Long
Dim CodExit As Long

    ProcessId = Shell(sFile, Visualizzazione)
    hProcess = OpenProcess(PROCESS_QUERY_INFORMATION, False, ProcessId)
    Do
        Call GetExitCodeProcess(hProcess, CodExit)
        DoEvents
    Loop While CodExit = STATUS_PENDING

    Call CloseHandle(hProcess)
End Sub

per usarla

call ShellAndWait("percorso tuo file", vbhide)

dopo di che puoi leggere tranquillamente il file perchè la funzione non esce finche il processo dell'eseguibile non è killato ti consiglio comunque di controllare che il file esista

[arcadia]

oh che bello, ti ringrazio