Originariamente inviato da pazienza
Non so fare un convertitore.
codice:
Option Explicit
Private Type NewMyFile
nome As String
frase As String
nascita As String
Text1 As String
Text2 As String
Text3 As String
Text4 As String
Text21 As String
End Type
Private Type OldMyFile
nome As String
frase As String
nascita As String
Text1 As String
Text2 As String
Text3 As String
Text4 As String
End Type
Public Function LoadOldFile(ByVal FileName As String) As OldMyFile
Dim file As Long
file = FreeFile
Open FileName For Binary Access Read As #file
Get #file, , LoadOldFile
Close #file
End Function
Public Sub SaveNewFile(ByVal FileName As String, ByRef NMF As NewMyFile)
Dim file As Long
file = FreeFile
Open FileName For Binary Access Write As #file
Put #file, , NMF
Close #file
End Sub
Public Function OldMF2NewMF(ByRef OldMF As OldMyFile) As NewMyFile
With OldMF2NewMF
.nome = OldMF.nome
.frase = OldMF.frase
.nascita = OldMF.nascita
.Text1 = OldMF.Text1
.Text2 = OldMF.Text2
.Text3 = OldMF.Text3
.Text4 = OldMF.Text4
.Text21 = ""
End With
End Function
Public Sub ConvertFile(ByVal OldFileName As String, ByVal NewFileName As String)
SaveNewFile NewFileName, OldMF2NewMF(LoadOldFile(OldFileName))
End Sub
Per convertire un file dalla vecchia versione alla nuova richiama ConvertFile passando come primo argomento percorso e nome del file in vecchio formato e come secondo percorso e nome file del file in nuovo formato da creare. Correda il tutto con un form o qualunque altra cosa che permetta di specificare all'utente che file convertire (o anche meglio, permettendogli di selezionare intere cartelle) e con un po' di gestione degli errori.
P.S.: non ho provato il codice, ma dovrebbe funzionare.
P.P.S.: andiamo bene... 
---EDIT---
Corretto qualche errore derivante dalle buone abitudini apprese con VB.NET...
Rispondi quotando
]
