[PILLOLA] Preload di dati caricati dinamicamente dal server

[Falcao]

una curiosità, ma a te quanto ci mette per completare il mio esempio?

no perchè a me con fastweb ci mette sui 560 ms... non male!

[andr3a]

Originariamente inviato da Falcao
una curiosità, ma a te quanto ci mette per completare il mio esempio?

no perchè a me con fastweb ci mette sui 560 ms... non male!

e chi l'ha mai provato

Classe LoadVars2()
... visto che vi voglio bene vi faccio gestire anche l' Interval

class LoadVars2 extends LoadVars {
	// andr3a [ www.3site.it ] [ 25/11/2003 ]
	// Thanks to: negatyve / Falcao / bubu77
	// from HTML.IT [ www.html.it ]
	private var myIntCheck:Number;
	function LoadVars2() {
		super();
	}
	public function load(url:String):Void {
		super.load(url);
		setMyInterval();
	}
	public function sendAndLoad(url:String, return_var:Object, method:String):Void {
		method = method != undefined ? method : "POST";
		super.sendAndLoad(url, return_var, method);
		setMyInterval();
	}
	public function stopLoading():Void {
		clearInterval(myIntCheck);
	}
	private function setMyInterval():Void {
		myIntCheck = setInterval(this, "checkCharge", 20);
	}
	private function checkCharge():Void {
		var loadedBytes:Number = getBytesLoaded() != undefined ? getBytesLoaded() : 0;
		var totalBytes:Number = getBytesTotal() != undefined ? getBytesTotal() : 0;
		if( this.onLoadProgress != undefined ) {
			this.onLoadProgress(loadedBytes, totalBytes);
		}
		if( loadedBytes > 0 && loadedBytes >= totalBytes) {
			clearInterval(myIntCheck);
		}
	}
}

Cosa e' cambiato ??
avete solo un metodo in piu' che vi permette di stoppare l' intervallo che cerca dati da macinare


Esempio:

var serverbytes = new LoadVars2();
serverbytes.onLoad = function(success) {
	if(success) {
		trace("____________________________________");
		trace("Caricati: " + this.getBytesLoaded());
		trace("Totali: " + this.getBytesTotal());
	}
	else {
		trace("Errore!");
		this.stopLoading();
	}
}
serverbytes.onLoadProgress = function(loadedBytes, totalBytes) {
	trace(loadedBytes + " - " + totalBytes);
}
serverbytes.load("http://miosito/miofile.php");

@ falcao
io e te semo come nVidia e ATI, se non c'eravamo noi non c'erano pillole e concorrenza

[Falcao]

Originariamente inviato da andr3a
e chi l'ha mai provato

dai il link a inizio pagina non fare il

[Falcao]

Originariamente inviato da andr3a
[ leggiti la mia pillola su MovieClipLoader, se la Macromedia inventa un metodo onLoadProgress per fare i preloads un motivo ci sara' ... :quipy: ]

Si l'hanno creata per i che non sapevano farsela da soli o che addirittura non sapevano farsi i preload... un modo per rendere flash più accessibile a tutti i più

:quote:

[andr3a]

Originariamente inviato da Falcao
Si l'hanno creata per i che non sapevano farsela da soli o che addirittura non sapevano farsi i preload... un modo per rendere flash più accessibile a tutti i più

stai incriminando gli scarsi ... chi e' lo sborone adesso ??? :gren:



P.S. 10 a 1 che per altri 12 mesi leggerai lostesso onEnterFrame nei preload di JPG e/o SWF ???
[ non parlo di chi continuera' ad usare MX ... ]

[Falcao]

cmq io preferisco MX ! o meglio anche se utilizzassi MX2004 ma non lo faccio utilizzerei AS 1.0 è più flashato!

Io ultimamente gli onEnterFrame li uso davvero pochino... diciamo quasi per niente infatti soprattutto programmando ad oggetti conviente utilizzare i setInterval con la quale si possono creare anche animazioni regolate dal tempo ad esempio e non dal framerate!

cioè vai da qui a lì in 1sec non in 10 frame! è tutto più preciso!

cmq a parte questo ho notato che è proprio la strada giusta in flash per fare tutto ciò che ci pare anche nel tempo senza essere vincolati ai movieClip o a quant'altro! vedi la classe che ti ho spedito ieri!

[andr3a]

Originariamente inviato da Falcao
cmq io preferisco MX ! o meglio anche se utilizzassi MX2004 ma non lo faccio utilizzerei AS 1.0 è più flashato!

Io ultimamente gli onEnterFrame li uso davvero pochino... diciamo quasi per niente infatti soprattutto programmando ad oggetti conviente utilizzare i setInterval con la quale si possono creare anche animazioni regolate dal tempo ad esempio e non dal framerate!

cioè vai da qui a lì in 1sec non in 10 frame! è tutto più preciso!

cmq a parte questo ho notato che è proprio la strada giusta in flash per fare tutto ciò che ci pare anche nel tempo senza essere vincolati ai movieClip o a quant'altro! vedi la classe che ti ho spedito ieri!

e' vero che sei piu' preciso in setInterval, ma considera che un semplice script come questo:

stop();
this.createEmptyMovieClip("quadrato", 1);
with(this["quadrato"]) {
	lineStyle( 1, 0xABABAB, 100 );
	moveTo( 10, 10 );
	beginFill(0xEFEFEF, 60);
	lineTo( 50, 10 ); 
	lineTo( 50, 50 );
	lineTo( 10, 50 );
	lineTo( 10, 10 );
	endFill();
}
function myMove(obj:MovieClip):Void {
	if( obj.startTime == undefined ) {
		obj.startTime = getTimer();
	}
	obj._x += 1;
	if(obj._x >= ( Stage.width - obj._width - 10 ) ) {
		clearInterval(myInt);
		trace("Arrivato!");
		var timeElapsed:Number = Math.round( ( getTimer() - obj.startTime ) / 1000 );
		trace("Tempo di esecuzione: " + timeElapsed );
	}
}
var myInt:Number = setInterval(myMove, 20, this["quadrato"]);

non gira allo stesso modo su un documento a 50 FPS piuttosto che 12 [ parlo oltre che del moto, dei secondi trascorsi ] ...

diciamo che onEnterFrame ha i suoi vantaggi pratici, semplice da utilizzare e semplice da gestire e/o fermare , pero' scrivere col setInterval come idea di base non e' affatto sbagliata, meno vincoli e piu' elasticita' ...

... ao' falcao, va a finire che siamo d'accordo su qualcosa

[Falcao]

Originariamente inviato da andr3a
e' vero che sei piu' preciso in setInterval, ma considera che un semplice script come questo:
.....
non gira allo stesso modo su un documento a 50 FPS piuttosto che 12 [ parlo oltre che del moto, dei secondi trascorsi ] ...

... ao' falcao, va a finire che siamo d'accordo su qualcosa

no in realtà l'animazione dura lo stesso tempo invece è solo più fluida se aumenti il framerate, è proprio quello che ti dicevo io!

Per emulare cmq un onEnterFrame basta che settyi l'intervallo in base al framerate e diventa cmq migliore! perchè è più facile da stoppare? poi eliminando un onEnterFrame tu elimini tutte le eventuali istruzioni di un clip... gestendo il moto col setInterval invece stopperesti solo il moto! (vedi sempre la mia classe)

Ancora non siamo molto d'accordo...

[andr3a]

Originariamente inviato da Falcao
no in realtà l'animazione dura lo stesso tempo invece è solo più fluida se aumenti il framerate, è proprio quello che ti dicevo io! ...

te la pazienza non ce l'hai vero ??? :quipy:

... prova ad aspettare che arrivi fino in fondo con 12 fps, poi metti a 50 e ripeti l'esperimento

Originariamente inviato da Falcao
Ancora non siamo molto d'accordo...

[Falcao]

Originariamente inviato da andr3a
te la pazienza non ce l'hai vero ??? :quipy:

... prova ad aspettare che arrivi fino in fondo con 12 fps, poi metti a 50 e ripeti l'esperimento

a me da sempre 23sec sia con 12 che con 50 che con 80 che con 120... del resto mi sembra abbastanza logico se tu effettui uno spostamento ogni tot ms non può dipendere dal framerate! il framerate ti da la fluidità del moto e basta!