Utenti on line

[fantamieru]

Salve, esiste uno script html, java o altro che permette di visualizzare gli utenti on line???
Grazie mille

[maximum]

Se intendi il numero degli utenti collegati, devi usare il global.asa, così:

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">

Sub Application_OnStart
  'Imposta a 0 il numero di utenti quando parte il servizio server
  Application("ActiveUsers") = 0
  'Nuovo
  Application("Users") = "" 
End Sub

Sub Session_OnStart
  '15 minuti di timeout
  Session.Timeout = 15
  'Inizia la sessione
  Session("Start") = Now
  'Incremento il numero di utenti all'inizio di una nuova sessione
  Application.Lock
  Application("ActiveUsers") = Application("ActiveUsers") + 1
  Application.UnLock
End Sub

Sub Session_OnEnd
  'Decremento il numero di utenti alla fine di ogni sessione
  Application.Lock
  Application("ActiveUsers") = Application("ActiveUsers") - 1
  Application.UnLock

End Sub

</SCRIPT>

Ma la pagina che richiama l'application deve essere .asp e richiamare il tutto così:

<%=Application("ActiveUsers") %>

Se usi pagine statiche HTML, non puoi ottenere la funzionalità.