Funzione vibra

[Graboid]

Sto cercando di costruire una funzione che associata ad un pulsante faccia tremare e cambiare gli alpha di un clip.
Deve farlo ogni 50 ms per 1 secondo.

Ecco il mio codice:

function vibra() {

tempo=getTimer();
i=50;
while (j<999999999) {
if(getTimer()<tempo+i){
_root.mvib._x +=random(7)-7;
_root.mvib._y +=random(7)-7;
_root.mvib._alpha = 100-random(50);
trace(_root.mvib._x);
trace(_root.mvib._alpha);
i=i+50;}
}
_root.mvib._x=30;
_root.mvib._y=140;
_root.mvib._alpha=100;
}

Perche' non succede niente?

[negatyve]

A parte che sarebbe:

 while (i<999999999) {

prova così:

function vibra()
{
	clearInterval(vibraID);
	timer = getTimer();
	_root.mvib._x = 30;
	_root.mvib._y = 140;
	_root.mvib._alpha = 100;
	vibraID = setInterval(_vibra, 50);
}
function _vibra()
{
	if(getTimer() - timer > 1000)clearInterval(vibraID);
	_root.mvib._x += random(7)-7;
	_root.mvib._y += random(7)-7;
	_root.mvib._alpha = 100-random(50);
}

[Graboid]

Hai ragione per la "j" ma ho distrattamente postato codice sporcato o meglio mal pulito da altri tentativi.

Provero' in tutti e due i modi che mi hai suggerito dopo aver studiato clearinterval e setinterval che proprio non conosco.

Grazie

[Graboid]

La prima no.

La seconda quasi,funziona ma una volta sola: io ho bisogno che le x e le y cambino ogni 50ms per un secondo.

Ciao

[negatyve]

Aspetta, le due funzioni vanno usate insieme:

function vibra()
{
	clearInterval(vibraID);
	timer = getTimer();
	_root.mvib._x = 30;
	_root.mvib._y = 140;
	_root.mvib._alpha = 100;
	vibraID = setInterval(_vibra, 50);
}
function _vibra()
{
	if(getTimer() - timer > 1000)clearInterval(vibraID);
	_root.mvib._x += random(7)-7;
	_root.mvib._y += random(7)-7;
	_root.mvib._alpha = 100-random(50);
}
vibra();

[Graboid]

Eccezzionale!

Mi manca solo che alla fine mi riporti in questo stato

_root.mvib._x = 34;
_root.mvib._y = 140;
_root.mvib._alpha=100;



Ma ... uhm ... come funziona?

Se per caso dovessi avere 2 min liberi.... 2 righette di commento....


Se no non importa


Ciao e grazie mille

[negatyve]

// funzione richiamata dall'utente
function vibra()
{
	// viene resettato l'intervallo
	clearInterval(vibraID);
	// viene salvato il numero di millisecondi
	// dall'inizio del filmato nella variabile timer
	timer = getTimer();
	// viene invocata la funzione "ripristina",
	// per resettare la posizione del movieclip
	ripristina();
	// viene reimpostato l'intervallo, perchè
	// chiami la funzione _vibra ogni 50 ms
	vibraID = setInterval(_vibra, 50);
}
// funzione richiamata da "vibra"
function _vibra()
{
	// verifica se è passato un secondo
	if(getTimer() - timer > 1000){
		// in caso affermativo, resetta l'intervallo
		clearInterval(vibraID);
		// resetta la posizione del movieclip
		ripristina();
	} else {
		// altrimenti...
		_root.mvib._x += random(7)-7;
		_root.mvib._y += random(7)-7;
		_root.mvib._alpha = 100-random(50);
	}
}
function ripristina()
{
	_root.mvib._x = 30;
	_root.mvib._y = 140;
	_root.mvib._alpha = 100;
}
vibra();

[Graboid]

[Graboid]

Ultima cosa. Lo giuro!
Ho provato a modificare la funzione perche' mi prenda un parametro in modo da poter specificare a che clip applicarla quando la richiamo ma non ci sono riuscito.

Io vorrei chiamarla cosi' :

vibra(percorsodelclip);

[GunraY]

function vibra(obb)
{
clearInterval(vibraID);
timer = getTimer();
obb._x = 30;
obb._y = 140;
obb._alpha = 100;
vibraID = setInterval(_vibra, 50,obb);
}
function _vibra(obb)
{
if(getTimer() - timer > 1000)clearInterval(vibraID);
obb._x += random(7)-7;
obb._y += random(7)-7;
obb._alpha = 100-random(50);
}
vibra(_root.mvib);