addChild ed estensioni classi Video

[ascip]

guarda, il file fla è completamente bianco... ho solo impostato la main class... cmq appena posso salvo in versione cs3

[and80]

Ah, pensavo ci fosse qualcosa in libreria visto che nel codice richiami MyVideo che non trovo tra le classi.

[ascip]

il progetto ha i nomi diversi dal codice postato :-D era per un po' di chiarezza...

[and80]

Sì ho notato, comunque ottengo diversi errori in fase di compilazione, credo che sia un problema di "impilamento" sulle classi, infatti per come hai strutturato la cartella, il package della classe M2PVideo dovrebbe essere classes.video e così via. Come ti dicevo probabilmente non ottieni errore perchè il tuo progetto non è impostato in strict mode e gli errori vengono "soppressi".

[and80]

Ho difficoltà a comprendere la classe M2PVideo, in particolare non riesco a comprendere perchè tu faccia il try...finally

[ascip]

urca... devo controllare questo "strict mode"(non mi sembra di averlo attivato)... il try finally era per evitare delle eccezioni, che non ricordo al momento, e non mi interessava intercettarle....

[ascip]

però mi sembra strano che istanziando la classe M2PVideo nella classe Main funziona e da dentro un altro elemento no... comunque se a te da errore in compilazione molte altre spiegazioni non ci sono...

[ascip]

ho tolto lo strict mode (anche se non ricordo come mai l'avessi attivo)

il risultato non cambia.

Credo che il problema sia dovuto al fatto che il display manager non trovi il metodo grafico per costruire il video.. o qualcosa del genere...

sul tuo framework che tipo di errore in compilazione ti restituisce and80??

[and80]

Per capire meglio la cosa, sto ricostruendo le classi a mio modo semplificando alcuni passaggi che ora per questo problema non ci servono, così capisco cosa non va.

[and80]

Questo è quanto, ho messo le classi tutte sullo stesso livello, quindi non ci sono i percorsi, in ogni caso in questo modo a me funziona:

// Main.as
package {
    import flash.display.Sprite;
    import flash.events.Event;
    public class Main extends Sprite {
        public var loadingScene:LoadingScene;
        public var scene:Sprite;
        public function Main():void {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        private function init(e:Event = null):void {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            loadingScene = new LoadingScene(stage);
            scene = addChild(loadingScene.getScene()) as Sprite;
        }
    }
} 

//LoadingScene.as
package {
    import flash.display.Sprite;
    import flash.display.Stage;
    public class LoadingScene {
        private var S:Sprite;
        private var V:M2PVideo;
        public function LoadingScene(rif:Stage) {
            S = new Sprite();
            V = S.addChild(new M2PVideo(rif.stageWidth, rif.stageHeight)) as M2PVideo;
            V.play("http://www.helpexamples.com/flash/video/cuepoints.flv");
        }
        public function getScene ():Sprite {
            return S;
        }
    }
} 

//M2PVideo
package {
    import flash.events.AsyncErrorEvent;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    public class M2PVideo extends Video {
        private var NC:NetConnection;
        private var NS:NetStream;
        public function M2PVideo(w:int=320, h:int=240) {
            super (w, h);
            NC = new NetConnection();
            NC.connect(null);
            NS = new NetStream(NC);
            attachNetStream(NS);
            configureListeners();
        }
        public function play (flv:String):void {
            NS.play(flv);
        }
        private function configureListeners ():void {
            NC.addEventListener (NetStatusEvent.NET_STATUS, netStatusHandler);
            NC.addEventListener (SecurityErrorEvent.SECURITY_ERROR, function (evt:SecurityErrorEvent):void { /* ignore security error event */ });
            NS.addEventListener (NetStatusEvent.NET_STATUS, netStatusHandler);
            NS.addEventListener (AsyncErrorEvent.ASYNC_ERROR, function (evt:AsyncErrorEvent):void { /* ignore async error event */ } );
            NS.client = new M2PClient();
        }
        private function netStatusHandler (evt:NetStatusEvent):void {
            if (evt.info.code == "NetStream.Play.StreamNotFound") {
                dispatchEvent(evt);
            }
        }
    }
} 

//M2PClient
package  {
    public class M2PClient {
        public function onMetaData(info:Object):void {
            trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
        }
        public function onCuePoint(info:Object):void {
            trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
        }    
    }    
} 

Per il mio test non ho avuto bisogno di riportare le altre classi, e con queste funziona come dovrebbe.