mc riflesso

[and80]

quella non era una classe, erano un paio di funzioni :stordita:

l'ho trasformata in classe:

import flash.display.BitmapData;
class Mirror {
    private var __t:MovieClip;
    private var __d:Number;
    private var __a:Number;
    private var __i:Number;
    private var __v:Number;
    private var __w:Number;
    private var __h:Number;
    private var __m:MovieClip;
    private var __tmp:MovieClip;
    function Mirror (t:MovieClip, d:Number, a:Number, i:Number) {
        __t = t;
        __d = d;
        __a = a;
        __i = i;
        __v = Number(getVersion().split(",").join("").split(" ").join("").split("WIN").join("").substr(0, 1));
        __init__();
    }
    private function __init__ () {
        __w = __t._width;
        __h = __t._height;
        __tmp = __t._parent.createEmptyMovieClip('tmp', __t._parent.getNextHighestDepth());
        if (__v >= 8) {
            var t1 = __tmp.createEmptyMovieClip("t1",1);
            var t2 = __mask__();
            __tmp.b = new BitmapData(__w, __h, true, 0x00000000);
            __tmp.b.draw(__t);
            t1.attachBitmap(__tmp.b, 1);
            t1.cacheAsBitmap = t2.cacheAsBitmap = true;
            t1.setMask(t2);
            __m = __t._parent.createEmptyMovieClip("reflection", __t._parent.getNextHighestDepth());
            var b:BitmapData = new BitmapData(__w, __h, true, 0x00000000);
            b.draw(__tmp);
            __m.attachBitmap(b,1);
            __tmp.removeMovieClip();
            __m._yscale = -100;
            __m._x = __t._x;
            __m._y = (__t._y+__h*2)+__d;
        }
    }
    private function __mask__():MovieClip {
        var t = __tmp.createEmptyMovieClip("t2", 2);
        var matrix = {matrixType:"box", x:0, y:0, w:__w, h:__h, r:(90/180)*Math.PI};
        t.beginGradientFill("linear", [0, 0], [__a, 0], [0, 255], matrix);
        t.moveTo(0, 0);
        t.lineTo(__w, 0);
        t.lineTo(__w, __h);
        t.lineTo(0, __h);
        t.lineTo(0, 0);
        t.endFill();
        t._x = __w;
        t._y = __h;
        t._yscale = __i;
        t._rotation = 180;
        return t;
    }
    public function get mirrorClip ():MovieClip {
        return __m;
    }
} 

utile se non vuoi avere la dichiarazione delle funzioni nel codice e poi funziona con il new come le altre classi

questo codice lo copi in un nuovo documento AS vuoto e lo salvi nella stessa cartella del fla in cui intendi usarlo con nome "Mirror.as"

poi al posto di richiamare una funzione sul tuo codice, fai:

var r:Mirror = new Mirror(prova, 30, 50, 20); 

[edit] c'è solo una limitazione... il ridisegno che permette la creazione del riflesso avviene solo dalle coordinate 0,0 del contenuto del clip specchiato, quindi se ad esempio hai un oggetto dentro a clip spostato a -100,-100 viene disegnata solo la parte a coordinate "positive"

[gobbo89]

Uh, and penso ti sia scappato un copia incolla nella linea 44 della classe.

[and80]

Originariamente inviato da gobbo89
Uh, and penso ti sia scappato un copia incolla nella linea 44 della classe.

:ciauz:

ho corretto...
è il forum che ha preso la sequenza :( e l'hai trasformata in
poi quando si trova dentro il tag [php*] non viene trasformata in immagine, ma appare il codice di incorporamento dell'immagine

[slay]

ok perfetto ...

[slay]

scusa ancora un problema

var spazio:Number = 170;
var kl:Number = parsed.length;
var k:Number = 0;
    // PRELOAD IMG ////////////////////////////////////////////// 
    var mcLoad:MovieClipLoader = new MovieClipLoader(); 
    var obj23 = new Object() 
    //target e il clip attuale che viene processato che sartebbe mc.imgin_mc
        obj23.onLoadProgress = function(target, bytesLoaded, bytesTotal){ 
        target._parent.enabled = false;
        var percentuale:Number = Math.floor((bytesLoaded/bytesTotal)*100); 
        target._parent.perc.perc = percentuale +  " %"; 
            if (percentuale == 100) { 
                target._parent.perc._visible = false;
                target._parent.enabled = true;
        } 
    } 
// definisce altezza e larghezza delle thumb prima del caricamento
obj23.onLoadInit = function(target) { 
    target._y = - target._height;
    target._x = - target._parent._width/2; 
    
    target._parent.lung_or = target._parent._height
    target._parent.lung_mod = target._parent.lung_or + 30
    
    target._parent.larg_or = target._parent._width
    target._parent.larg_mod = target._parent.larg_or + 30
    
    target._parent.y_or = target._parent._y
    target._parent.y_mod = target._parent.y_or + 20
    
    
    // RICHIAMA LA CLASSE MIRROS.AS PER RIFLETTE L'MC RIFLESSO
    var r:Mirror = new Mirror(target, 3, 40, 40);

    
    target.onRollOver = function() {
    
    var ___TWEENtop2:Tween = new Tween(this._parent, "_width", Strong.easeOut, this._parent.larg_or, this._parent.larg_mod, 15, false);
    var ___TWEENtop3:Tween = new Tween(this._parent, "_height", Strong.easeOut, this._parent.lung_or, this._parent.lung_mod, 15, false);
    var ___TWEENtop4:Tween = new Tween(this._parent, "_y", Strong.easeOut, this._parent.y_or, this._parent.y_mod, 15, false);
    trace(this._parent.lung_or)
    }
    
    target.onRollOut = function() {
    var ___TWEENtop5:Tween = new Tween(this._parent, "_width", Strong.easeOut, this._parent.larg_mod, this._parent.larg_or, 15, false);
    var ___TWEENtop6:Tween = new Tween(this._parent, "_height", Strong.easeOut, this._parent.lung_mod, this._parent.lung_or, 15, false);
    var ___TWEENtop7:Tween = new Tween(this._parent, "_y", Strong.easeOut, this._parent.y_mod, this._parent.y_or, 15, false);

    }
    
    
}
mcLoad.addListener(obj23); 
// FINE PRELOAD ////////////////////////////////////////////////////////////


while (k<kl) {
    var name:String = "immagine" + k + "_mc";
    immagine_mc.duplicateMovieClip(name, k);
    mc = eval([name])
    mc._x = (mc._x) + (k * spazio);
    mc.imgpic = parsed[k].imgpic
    mcLoad.loadClip("gallery/" + mc.imgpic, mc.imgin_mc);

    
    
++k
    } 

praticamente quando vado sopra con il mouse voglio ingrandire il clip e fin qui tutto ok il problema mi si presente in questa riga

var ___TWEENtop3:Tween = new Tween(this._parent, "_height", Strong.easeOut, this._parent.lung_or, this._parent.lung_mod, 15, false);

praticamente non mi ridimensiona giusta l'altezza nonostante il trace sia giusto trace(this._parent.lung_or) la lung_or è di 250 8è l'altezza della foto caricata) appena mi metto sopra con il mouse mi si rimpicciolisce di molto in teoria dovrebbe andare a 280 che è la lung_mod .. hai qualche consiglio?

[and80]

tutte le tween hanno this._parent, ma a cosa dovrebbe puntare?

[slay]

trace(this._parent) da _level0.body_mc.immagine2_mc
trace(target) o trace(this) da _level0.body_mc.immagine2_mc.imgin_mc

l'immagine viene caricata esternamente dentro a imgin_mc

missa che sto facendo un po' di confusione..

this._parent contiene il clip con l'immagine originale più il cli riflesso che si dovrebbe ingrandire al passaggio del mouse ._y e ._width funzionano ma height non funziona come dovrebbe ...

[slay]

vedi la terza img sono sopra con il mouse la larghezza e y mi vengono giuste ma l'altezza me la sfalsa completamente.. l'altezza dovrebbe essere come la prima immagine + 30 px

[slay]

ho risolto così:

target._parent.lung_or = (target._parent._height * 2) + 3
target._parent.lung_mod = target._parent.lung_or + 30


target._parent.lung_or sarebbe altezza dell'mc originale * 2 (perchè c'è l'mc riflesso) + 3 che sarebbe lo spazio tra l'mc originale e il riflesso ... oppure bastava mettere

target._parent.lung_or = target._parent._height
dopo
var r:Mirror = new Mirror(target, 3, 40, 40);

[and80]

ho visto meglio lo script e se ogni immagine2_mc contiene la giusta dimensione dentro la variabile lung_mod, non c'è spiegazione del perchè non funzioni :master: salvo che non si incartino le tween per via dei nomi duplicati...