Slide img e classe ScaleSquare (and80)

[micio1980]

Ciao a tutti,
ho copiato lo script di and80 per realizzare una slide show per viasualizza img presenti in una cartella:
http://www.v2online.it/articoli/scalesquare_howto.html
Funziona benissimo.
Ma adesso, visto sempre and80, vorrei che la transazione delle img apparisse, invece che con l'effeto fade, con questo altro effetto di and80
http://www.v2online.it/classes/scaleSquare_class.html
Come e dove devo modivicare l'AS di and80.
Ho già scaricato la classe ScaleSquare ma non ho capito come inserirla.

Ciao e grazie

[gobbo89]

- Crea una cartella img contenente le tue immagini, chiamate 1.jpg, 2.jpg.....
- Apri un nuovo documento flash ed incolla questo codice:

import mx.transitions.easing.*;
var slideShow:Function = function (target:MovieClip, shifting:Number, xSections, ySections, random, ease) {
	var mclo:MovieClipLoader = new MovieClipLoader();
	var mcli:Object = new Object();
	var index:Number = 1;
	mcli.onLoadProgress = function(target:MovieClip, lbytes:Number, tbytes:Number) {
		trace("Caricamento..."+Math.floor((lbytes/tbytes)*100)+"%");
	};
	mcli.onLoadError = function(target:MovieClip, errorCode:String) {
		if (errorCode == "URLNotFound") {
			slideShow(target, shifting, xSections, ySections, random, ease);
		}
	};
	mcli.onLoadInit = function(target:MovieClip):Void  {
		index++;
		target._alpha = 100;
		var scale:Object = new ScaleSquare(target, xSections, ySections, target._width, target._height, random, ease, 1);
		scale.onMotionFinished = function() {
			var a = setInterval(function () {
				clearInterval(a);
				var t:Object = new mx.transitions.Tween(target, "_alpha", None.easeNone, 100, 0, .5, true);
				t.onMotionFinished = function() {
					mclo.loadClip("img/"+index+".jpg", target);
				};
			}, shifting*1000);
		};
	};
	mclo.addListener(mcli);
	mclo.loadClip("img/"+index+".jpg", target);
};
var test:MovieClip = _level0.createEmptyMovieClip("test", 1);
// slideShow(nomeIstanzaClip, tempoPermanenzaFoto, numeroQuadratiniOrizzontali, numeroQuadratiniVerticali, comparsaQuadratiniRandom, tipoDiEase);
slideShow(test, 1, 5, 5, true, Back.easeOut);

- Salva il documento fla dove vuoi
- Nello stesso percorso del fla, copia il file ScaleSquare.as [quello della classe]
- Genera l'swf nello stesso percorso della cartella img

[micio1980]

OK grazie funziona.
Visto che sei così gentile ti pongo due domande:
La prima
io ho fatto il testo con tre img ma quando lo provo in flash con prova filmato, dopo la terza img mi dice
"file:///C|/Documents%20and%20Settings/micio80/Desktop/slide/img/4.jpg", cioè come se non trovasse la quarta img.
Come faccio a dargli che le img sono solo tre.

La seconda
se volessi che invece di avere una transizione con dei quadrati volessi avere una transizione con dei rettangoli in verticale, tipo i tabelloni pubblicitari che si vedono per le strade.

Ciao

[gobbo89]

Originariamente inviato da micio1980
OK grazie funziona.
Visto che sei così gentile ti pongo due domande:
La prima
io ho fatto il testo con tre img ma quando lo provo in flash con prova filmato, dopo la terza img mi dice
"file:///C|/Documents%20and%20Settings/micio80/Desktop/slide/img/4.jpg", cioè come se non trovasse la quarta img.
Come faccio a dargli che le img sono solo tre.

La seconda
se volessi che invece di avere una transizione con dei quadrati volessi avere una transizione con dei rettangoli in verticale, tipo i tabelloni pubblicitari che si vedono per le strade.

Ciao

Per la prima:
E' normale che dia quell'errore, ma lo slide ricomincia dalla prima immagine, quindi non vedo dov'è il problema...

Per la seconda:
sostituisci l'ultima riga di codice con:
slideShow(test, 1, 5, 1, true, Back.easeOut);
oppure
slideShow(test, 1, 5, 1, false, Back.easeOut);

... a seconda di quella che è più adatta al tuo scopo.

[micio1980]

CIAO,
mi va bene la tua dritta, anche se io intendevo dei retangoli che si girano in verticale (per spiegarmi meglio, una specie di carta da gioco che si gira mostrando il dorso)
CMQ
sei di grande aiuto

[gobbo89]

Originariamente inviato da micio1980
CIAO,
mi va bene la tua dritta, anche se io intendevo dei retangoli che si girano in verticale (per spiegarmi meglio, una specie di carta da gioco che si gira mostrando il dorso)
CMQ
sei di grande aiuto

Ok, puoi ottenere un effetto simile con
slideShow(test, 1, 1, 10, true, Back.easeOut);
o
slideShow(test, 1, 1, 10, false, Back.easeOut);

Però non è proprio uguale a quello dei cartelloni pubblicitari, anche perchè la classe non è stata pensata per riprodurre quell'effetto...