Preloader con mc

[whisher]

Ciao.
Ho adattato il codice di Essential AS3

package com{ 
    import flash.display.*; 
    import flash.net.URLRequest; 
    import flash.events.*; 
    import flash.text.*; 
    public class DataLoader extends Sprite { 
        public static const ON_LOAD_COMPLETE:String="onLoadComplete"; 
        private var _loader:Loader;// The asset loader 
        private var progressOutput:ClipPreLoader;// The text field in which 
        // to display load progress 
        // Constructor 
        public function DataLoader(contentData:String) { 
            _loader=new Loader (); 
            // Register for events 
            _loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS,progressListener); 
            _loader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeListener); 
            _loader.contentLoaderInfo.addEventListener(Event.INIT,initListener); 
            _loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR,ioErrorListener); 
            // Create the progress indicator 
            createProgressIndicator(); 
            // Start the load operation 
            _load(new URLRequest(contentData)); 
        } 
        private function createProgressIndicator():void { 
            progressOutput = new ClipPreLoader(); 
            /* TEST */ 
            progressOutput.x= 200; 
            progressOutput.y= 400; 
        } 
        private function _load(urlRequest:URLRequest):void { 
            _loader.load(urlRequest); 
            if (! contains(progressOutput)) { 
                addChild(progressOutput); 
            } 
             
        } 
        // Listener invoked whenever data arrives 
        private function progressListener(e:ProgressEvent):void { 
            // Update progress indicator. 
            var perc:Number = e.bytesLoaded / e.bytesTotal; 
            var fr:Number = Math.ceil(perc*100); 
            progressOutput.gotoAndPlay(fr); 
        } 
        private function initListener(e:Event):void { 
            addChild(_loader.content);// Add loaded asset to display list 
        } 
        // Listener invoked when the asset has been fully loaded 
        private function completeListener(e:Event):void { 
            // Just in case  
            progressOutput.play(); 
            // Remove progress indicator. 
            removeChild(progressOutput); 
            dispatchEvent(new Event(ON_LOAD_COMPLETE)); 
        } 
        private function ioErrorListener(e:IOErrorEvent):void { 
            trace("LOAD ERROR"); 
        } 
    } 
} 

Il swf viene caricato ma non
si vede il preloader.
Non riesco a capire dove possa
essere lo sbaglio.
(Può darsi benissimo che mi perda qc)
Help me, please

PS
La mc del preloader è formata
da 100 frames con lo stop()
all'inizio e alla fine.