Scia di trascinamento

[Marcel Gave]

non riesco a fare l'effetto di un elemento che mentre si sposta lascia dietro la sua scia o qualcosa di simile.
Qualcuno può aiutarmi?

[KillerWorm]

Ciao

La tua richiesta mi sembra troppo generica.

Che tipo di scia vorresti creare?
Hai qualche link di riferimento?
Hai già qualche idea?
Hai già provato ad elaborare qualcosa?
...

[Marcel Gave]

intendo come se si trascinasse la coda di se stesso e sfumasse pian piano fino a scomparire quando si ferma sull'ultimo keyframe

[KillerWorm]

Ho stilato una piccola funzione per l'occasione.
Basta inserirla nel primo frame del tuo filmato e richiamarla da dove e quando vuoi, passando i parametri indicati.

In fondo allo script c'è un esempio di come viene richiamata
con dei valori già impostati.
Fai delle prove imostando diversi valori a tuo piacimento.

scia = function (target, elementiScia, elementiDist, alphaInit, coda) {
	// 
	// \<><><><><><><><><><><><><><><><><><><><><><><><><>/
	// /         ..:: FADE WORM-TRAIL EFFECT ::..         \
	// \        effetto scia-verme in dissolvenza         /
	// /                                                  \
	// \              script by: KillerWorm               /
	// /<><><><><><><><><><><><><><><><><><><><><><><><><>\
	// 
	// Questo effetto è applicabile a qualsiasi istanza
	// Basterà richiamare la funzione scia impostandone
	// i parametri.
	// scia(target, numElementiScia, ritardoScia, alphaPrimoElemento, effettoCoda)
	// 
	var zTarget = target.getDepth();
	var parent = target._parent;
	elementiDist = Math.max(elementiDist, 1);
	duplicateMovieClip(target, "scia"+elementiScia, zTarget+elementiScia);
	var mcScia = eval(parent+".scia"+elementiScia);
	target.swapDepths(mcScia);
	mcScia.enabled = false;
	mcScia.mcScia._x += 50;
	alphaScia = target._alpha/(elementiScia+1)*elementiScia/100*alphaInit;
	alphaInit = 100;
	mcScia._alpha = alphaScia;
	mcScia.onEnterFrame = function() {
		var pointDif = Math.max(Math.abs(target._x-mcScia._x), Math.abs(target._y-mcScia._y));
		if (pointDif>1) {
			mcScia._visible = true;
			mcScia._x += (target._x-mcScia._x)/elementiDist;
			mcScia._y += (target._y-mcScia._y)/elementiDist;
			if (coda>0) {
				mcScia._xscale = target._xscale/(1+pointDif/1000*coda);
				mcScia._yscale = target._yscale/(1+pointDif/1000*coda);
			}
		} else if (mcScia._visible) {
			mcScia._visible = false;
			mcScia._x = target._x;
			mcScia._y = target._y;
		}
	};
	if (elementiScia>1) {
		scia(mcScia, elementiScia-1, elementiDist, alphaInit, coda);
	} else {
		delete scia;
	}
};
// (target, numElementiScia, ritardoScia, alphaPrimoElemento, effettoCoda)
// Esempio di impostazione dei parametri
scia(_root.istanza, 15, 3, 30, 5);