richiamo funzione ma problema con condizione if...

[scmatteo]

Salve ragazzi,
ho un problema che non riesco a risaolvere da tempo, e ora mi sono deciso a postare il problema:

ho un menu SELECT che viene da popolato richiamando una funzione che mi tira fuori dei dati da una tabella:

FUNCTION getCategorie()
	SQLCategorie= "SELECT * FROM categorie ORDER BY Nominativo ASC"
	set rsDBCategorie=Server.CreateObject("ADODB.Recordset")
	rsDBCategorie.Open SQLCategorie, cnn, 1, 3
	
		if not rsDBCategorie.eof then
			do while not rsDBCategorie.eof
					if request("vIDCategoria")=rsDBCategorie("IDCategoria") then
						strHTML=strHTML & "<option value='" & rsDBCategorie("IDCategoria") & "' selected>" & rsDBCategorie("Nominativo") & "</option>" & vbCrLf
					else
						strHTML=strHTML & "<option value='" & rsDBCategorie("IDCategoria") & "'>" & rsDBCategorie("Nominativo") & "</option>" & vbCrLf
					end if
				rsDBCategorie.movenext
			Loop
		else		
					strHTML=strHTML & "<option value='0'>Nessuna categoria nel database</option>" & vbCrLf
		end if

		 getCategorie = strHTML


	rsDBCategorie.Close
	Set rsDBCategorie = nothing
END FUNCTION

ora vengo al dunque:
quando si verifica l'evento onChange() dal menu tendina mi viene inviato il form e quindi mi ritrovo un URL del tipo miapagina.asp?vIDCategoria=13

nella funzione ho una condizione:

if vIDCategoria=rsDBCategorie("IDCategoria") then
'response.write "si"
strHTML=strHTML & "<option value='" & rsDBCategorie("IDCategoria") & "' selected>" & rsDBCategorie("Nominativo") & "</option>" & vbCrLf

che mi verifica se vIDCategoria dell'url è uguale a IDCAtegoria del record nel recordset e mi tiene selezionata la option dal menù tendina...

ma non mi funziona.... come mai ragazzi?

[Roby_72]

if CStr(request("vIDCategoria")) = CStr(rsDBCategorie("IDCategoria")) then

Roby

[scmatteo]

Originariamente inviato da Roby_72

if CStr(request("vIDCategoria")) = CStr(rsDBCategorie("IDCategoria")) then

Roby

in effetti ho risolto proprio ora... era il cint()


grazie