[dos e batch] inserire valori a riga di comando

[maremma]

ciao a tutti devo fare un batch che una volta lanciato, co9mpare un menu e se scelgo una certa opzione faccio un echo e chiedo all'utente di inserire un parametro a riga di comando, che passo ad un altro batch....come faccio???
Grazie

[$$$]

@echo off
@cls

if "%OS%" == "Windows_NT" goto selezione
echo Questo programma richiede un sistema operativo della famiglia NT.
goto fine

:selezione
echo.
echo Digita 4 per avviare il programma, 5 per uscire, le altre scoprile.
echo.
echo 1) scelta #1
echo 2) scelta #2
echo 3) scelta #3
echo 4) scelta #4
echo 5) scelta #5
echo.

set /p SCELTA=Scegli: 

if "%SCELTA%" gtr "5" goto invalido
if "%SCELTA%" lss "0" goto invalido
goto sel%SCELTA%

:sel1
echo.
echo Bravo hai scelto #1: adesso morirai.
goto fine

:sel2
echo.
echo Scegliendo #2 formattero' il sistema.
goto fine

:sel3
echo.
echo Scelta buona la numero #3, ma non ci siamo.
goto fine

:sel4
echo.
echo Azzeccato: con la #4 avvieremo un programma ma ci serve la linea di comando.
set /p CMD4BAT=Digita la linea di comando: 
echo Grazie... Attendi l'avvio di ALTROBATCH.BAT
call ALTROBATCH.BAT %CMD4BAT%
goto fine

:sel5
echo.
echo OK. Programma finito premendo #5.
goto fine

:invalido
echo Errore: scelta non valida, prova ancora.
goto selezione

:fine

vista la complessita' del bat puo lavorare SOLO in
ambienti della famiglia NT.

ciao