[vb6] listbox e combobox

[Rplus]

ho creato un form nel quale ci sono una listbox e una combobox..

al click sulla listbox viene pescata in una tabella il valore di una variabile,il cui valore viene scritto nella combobox..

durante l'esecuzione, però, ottengo un errore 13: "tipo nn corrispondete" in quanto quando clicko su un elemento della listbox dopo averne modificato uno sulla combo viene eseguita anke la procedura cboGio1notte_Click() dopo l'esecuzione di lstInf_Click(), senza ke io lo richieda..

questo è il codice del mio form:

Option Explicit
Const righe As Byte = 2
Dim i As Byte

Private Sub cboGio1notte_Click()
  tabella(lstInf.ListIndex + 1).primanotte = cboGio1notte.List(cboGio1notte.ListIndex)
  'tabella(lstInf.ListIndex + 1).primanotte = 8
End Sub

Private Sub Form_Load()
  For i = 1 To righe
    lstInf.AddItem (tabella(i).nome)
  Next i
End Sub

Private Sub lstInf_Click()
  cboGio1notte.Locked = False
  cboGio1notte.ListIndex = tabella(lstInf.ListIndex + 1).primanotte - 1
End Sub

Private Sub cmdOKButton_Click()
  Unload Me
End Sub

mentre la tabella è dichiarata in un modulo in questo modo:

Public Type tipopers
  nome As String * 20
  turno(1 To colonne) As Byte
  primanotte As Byte
End Type

come faccio per risolvere l'inconveniente?

[Rplus]

nessuno ha qualche idea sul perchè faccia così?

[tas]

Quando da codice si va a cambiare la proprietà ListIndex del ComboBox viene generato automaticamente l'evento Click del combobox. Potresti utilizzare un flag:

Option Explicit
Const righe As Byte = 2
Dim i As Byte
Dim flag As Boolean

Private Sub cboGio1notte_Click()
  If flag = False Then
    tabella(lstInf.ListIndex + 1).primanotte = cboGio1notte.List(cboGio1notte.ListIndex)
    'tabella(lstInf.ListIndex + 1).primanotte = 8
  End If
End Sub

Private Sub Form_Load()
  For i = 1 To righe
    lstInf.AddItem (tabella(i).nome)
  Next i
End Sub

Private Sub lstInf_Click()
  cboGio1notte.Locked = False
  flag = True
  cboGio1notte.ListIndex = tabella(lstInf.ListIndex + 1).primanotte - 1
  flag = False
End Sub

Private Sub cmdOKButton_Click()
  Unload Me
End Sub

[Rplus]

ah ecco cos'era..avevo questo dubbio infatti ma nn ne avevo trovato riscontro sul manuale..grazie 1000