inserire filmato esterno con loadMovie(): come fare?

[sidvizioso]

cmq sul movieclip vuoto ho scritto questo codice

onClipEvent(load) {
    contgallery.loadMovie("gallery.swf");
} 

se non inserisco onClipEvent mi darebbe errore

[ResianTaxidrive]

Beh si', la sintassi cambia a seconda di dove metti il codice.
Se metti sul frame principale ( non sul frame del contenitore o sul contenitore stesso):

loadMovie("gallery.swf",contGallery);

non serve l'onClipEvent(load)

Direi che potrebbe esserci qualcosa che non va nei percorsi all'interno della gallery, magari qualche riferimento a _root che una volta che sono inseriti in un altro swf non hanno lo stesso valore.

[sidvizioso]

questo è il codice sul frame principale che si trova in "gallery.swf"

//centro l'immagine 
_root.onEnterFrame = function() {
    if (_root.box.getBytesLoaded()>10 && _root.box.getBytesLoaded()>=_root.box.getBytesTotal()) {
        _root.box._x = Stage.width/2-(_root.box._width/2);
        _root.box._y = Stage.height/2-(_root.box._height/2);
    }
};
Stage.showMenu = false;
quality = "BEST"; 

questo invece è il codice in un frame del movieclip che si trova sempre dentro "gallery.swf"

// imposta a false se non vuoi la descrizione
descriptions = true;
// box descrizione invisibile
alert._visible = false;
// effetto ease
var ease = 5;
//imposto la scala della foto grande
_root.scala_x = 90;
_root.scala_y = 110;
//imposto la barra visibile
_root.barra_stato = "true";
_root.box.useHandCursor = false;
//leggo i dati XML
thumbs = new XML();
thumbs.ignoreWhite = true;
thumbs.load("dati.xml");
// qui inserire il percorso al file .XML
thumbs.onLoad = function() {
    root = this.firstChild;
    total = root.childNodes.length;
    displayNum = Number(root.childNodes[0].attributes.displayNum);
    separation = Number(root.childNodes[0].attributes.separation);
    //settings
    w = 60;
    h = 55;
    mask._width = displayNum*(w+separation);
    mask._height = h+30;
    forward._x = mask._width+20;
    forward._y = back._y=h/2;
    mcs = [];
    for (i=0; i<total; i++) {
        mcs.push(i);
        newThumb = thumbnailer.container.duplicateMovieClip("container"+i, i);
        with (newThumb) {
            _x = (w+separation)*i;
            preloader._x = w/2;
            preloader._y = h/2;
            shape._width = w;
            shape._height = h;
        }
        var image = root.childNodes[i].childNodes[0].firstChild.nodeValue;
        var image1 = root.childNodes[0].childNodes[0].firstChild.nodeValue;
        newThumb.image = root.childNodes[i].childNodes[0].firstChild.nodeValue;
        newThumb.desc = root.childNodes[i].childNodes[1].firstChild.nodeValue;
        newThumb.link = root.childNodes[i].childNodes[2].firstChild.nodeValue;
        loadMovie(image1, _root.box.foto_effetto);
        _root.box._xscale = _root.scala_x;
        // scalo la larghezza
        _root.box._yscale = _root.scala_y;
        // scalo l'altezza
        newThumb.onRelease();
        newThumb.cont.loadMovie(image);
        //carico le thumbs
        newThumb.cont2.loadMovie(image);
        //carico le thumbs e le scalo
        newThumb.cont._xscale = 8.2;
        // scalo la larghezza
        newThumb.cont._yscale = 12.2;
        // scalo l'altezza delle ombre associate alle immagini
        newThumb.cont2._xscale = newThumb.cont._xscale;
        newThumb.cont2._yscale = newThumb.cont._yscale;
        newThumb.onRelease = function() {
            loadMovie(this.image, _root.box.foto_effetto);
            // carico l'immagine nel clip effetto
            _root.box.play();
            // avvio il box
            _root.box._xscale = _root.scala_x;
            // scalo la larghezza
            _root.box._yscale = _root.scala_y;
            // scalo l'altezza
        };
        newThumb.onReleaseOutside = function() {
            this._xscale = 100;
            this._yscale = 100;
            this._y = this._y+10;
            this._x = this._x+5;
        };
        if (descriptions) {
            newThumb.onRollOver = function() {
                alert.desc = this.desc;
                alert._visible = true;
                this._xscale = 120;
                this._yscale = 120;
                this._y = this._y-10;
                this._x = this._x-5;
                this.swapDepths(9);
            };
            newThumb.onRollOut = function() {
                alert._visible = false;
                this._xscale = 100;
                this._yscale = 100;
                this._y = this._y+10;
                this._x = this._x+5;
            };
        }
    }
    //
    var offset = total-1;
    var dest = 0;
    var increment = w+separation;
    var ending = (total-displayNum)*(w+separation);
    var lastmc = total-1;
    var firstmc = 0;
    back.onRelease = function() {
        if (dest<0) {
            dest += increment;
        } else {
            first = mcs[0];
            for (k=0; k<total; k++) {
                mcs[k] = mcs[k+1];
            }
            mcs[total-1] = first;
            thumbnailer["container"+lastmc]._x = -(w+separation);
            firstmc = lastmc;
            //check whos new lastmc
            for (k=0; k<total; k++) {
                if (mcs[k] == (total-1)) {
                    lastmc = k;
                }
            }
        }
    };
    forward.onRelease = function() {
        if (dest>-ending) {
            dest -= increment;
        } else {
            last = mcs[total-1];
            for (k=1; k<total; k++) {
                mcs[total-k] = mcs[total-k-1];
            }
            mcs[0] = last;
            thumbnailer["container"+firstmc]._x = (displayNum)*(w+separation);
            lastmc = firstmc;
            //check whos new firstmc
            for (k=0; k<total; k++) {
                if (mcs[k] == 0) {
                    firstmc = k;
                }
            }
        }
    };
    //movement
    onEnterFrame = function () {
        for (j=0; j<total; j++) {
            thumbnailer["container"+j]._x += (dest+(mcs[j])*(w+separation)-thumbnailer["container"+j]._x)/ease;
        }
        alert._x = _xmouse;
        alert._y = _ymouse;
    };
}; 

[ResianTaxidrive]

Vedi che tu hai

loadMovie(this.image, _root.box.foto_effetto);

quel _root.box.foto_effetto è la chiave secondo me. In gallery l'oggetto box sta sulla root ma quando gallery lo metti in un altro swf la root non è più la stessa.

C'è un comando che qualcuno ha scritto poco tempo fa sul forum (ma adesso non mi ricordo qual è) per far sì che venga presa la root giusta.

[sidvizioso]

ma se faccio un'altra cosa?

se carico il tutto script compresi direttamente nel filmatoprincxipale quindi senza usare loadMovie potrebbe funzionare?

[ResianTaxidrive]

Prova a mettere nella linea temporale principale di gallery

this._lockroot = true;

[sidvizioso]

allora, funziona anche se hoscopeto che miero mangiato una lettera del nome istanza del movieclip vuoto ... cmq funziona anche senza l'ultimo codice che mi hai postato, ma con questo viene posizionato meglio.
ora rimane un problema, l'swf caricato non si trova perfettamente inposizione, cioèle thumbnails sono ok ma non si vede correttamente la foto ingrandita.

cmqlo script è questotanto per intenderci gallery

[sidvizioso]

ps = cmq ti ringrazio moltissimo, sei stato gentilissimo ma soprattuto mi sei stato di grandissimo aiuto!!



se ti servisse una mano su php/mysql/html/js o java chiedi pure

[ResianTaxidrive]

OK grazie per la disponibilità. Saluti da Jack!

ps. hai risolto il problema del posizionamento della foto ingrandita?

[sidvizioso]

sisisi , smanettando un pò alla fine ci sono riuscito


grazie ancora