Cassaforte con combinazione

[Diurno87]

salve a tutti, volevo sapere in che modo è possibile creare una cassaforte a sequenza numerica, tipo di 4 cifre, con il tastierino a destra da usare per immettere le vari cifre.

praticamente ho in testa di creare questa cassaforte su 2 frame, al primo è kiusa e al secondo è aperta, xò non so come fare per far si che immettendo una corretta sequenza di cifre questa si apra...

[Chimira]

Puoi fare un controllo ad ogni pressione del tastierino e vedere se le quattro cifre unite corrispondono ad una variabile che contiene la combinazione esatta.

[Diurno87]

eh si questo l'avevo pensato, ma alla variabile come imposto la combinazione? cioè la sequenza anche temporale dei 4 numeri, senno basta premerli a caso e si apre.

[KillerWorm]

Ciao

Dovrai mettere una variabile della sequenza esatta, ad esempio nel primo frame.

var combinazioneEsatta = 1234 

Quindi avrai una casella di testo imput a cui associ un'altra variabile ad esepio "combinazioneInserita"

Magari ti conviene mettere anche un pulsante "OK", a cui dai nome istanza "ok"

Ora ti basterà fare un controllo dell'uguaglianza delle due variabili che ti manda al frame 2 se queste risultano uguali.

ok.onRelease = function() {
    if (combinazioneEsatta == combinazioneInserita) {
        gotoAndStop(2);
    }
}; 

Aperta la cassaforte!!!

[KillerWorm]

Ho letto meglio la richiesta.

In pratica non devi utilizzare una casella di imput..

Allora elimina tutto e inserisci semplicemente questo script al primo frame:

stop();
combinazioneEsatta = 1234;
combinazioneInserita = "";
var keyListener:Object = new Object();
// evento per la pressione dei tasti
keyListener.onKeyDown = function() {
    //aggiungi il valore dell'ultimo tasto premuto
    combinazioneInserita += chr(Key.getAscii());
    // se la lunghezza della stringa inserita è >= a quella totale
    if (combinazioneInserita.length>=combinazioneEsatta.toString().length) {
        // se la combinazione risulta esatta
        if (combinazioneInserita == combinazioneEsatta) {
            gotoAndStop(2);
            // altrimenti ripulisci la variabile
        } else {
            combinazioneInserita = "";
        }
    }
};
Key.addListener(keyListener); 

Ho commentato riga per riga così si può capire il procedimento utilizzato.

In questo esempio, dopo la pressione di 4 tasti, viene fatto il controllo, se la combinazione è giusta va al frame 2 altrimenti azzera la variabile che contiene la sequenza dei tasti premuti

[Diurno87]

mmm ma aspetta praticamente come hai scritto tu i numeri vengono impressi premendo i tasti numerici della tasteria?xkè a me servirebbe che i tasti siano disegnati sullo stage e bisogna premerli con il mouse ^^

[KillerWorm]

ah ecco.. ancora una volta non avevo capito..

con il tastierino a destra da usare per immettere le vari cifre.

Pensavo ti riferissi al testierino numerico della tastiera, e che dovessi interagire direttamente da tastiera..

Mentre in pratica tu hai un tastierino disegnato sul tuo filmato...

Allora crei 10 bottoni con nome istanza "btn0", "btn1", "btn2", ecc da 0 a 9

quindi utilizzi questo script:

stop();
_root.combinazioneEsatta = "0123";
_root.combinazioneInserita = "";
for (var id = 0; id<=9; id++) {
    // associa un indice ad ogni pulsante
    _root["btn"+id].id = id;
    // quando clicco un pulsante
    _root["btn"+id].onRelease = function() {
        with (_root) {
            // aggiungi l'indice del pulsante cliccato
            combinazioneInserita += this.id.toString();
            // se la lunghezza della stringa inserita è >= a quella totale
            if (combinazioneInserita.length>=combinazioneEsatta.length) {
                // se la combinazione risulta esatta
                if (combinazioneInserita == combinazioneEsatta) {
                    // vai al frame 2
                    gotoAndStop(2);
                    // altrimenti ripulisci la variabile
                } else {
                    combinazioneInserita = "";
                }
            }
        }
    };
} 

E apri la cassaforte