Download spezzando il file con chunk

[fosforo]

Ciao
Sto utilizzando uno script trovato nel forum per downlodare file di grandi dimensioni.

Da quello che ho capito utilizzando CHUNK si spezza il file in piccoli pezzetti e lo si downloda
Esistono limiti di peso/file?
Sto cercando di spostare un file di 10GB ma dopo un po IE mi va in errore.

Grazie

[optime]

io uso questo

<%

Session.Timeout = 20

	'8***********************************************8
	' Jason Withrow - For ASP101 July 2001
	' This page forces the save as dialogue to prevent
	' files from being opened in the browser.
	'
	' jwithrow@mediaone.net
	'8***********************************************8


Response.Buffer = True

Dim strFilePath, strFileSize, strFileName

' added by edc 7.1.2003

	If Session("FileName") = "" Then
		Response.Redirect "default.asp"
	End If

	Dim oFso, oFile

	strFilePath = Server.MapPath(Session("FileName"))
	Set oFso = CreateObject("Scripting.FileSystemObject")
	Set oFile = oFso.GetFile(strFilePath)
	strFileName = UCase(oFile.Name)
	strFileSize = CLNG(oFile.size)
	Set oFile = Nothing
	Set oFso = Nothing

' end add

Const adTypeBinary = 1

'strFilePath = Request.QueryString("File")
'strFileSize = Request.QueryString("Size")
'strFileName = Request.QueryString("Name")

Response.Clear

'8*******************************8
' Requires MDAC 2.5 to be stable
' I recommend MDAC 2.6 or 2.7
'8*******************************8
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile strFilePath

strFileType = lcase(Right(strFileName, 4))
    
	' Feel Free to Add Your Own Content-Types Here
    Select Case strFileType
        Case ".asf"
            ContentType = "video/x-ms-asf"
        Case ".avi"
            ContentType = "video/avi"
        Case ".doc"
            ContentType = "application/msword"
        Case ".zip"
            ContentType = "application/zip"
            ContentType = "application/x-zip-compressed"
        Case ".xls"
            ContentType = "application/vnd.ms-excel"
        Case ".gif"
            ContentType = "image/gif"
        Case ".jpg", "jpeg"
            ContentType = "image/jpeg"
        Case ".wav"
            ContentType = "audio/wav"
        Case ".mp3"
            ContentType = "audio/mpeg3"
        Case ".mpg", "mpeg"
            ContentType = "video/mpeg"
        Case ".rtf"
            ContentType = "application/rtf"
		Case ".htm", "html"
            ContentType = "text/html"
		Case ".asp"
            ContentType = "text/asp"
        Case Else
            'Handle All Other Files
            ContentType = "application/octet-stream"
    End Select
	
	Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
	Response.AddHeader "Content-Length", strFileSize
	' In a Perfect World, Your Client would also have UTF-8 as the default 
	' In Their Browser
	Response.Charset = "UTF-8"
	Response.ContentType = ContentType
	
	Do While Not objStream.EOS
		Response.BinaryWrite objStream.Read(8192)	'	1024*8
		Response.Flush
	Loop

objStream.Close
Set objStream = Nothing

%>


<SCRIPT LANGUAGE='JavaScript'>
{
	window.close();
}
</SCRIPT>


x</p>

[fosforo]

Grazie Optime ma questo script, da quello che capisco, forza il download del file senza che il browser lo apra.
Il mio problema sono i file pesanti.
Per questo chiedo informazioni sul funzionamento di CHUNK.

[optime]

provalo prima di dire che non va bene...