creare db access senza access

[videoD]

Ciao a tutti,

sto cercando un software free, opensource che mi permetta di creare db access..esiste?

Ho provato dbase ma non riesco a capire come espore il db creato con estensione .mdb ammesso che lo faccia...

Grazie

[akinet]

<%
' impostiamo il path ed il nome del db da creare...
path_db = "\mdb-database\nomedb.mdb"

' creiamo l'oggetto ADOX e quindi eseguiamo la creazione del file database...
Set objAdox = Server.CreateObject("ADOX.Catalog")
objAdox.Create "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(path_db)

' creiamo l'oggetto che ci permetterà di inserire una tabella nel db...
Set objAdoxTable = Server.CreateObject("ADOX.Table")

' il nome della tabella...
objAdoxTable.Name = "nomeTabella"

' inseriamo il campo Contatore...
Set objAdoxColumn = Server.CreateObject("ADOX.Column")
Set objAdoxColumn.ParentCatalog = objAdox
With objAdoxColumn
.Type = adInteger
.Name = "ID"
.Properties("Autoincrement") = True
End With

' eseguiamo la creazione del campo Contatore...
objAdoxTable.Columns.Append objAdoxColumn
Set objAdoxColumn = Nothing

' aggiungiamo gli altri campi...
objAdoxTable.Columns.Append "campo_data", adDate, 7
objAdoxTable.Columns.Append "campo_Titolo", adVarWChar, 255
objAdoxTable.Columns.Append "campo_Testo", adLongVarWChar
objAdoxTable.Columns.Append "campo_Immagine", adVarWChar, 255
objAdoxTable.Columns.Append "campo_autore", adVarWChar, 255
objAdoxTable.Columns.Append "campo_email", adVarWChar, 50

' impostiamo il campo contatore come chiave primaria...
objAdoxTable.Keys.Append "PK_CampoID", 1, "ID"

' eseguiamo la creazione degli altri campi...
objAdox.Tables.Append objAdoxTable

Set objAdoxTable = Nothing
Set objAdox = Nothing
%>

[videoD]

mi hai letto nel pensiero, pensavo anche io ad un modo alternativo...poco comodo ma vabeh....

grazie

[videoD]

e come pws cosa mi consigli?..Io ho XP e non posso installarmi il psw del 98, xp non cel' ha...che fare?

Apache supporta anche asp?...Qualcuno sa come configurarlo per tale scopo?

Grazie