Access....

[SirSeymour]

Salve a tutti.
Per problemi di dimensioni massime di server, mi trovo a dover cercare di snellire il mio database che fa di supporto ad un guestbook-messaggeria. Quando vado a cancellare per esempio le 200 discussioni + vecchie, le dimensioni del database nn diminuiscono, anzi registrano un piccolo aumento.....ora a meno che nn sia pazzo, nn trovo niente di logico in questo.
Qualkuno per piacere sa aiutarmi?
Grazie.

[vives]

Devi compattare il database ...

[SirSeymour]

compattare?....cioè?

[Shagrat]

o lo fai con una paginetta asp:

<%
'compatta il database dbname
Function CompactDB(dbname, password)
  Dim dbpath
  dbpath = Server.MapPath(dbname)

  Dim cnfrom, cnto
  cnfrom = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&dbpath
  cnto = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&dbpath&".temp"

  'se il db è protetto da password...
  If password<>"" Then
    cnfrom = cnfrom&";Jet OLEDB:Database Password="&password
    cnto = cnto&";Jet OLEDB:Database Password="&password
  End If

  Dim engine
  Set engine = Server.CreateObject("JRO.JetEngine")
  'compatta il database
  engine.CompactDatabase cnfrom, cnto

  Dim fso
  Set fso = Server.CreateObject("Scripting.FileSystemObject")
  'il db originale viene eliminato
   fso.DeleteFile dbpath
  'il db appena compresso viene rinominato col nome del db originale
  fso.MoveFile dbpath&".temp", dbpath

  Set fso = nothing
  Set engine = nothing
End Function

'chiamo la funzione per la compressione del database
Call CompactDB("utenti.mdb", "")

Response.Write("Il DataBase è stato compattato con successo!")
%>

oppure lo scarichi, lo apri con access

Strumenti->utilità database->compatta e ripristina database

e poi lo rimetti online

[vives]

Puoi farlo via web (ma ci vuole l'apposito script) o scaricare il database, aprirlo con Access e andare in Strumenti > Utilità database > Compatta e ripristina database.

Il database tornerà bello e snello, quasi come nuovo ...

[SirSeymour]

e poi ci si chiede perchè html.it è il num1 nel web...risp sempre utili ed immediate!
complimenti!...siete stati fondamentali!...grazie ancora.

[Shagrat]

prego