[VB6] Non fare eseguire righe di codice al programma

[Elena85]

Ciao a tutti!
E' possibile non fare eseguire alcune righe di codice al programma?

Private Sub lstLotto_Click()

Dim i As Integer

'Quando si seleziona un codice lotto, devo popolare la ListBox lstFile2...
If lstLotto.ListIndex <> -1 Then

    'Recupero indice del file selezionato e deseleziono tutti gli altri...
    Dim indice As Integer
    indice = lstLotto.ListIndex
    
    For i = 0 To lstLotto.ListCount - 1
        
        If i <> indice Then
            lstLotto.Selected(i) = False
        Else
            lstLotto.Selected(i) = True
        End If
        
    Next
    
End If

.....

End sub

Nel codice che ho postato, quando viene eseguita la riga di codice

lstLotto.Selected(i) = True

il programma non passa alla riga successiva, ma richiama la sub lstLotto.Click() e quindi ricomincia!

Come posso evitarlo?
Grazie mille!

[oregon]

Ma cosa stai tentando di fare con quel codice?

[Elena85]

Ho una listBox a singola selezione con style impostato su checkbox...
Quindi se l'utente clicca su una voce della listBox, devo anche selezionarla (mettere la spunta nella checkbox)...
Quindi devo inserire dei dati nel db....

Però, quando mette la spunta, mi richiama la sub...
Non so se mi sono spiegata....

[oregon]

Ma a cosa ti serve la checkbox ? Non ti basta selezionare la voce ??

[Elena85]

A me basterebbe!!
Ma il programma non è per me e vogliono la checkbox...

[gibra]

Prova così, aggiungi:

    Static bDone as Boolean
    If bDone Then Exit Sub

all'inizio della routine


Prima del ciclo For metti

    bDone = True

Prima di End Sub metti

    bDone = False

per ristabilire la situazione alla normalità

[oregon]

Mah ... comunque prova così (cambiando il nome della lista)

Private Sub List1_Click()
    Static updateActive As Boolean
    
    If Not updateActive Then
        Dim i As Integer
        
        If List1.ListIndex <> -1 Then
            updateActive = True
            
            Dim oldsel As Integer
            oldsel = List1.ListIndex
            
            For i = 0 To List1.ListCount - 1
                List1.Selected(i) = False
            Next
            
            List1.Selected(oldsel) = True
            updateActive = False
        End If
    End If
End Sub

EDIT: più o meno come ha detto Giorgio ...

[Elena85]

Grazie a tutti e due!
Adesso provo!

[Elena85]

Perfetto!!
Funziona! Grazie mille!