[vb6] allineare colonne in un combobox

[afrappe]

ho la necessita di inserire delle voci conposte da piu colonne in un combo box ed allinearle,

del tipo

'esatto
alessio  20/08/77
luca     10/04/69

'errato
alessio  20/08/77
luca 10/04/69

e cosi dicendo tenendo l'allineamento tra le colonne, ora ho pensato di creare una stringa di lunghezza fissa e andate a sottrarre di volta in volta i caratteri necessari alla voce corrente e aggiungerli sotto forma di spazi alla stessa, ma avete qualche altro suggerimento?

[xegallo]

Public Function PadL(s As Variant, n As Integer) As String
' Allinea a sinistra
'   INPUT: variant:  stringa da riempire
'          integer:  totale lunghezza stringa
'   ESEMPIO: PadL("Pippo", 10) = "Pippo     "
        
    s = CStr(s)
    If Len(s) >= n Then
        PadL = Left$(s, n)
    Else
        PadL = s & Space(n - Len(s))
    End If
    
End Function

Public Function PadR(s As Variant, n As Integer) As String
' Allinea a destra
'   INPUT: variant:  stringa da riempire
'          integer:  totale lunghezza stringa
'   ESEMPIO: PadR("Pippo", 10) = "     Pippo"
    
    s = CStr(s)
    If Len(s) >= n Then
        PadR = Left$(s, n)
    Else
        PadR = Space(n - Len(s)) & s
    End If

End Function

Public Function PadC(s As Variant, n As Integer) As String
' Allinea a sinistra
'   INPUT: variant:  stringa da riempire
'          integer:  totale lunghezza stringa
'   ESEMPIO: PadC("Pippo", 10) = "  Pippo   "
'
        
    s = CStr(s)
    If Len(s) >= n Then
        PadC = Left$(s, n)
    Else
        If (n - Len(s)) Mod 2 = 0 Then
            PadC = Space((n - Len(s)) \ 2) & s & Space((n - Len(s)) \ 2)
        Else
            PadC = Space((n - Len(s)) \ 2) & s & Space((n - Len(s)) \ 2) & " "
        End If
    End If
    
End Function

alla fine basta fare


combo1.additem padl("pippo", 10) & "01/01/05"

[afrappe]

hai capito che gran personaggio è sto moderatore
grazieeeee

[Jupy64]

Ciao, il tutto funziona se usi un font non proporzionale...tipo Courier o Courier New, altrimenti non ti verrà mai incolonnato.

[afrappe]

grazie della dritta,