Separare in 2 variabili nomi file ed estensioni

[selidori]

Chiedo innanzitutto scusa per la banalità della richiesta.
Ho anche cercato di usare la ricerca del forum ma mi restituisce una pagina bianca senza risultati con entrambi i browser più noti.

Arrivo al dunque, sono uno (scarso) programmatore php e devo mettere mano in uno script asp. Questo visualizza semplicemente un elenco di file che legge dalla sua directory e li stampa a schermo.
Ecco il mio problema: devo visualizzare anche il nome del file senza estensione e poi sostituire l'estensione del file con un testo alternativo (del tipo se JPG->IMMAGINE se MPG->FILMATO ecc).
Ho provato in vari modi con i vari Mid, LEFT, RIGHT ecc ma questi vogliono un numero di caratteri da prendere. OK per le estensioni (gli ultimi 4 caratteri a destra) ma come ricavare il nome file visto che questi ha una lunghezza variabile?
Insomma una vera banalità, lo so, ma da non conoscitore dell'ambiente e per solo questa cosina forse faccio prima a chiedere qua al volo piuttosto che passare un pomeriggio a studiare ASP per questa scemenza.

Grazie e scusate ancora

[saltodifondi]

Usa queste due funzioni per avere nome del file ed estensione

Function get_estensione(nome_file)
	if instr(nome_file,".") > 0 then
		'il file ha estensione
		arr_appoggio = split(nome_file,".")
		get_estensione = arr_appoggio(ubound(arr_appoggio))
	else
		'il file non ha estensione
		get_estensione = ""
	end if
end function

Function get_nome(nome_file)
	if instr(nome_file,".") > 0 then
		arr_appoggio = split(nome_file,".")
		for i = 0 to ubound(arr_appoggio) - 1
			 out = out & "." & arr_appoggio(i)
		next
		out = right(out,len(out)-1)
	else
		out = nome_file
	end if
	get_nome = out
end function

'TEST

f1 = "nome"
f2 = "nome.txt"
f3 = "nome.cognome.txt"

response.write(f1 & ": Nome=" & get_nome(f1) & ", Ext=" & get_estensione(f1) & "
")
response.write(f2 & ": Nome=" & get_nome(f2) & ", Ext=" & get_estensione(f2) & "
")
response.write(f3 & ": Nome=" & get_nome(f3) & ", Ext=" & get_estensione(f3) & "
")