Una pagina in una stringa

[plumb]

come faccio in Asp ad inserire in una stringa il contenuto di una pagina? Ossia ho una pagina html e voglio che il suo contenuto venga salvato dentro una variabile. Come faccio?

[weppos]

Con l'oggetto File System Object leggi il contenuto del file e lo assegni ad una variabile.

[plumb]

Qual'è il codice per questa operazione?
mettiamo che la pagina sia ciao.asp e voglio inserire il suo contenuto dentro una variabile "stringa" che cosa devo fare?

[Mems]

Ma la pagina sta sullo stesso server, ovvero nello stesso sito?

[plumb]

si nella stessa cartella addirittura.

[Baol74]

Function ReadFile(Name)
	Dim fso,File
			Set Fso = Server.CreateObject("Scripting.FileSystemObject")
			On error resume next
			Set File = Fso.OpenTextFile(Server.MapPath(Name) , 1)
			ReadFile = File.ReadAll()
			If err.number<>0 then
				ReadFile = ""
			else
				File.Close()
			End if
			On error goto 0
			Set File = Nothing
			Set Fso = Nothing
End Function

Variabile = ReadFile("NomeFile.Ext")

[plumb]

GRAZIE Baol74

[Mems]

<%
pagina = "\public\pagina.html"
set fso = server.createObject("scripting.fileSystemObject")
if fso.fileExists(server.mapPath(pagina)) then
set file = fso.openTextFile(server.mapPath(pagina),1)
content = file.readAll
set file = nothing
else
content = "Nulla"
end if
set fso = nothing
response.write content
%>

[studioerrico]

Una domanda e se il file fosse su un altro server?

[maxolino]

strURL = "http://www.pagina_da_cui_prendere_il_codice"
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
objXMLHTTP.Open "GET", StrURL, false
objXMLHTTP.Send
strPagina = CStr(objXMLHTTP.ResponseText)
Set objXMLHTTP = Nothing

nella variabile strPagina ottieni il codice