NetGetDCName VB 6.0 Networking

[meronet]

Ciao a tutti
Qualcuno sa per caso
quale riferimento o componente bisogna
inserire per utilizzare la funzione
NetGetDCName.


Ultimamente mi sto appasionando
di programmazione client\server...
se conoscete qualche sito...
mi farebbe piacere condividerlo !!!

[xegallo]

Originariamente inviato da meronet
Ciao a tutti
Qualcuno sa per caso
quale riferimento o componente bisogna
inserire per utilizzare la funzione
NetGetDCName.

nessuno è un' API della Netapi32.dll

Private Declare Function NetGetDCName Lib "netapi32.dll" _
    (ServerName As Any, DomainName As Any, lpBuffer As Long) As Long
Private Declare Function NetApiBufferFree Lib "netapi32.dll" _
    (ByVal pBuffer As Long) As Long
Private Declare Sub CopyMem Lib "kernel32.dll" Alias "RtlMoveMemory" _
    (pTo As Any, uFrom As Any, ByVal lSize As Long)
Private Declare Function lstrlenW Lib "kernel32.dll" _
    (ByVal lpString As Long) As Long


Private Const NERR_Success As Long = 0&


Private Function PtrToString(lpwString As Long) As String
    
    Dim Buffer() As Byte
    Dim nLen As Long

    If lpwString Then
        nLen = lstrlenW(lpwString) * 2
        If nLen Then
            ReDim Buffer(0 To (nLen - 1)) As Byte
            CopyMem Buffer(0), ByVal lpwString, nLen
            PtrToString = Buffer
        End If
    End If
End Function

Public Function GetPDCName(ComputerName As String, DomainName As String) As String
    Dim bComputer() As Byte
    Dim bDomain() As Byte
    Dim ret As Long
    Dim lpBuffer As Long
    Dim s As String

    If Trim(ComputerName) = "" Then
        
        bComputer = vbNullChar
    Else
        
        If InStr(ComputerName, "\\") = 1 Then
            bComputer = ComputerName & vbNullChar
        Else
            bComputer = "\\" & ComputerName & vbNullChar
        End If
    End If
    If Trim(DomainName) = "" Then
        
        bDomain = vbNullChar
    Else
        bDomain = DomainName & vbNullChar
    End If
    ret = NetGetDCName(bComputer(0), bDomain(0), lpBuffer)
    If ret = NERR_Success And lpBuffer Then
        s = PtrToString(lpBuffer)
    End If
    If lpBuffer Then
        Call NetApiBufferFree(lpBuffer)
    End If
    GetPDCName = s
End Function

per usarla

   debug.print GetPDCName ("nome computer", "nome dominio")

certo che una passione impegnativa per uno che non distingue un'api quando la vede

[meronet]

non mi appare nulla....

[xegallo]

Originariamente inviato da meronet
non mi appare nulla....

si
sei stato molto chiaro nell'esposizione del problema, sarà una gioia per me cercare di indovinare che problema hai, perchè il codice di per se funziona

[meronet]

ho inserito tutto in una modulo
e poi il code del debug in un pulsante
ma non mi appare nulla come se
caricasse valore vuoto


Ho trovato anche questo link
http://www.developer.be/index.cfm/fu...GroupID/88.htm

Interessante ma se richiamo la funzione getusername
mi dà errore !!!

[xegallo]

ma tu ce l'hai una rete con un domain server?

[meronet]

risolto
con questa funzione :

code.
-----------------------------------------------------------------
Private Declare Function GetUserName Lib "advapi32.dll" Alias _
"GetUserNameA" (ByVal lpBuffer As String, ByRef nSize As Long) As Long
Function GetUser()
Dim Ret As Long
Dim UserName As String
Dim Buffer As String * 25
Ret = GetUserName(Buffer, 25)
UserName = Left$(Buffer, InStr(Buffer, Chr(0)) - 1)
MsgBox (UserName)
End Function
------------------------------------------------------------------
non metto in dubbio il codice che hai postato
sicuramente facevo qualche errore io ad inserirlo corretamente
visto il fatto che da poco sto studiando questo mondo ....
Se per caso conosci qualche sito in italiano dove posso appprofondire questi concetti ....gradirei
Saluti a tutti
ed un ringraziamento particolare a tutti i collaboratori di html
che grazie al loro apporto quotidiano fatto di piccoli consigli
ci aiutano tantissimo e che dire
grazia anche a chi inventò il forum....

bella l' informatica ma fatta così
è ancora più carina

[xegallo]

si ma questa funzione è tutta un'altra cosa da quello che hai chiesto!

GetUserName recupera il nome utente attualmente loggato nella macchina in cui gira il programma
mentre NetGetDCName recupera il nome del server di dominio di una determinata macchina

[meronet]

Ok mi sta bene quel che mi dici
e vorrei approfondire la discussione
ma mi mancano degli elementi
forse giusto per capirci
il codice che hai postato funziona su una macchina server ?

[xegallo]

Originariamente inviato da meronet

il codice che hai postato funziona su una macchina server ?

no quel codice funziona su un qualsiasi client o server di dominio e serve proprio per ricavare il nome del server di dominio.