errore con function

**Rossella_75** · 14-03-2005, 10:51

ciao a tutti,

voi ci trovate un'errore a me sembra che non c'è ma non capisco perchè non mi funziona

codice:

function caricaFornitori() {
    dgFornitori.removeAll();
    caricoFornitore = new LoadVars();
    caricoFornitore.onLoad = function() {
        _root.totfornitori.text = "Totale Fornitori: "+this.totale;
        // creo l'Array che conterrà i dati
        var myArray:Array = new Array();
		trace(this.totale+ " - "+caricoFornitore);
        // ciclo i dati un numero di volte tante quanti saranno i risultati
        for (i=1; i<=this.totale; i++) {
            // assegno i dati caricati all'oggetto myArray[i]
            myArray[i] = new Object();
            myArray[i]["nID"] = _root.caricofornitore["ID"+i];
            myArray[i]["nfornitori"] = _root.caricoFornitore["fornitori"+i];
            myArray[i]["nindirizzo"] = _root.caricofornitore["indirizzo"+i];
            myArray[i]["ncitta"] = _root.caricofornitore["citta"+i];
            myArray[i]["ncap"] = _root.caricofornitore["cap"+i];
            myArray[i]["nprovincia"] = _root.caricofornitore["provincia"+i];
            myArray[i]["ntelefono"] = _root.caricofornitore["telefono"+i];
            myArray[i]["nfax"] = _root.caricofornitore["fax"+i];
            myArray[i]["ndata"] = _root.caricofornitore["data"+i];
            myArray[i]["npartitaiva"] = _root.caricofornitore["partitaiva"+i];
            dgFornitori.addItem({
				ID:myArray[i]["nid"],
				FORNITORE:myArray[i]["nfornitori"],
				INDIRIZZO:myArray[i]["nindirizzo"],
				CITTA:myArray[i]["ncitta"],
				CAP:myArray[i]["ncap"],
				PROVINCIA:myArray[i]["nprovincia"],
				TELEFONO:myArray[i]["ntelefono"],
				FAX:myArray[i]["nfax"],
				DATA:myArray[i]["ndata"],
				PARTITAIVA:myArray[i]["npartitaiva"]});
        }
    };
    caricoFornitore.load(_global.pathfile+"Search/listafornitori.php", caricoFornitore, "get");
}
caricaFornitori();

da php arrivano cosi

&totale=1&fornitori1=hjklhj&ID1=1&indirizzo1=jkhjh j&citta1=khkjh&cap1=0&provincia1=jk&telefono1=0&fa x1=0&data1=2005/2/14&partitaiva1=hjkhjjk

il datagrid

codice:

dgFornitori.columnNames = ["FORNITORE", "INDIRIZZO", "CITTA", "CAP"];
dgFornitori.getColumnAt(0).width = 200;
dgFornitori.getColumnAt(1).width = 300;
dgFornitori.getColumnAt(2).width = 200;
dgFornitori.getColumnAt(3).width = 100;
dgFornitori.getColumnAt(0).headertext = "FORNITORE";
dgFornitori.getColumnAt(1).headertext = "INDIRIZZO";
dgFornitori.getColumnAt(2).headertext = "CITTA";
dgFornitori.getColumnAt(3).headertext = "CAP";

l'unico che si riempie è fornitore gli altri rimangono vuoti

grazie :master:

**and80** · 14-03-2005, 11:14

non so se possa dipendere solo da quello, però sarebbe meglio dare la verifica all'onLoad in questo modo

codice:

dati = new LoadVars();
dati.onLoad = function(success){
     if (success){
          //azioni da eseguire
     } else {
          //messaggio d'errore
     }
}

**negatyve** · 14-03-2005, 11:20

Fai fare a questi dati un giro assurdo:

codice:

function caricaFornitori()
{
	var caricoFornitore:LoadVars = new LoadVars();
	caricoFornitore.onLoad = function()
	{
		_root.totfornitori.text = "Totale Fornitori: " + this.totale;
		trace(this.totale + " - " + caricoFornitore);
		dgFornitori.removeAll();
		dgFornitori.columnNames = ["FORNITORE", "INDIRIZZO", "CITTA", "CAP"];
		dgFornitori.getColumnAt(0).width = 200;
		dgFornitori.getColumnAt(1).width = 300;
		dgFornitori.getColumnAt(2).width = 200;
		dgFornitori.getColumnAt(3).width = 100;
		// ciclo i dati un numero di volte tante quanti saranno i risultati
		for (var i:Number = 1; i <= this.totale; i++) {
			// assegno i dati caricati all'oggetto myArray[i]
			var obj:Object = new Object();
			obj.ID = this["ID" + i];
			obj.FORNITORE = this["fornitori" + i];
			obj.INDIRIZZO = this["indirizzo" + i];
			obj.CITTA = this["citta" + i];
			obj.CAP = this["cap" + i];
			obj.PROVINCIA = this["provincia" + i];
			obj.TELEFONO = this["telefono" + i];
			obj.FAX = this["fax" + i];
			obj.DATA = this["data" + i];
			obj.PARTITAIVA = this["partitaiva" + i];
			dgFornitori.addItem(obj);
		}
	};
	caricoFornitore.load(_global.pathfile + "Search/listafornitori.php");
}
caricaFornitori();

**Rossella_75** · 14-03-2005, 11:25

ops.. grazie

quindi cosi va bene

codice:

import mx.controls.Alert;
// PREPARO IL DATAGRID
import mx.controls.gridclasses.DataGridColumn;
dgFornitori.rowHeight = 20;
dgFornitori.setStyle("alternatingRowColors", [0xFFFFFF, 0xEDEDED]);
dgFornitori.setSize(800, dgFornitori.rowHeight*10+dgFornitori.headerHeight);


function caricaFornitori()
{
	var caricoFornitore:LoadVars = new LoadVars();
	caricoFornitore.onLoad = function()
	{
		_root.totfornitori.text = "Totale Fornitori: " + this.totale;
		trace(this.totale + " - " + caricoFornitore);
		dgFornitori.removeAll();
		dgFornitori.columnNames = ["FORNITORE", "INDIRIZZO", "CITTA", "CAP"];
		dgFornitori.getColumnAt(0).width = 200;
		dgFornitori.getColumnAt(1).width = 300;
		dgFornitori.getColumnAt(2).width = 200;
		dgFornitori.getColumnAt(3).width = 100;
		// ciclo i dati un numero di volte tante quanti saranno i risultati
		for (var i:Number = 1; i <= this.totale; i++) {
			// assegno i dati caricati all'oggetto myArray[i]
			var obj:Object = new Object();
			obj.ID = this["ID" + i];
			obj.FORNITORE = this["fornitori" + i];
			obj.INDIRIZZO = this["indirizzo" + i];
			obj.CITTA = this["citta" + i];
			obj.CAP = this["cap" + i];
			obj.PROVINCIA = this["provincia" + i];
			obj.TELEFONO = this["telefono" + i];
			obj.FAX = this["fax" + i];
			obj.DATA = this["data" + i];
			obj.PARTITAIVA = this["partitaiva" + i];
			dgFornitori.addItem(obj);
		}
	};
	caricoFornitore.load(_global.pathfile + "Search/listafornitori.php");
}
caricaFornitori();

**negatyve** · 14-03-2005, 11:40

Si, va bene, e considera anche il giusto suggerimento di and80 per una questione di usabilità.

**Rossella_75** · 14-03-2005, 11:45

Originariamente inviato da negatyve
Si, va bene, e considera anche il giusto suggerimento di and80 per una questione di usabilità.

certo!! grazie and80

Nega ho pensato di fare una cosina se non è troppo complessa
al click posso far aprire il componente Window adesso io faccio cosi per recuperare tutti gli altri valori

codice:

// creo un nuovo oggetto in modo che quando seleziono un dato dal DataGrid
// assegno i valori alle variabili
var gestioneFornitore = new Object();
gestioneFornitore.change = function(event) {
    // Utilizzo la tipizzazione forte per creare le variabili
    // da assegnare succesivamente database
    _global.IDFornitore = event.target.selectedItem.ID;
    // 
    _global.Fornitore = event.target.selectedItem.FORNITORE;
    // 
    _global.Indirizzo = event.target.selectedItem.INDIRIZZO;
    // 
    _global.Citt = event.target.selectedItem.CITTA;
    // 
    _global.Cap = event.target.selectedItem.CAP;
    // 
    _global.PR = event.target.selectedItem.PROVINCIA;
    // 
    _global.Telefono = event.target.selectedItem.TELEFONO;
    // 
    _global.Fax = event.target.selectedItem.FAX;
    // 
    _global.Data = event.target.selectedItem.DATA;
	//
	_global.Partita_IVA = event.target.selectedItem.PARTITAIVA;
    // 
	dettaglio.text = 
				"ID: " + _global.IDFornitore+
				" Indirizzo: " + _global.Indirizzo +
				" Città: " + _global.Citt +
				" Cap: " + _global.Cap +
				" PR: " + _global.PR +
				" Telefono: " +	_global.Telefono +
				" Fax: " + _global.Fax +
				" Partita IVA: " +_global.Partita_IVA
    // 
    modifica.visible = true;
    inserimento.visible = true;
	assegna.visible = true;
};
dgFornitori.addEventListener("change", gestioneFornitore);

ma per aprire il componente??

grazie ad entrambi cmq

**negatyve** · 14-03-2005, 13:07

Aprire il component Window con che contenuti?

**Rossella_75** · 14-03-2005, 13:19

no pultroppo ho grosse difficoltà con questo componente non riesco ad usarlo affatto!!! e da quanto ho il 2004 Prof che ci provo senza risultati

mi faresti un'esempio (sempre se non ti crea problemi)

**negatyve** · 14-03-2005, 13:30

codice:

import mx.controls.Alert;
import mx.controls.gridclasses.DataGridColumn;

dgFornitori.rowHeight = 20;
dgFornitori.setStyle("alternatingRowColors", [0xFFFFFF, 0xEDEDED]);
dgFornitori.setSize(800, dgFornitori.rowHeight * 10 + dgFornitori.headerHeight);

function caricaFornitori()
{
	var caricoFornitore:LoadVars = new LoadVars();
	caricoFornitore.onLoad = function()
	{
		_root.totfornitori.text = "Totale Fornitori: " + this.totale;
		trace(this.totale + " - " + caricoFornitore);
		dgFornitori.removeAll();
		dgFornitori.columnNames = ["FORNITORE", "INDIRIZZO", "CITTA", "CAP"];
		dgFornitori.getColumnAt(0).width = 200;
		dgFornitori.getColumnAt(1).width = 300;
		dgFornitori.getColumnAt(2).width = 200;
		dgFornitori.getColumnAt(3).width = 100;
		// ciclo i dati un numero di volte tante quanti saranno i risultati
		for (var i:Number = 1; i <= this.totale; i++) {
			// assegno i dati caricati all'oggetto myArray[i]
			var obj:Object = new Object();
			obj.ID = this["ID" + i];
			obj.FORNITORE = this["fornitori" + i];
			obj.INDIRIZZO = this["indirizzo" + i];
			obj.CITTA = this["citta" + i];
			obj.CAP = this["cap" + i];
			obj.PROVINCIA = this["provincia" + i];
			obj.TELEFONO = this["telefono" + i];
			obj.FAX = this["fax" + i];
			obj.DATA = this["data" + i];
			obj.PARTITAIVA = this["partitaiva" + i];
			dgFornitori.addItem(obj);
		}
		dgFornitori.addEventListener("change", gestioneFornitore);
	};
	caricoFornitore.load(_global.pathfile + "Search/listafornitori.php");
}
var gestioneFornitore = new Object();
gestioneFornitore.change = function(event)
{
	var selected:Object = event.target.selectedItem;
	_global.IDFornitore = selected.ID;
	_global.Fornitore = selected.FORNITORE;
	_global.Indirizzo = selected.INDIRIZZO;
	_global.Citt = selected.CITTA;
	_global.Cap = selected.CAP;
	_global.PR = selected.PROVINCIA;
	_global.Telefono = selected.TELEFONO;
	_global.Fax = selected.FAX;
	_global.Data = selected.DATA;
	_global.Partita_IVA = selected.PARTITAIVA;

	var det:String =	"ID: " + _global.IDFornitore + "\n" + 
						"Indirizzo: " + _global.Indirizzo +  "\n" + 
						"Città: " + _global.Citt +  "\n" + 
						"Cap: " + _global.Cap +  "\n" + 
						"PR: " + _global.PR +  "\n" + 
						"Telefono: " + _global.Telefono +  "\n" + 
						"Fax: " + _global.Fax +  "\n" + 
						"Partita IVA: " + _global.Partita_IVA;
	Alert.show(det, "Elemento selezionato", Alert.OK);
	dettaglio.text = det;
	modifica.visible = true;
	inserimento.visible = true;
	assegna.visible = true;
};
caricaFornitori();

**Rossella_75** · 14-03-2005, 13:54

grazie mille è perfetto adesso lo studio poi se ho dubbi ti faccio un fischio

Discussione: errore con function

Strumenti discussione

Ricerca discussione

Visualizza

errore con function

Permessi di invio