[AS3] Disporre orizzontalmente testo di grandezza variabile

[bikfellas]

Salve,
mi sto cimentando nell'uso di AS3 e mi sono imbattuto in un problemino stupido, ma che per ora non trova soluzione.
ho creato dinamicamente un un menu che si dovrebbe disporre in orizzontale, con ogni voce distanziata dalla precedente di un tot di pixel.
In AS2 facevo una cosa del genere:

var menuHolder:MovieClip = this.createEmptyMovieClip("menuHolder", 0); 

for (i=0; i<menu.length; i++) { 
//menu è un array che contiene tutte le voci di menu 

var m:MovieClip = menuHolder.createEmptyMovieClip("m"+i, i); 
if (i>0) { 
    menuHolder["m"+i]._x = menuHolder["m"+(i-1)]._x+menuHolder["m"+(i-1)]._width+10; 
} 
} 

e così non c'erano problemi...

ora...come faccio la stessa cosa con AS3?
ho provato ad assegnare un nome ad ogni istanza ed a refenziarla con un parent, ma non funzia...

Qualcuno sa darmi una dritta?

Grazie

[whisher]

package com.w.display{
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    public class Tab extends Sprite {
        public static var _pos=0;
        private var _item:Object;
        private var _href:String;
        private var _label:TextField;
        public function Tab(item:Object) {
            _item=item;
            if (_item.height===undefined) {
                _item.width=100;
                _item.height=20;
                _item.alpha=1;
                _item.ellipseWidth=5;
                _item.color=0xFFFFFF;
            }
            _setLabel();
            _setTab();
            
        }
        private function _setLabel():void {
            _label = new TextField();
            _label.autoSize=TextFieldAutoSize.LEFT;
            _label.background=false;
            _label.border=false;
            _label.name="label_txt";
            _label.x=5;
            _label.y=0;
            _label.selectable=false;

            var format:TextFormat = new TextFormat();
            format.font="Verdana";
            format.color=0xFF0000;
            format.size=10;
            format.underline=true;

            _label.defaultTextFormat=format;

            _label.text=_item.label;



        }
        private function _setTab():void {
            _href=_item.href;
            name=_item.name;
            graphics.beginFill( _item.color, _item.alpha );
            graphics.drawRoundRect( 0, 0, _item.width,_item.height, _item.ellipseWidth);
            graphics.endFill();
            buttonMode=true;
            mouseChildren=false;
            
            addChild( _label);
            
        }
        public function get href():String {
            return _href;
        }
    }
} 

Possibile modo

[Kaneda81]

Io farei così:

var menu:Array = ["home", "chi siamo", "prodotti", "contatti"];

var menuHolder:MovieClip = new MovieClip();
addChild(menuHolder);

for (var i:int = 0; i<menu.length; i++)
{
    var tf:TextField = addTf(menu[i]);
    var mc:MovieClip = addMc(tf.width, tf.height);
    mc.addChild(tf);
    menuHolder.addChild(mc);
    
    try {
        menuHolder.getChildAt(i).x = menuHolder.getChildAt(i-1).x + menuHolder.getChildAt(i-1).width + 10;
    } catch (e:Error) {};
    
}

function addTf(testo:String):TextField
{
    var tf:TextField = new TextField();
    tf.autoSize = TextFieldAutoSize.LEFT;
    tf.text = testo;
    
    return tf;
}

function addMc(w:Number, h:Number):MovieClip
{
    var mc:MovieClip = new MovieClip();
    mc.graphics.beginFill(0xCCCCCC, 1);
    mc.graphics.drawRect(0, 0, w, h);
    
    return mc;
} 

Ovviamente se i bottoni del menu li hai già devi solo usare il ciclo con i tuoi bottoni, senza crearli a runtime.

[bikfellas]

fantastico!!!
ora provo con entrambi i metodi e poi vi fo sapere...

per ora il GRAZIE è d'obbligo!

[nuovobuio]

mi intrometto

ciao kaneda, nel tuo esempio (utilissimo) perchè mi da errore se aggiungio un trace al catch dopo il posizionamento con getChild?

        } catch (e:Error) {//
//            trace("Si è verificato un errore: " + e.message);
//            return
        } 

Si è verificato un errore: Error #2006: L'indice fornito è fuori intervallo. 

[Kaneda81]

Perchè il primo indice è fuori intervallo, dato che stai cercando di ricavare l'oggetto alla depth -1. menuHolder.getChildAt(i-1) al primo giro di for vale 0 - 1.
Al posto che try / catch puoi mettere un'if per controllare che sia > 0, come ti pare.