Ciao.
Premetto che non ho mai nemmeno provato a scrivere una riga di DOS prima d'ora 
ma, giusto per schiribizzo, ho voluto vedere cosa sarei riuscito a mettere su in questo particolare caso.
Dopo varie capriole su gugol sono riuscito ad assiemare un coso 
Puoi provare a fare così:
- apri la cartella dei file che vuoi svuotare
- qui dentro, crea un file .bat (ad es: svuota_file.bat) e con un editor appiccicaci questa roba:
codice:
@echo off
title Svuota file
set "dir=.\"
:Init
cls
echo -- SVUOTA FILE --
echo -----------------
echo(
set contafile=0
for %%F in ("%dir%\*.*") do if not %%~nxF == %~nx0 set /a contafile+=1
if %contafile% == 0 (
echo - Non vedo file da svuotare o_O
echo(
pause>nul
goto EOF
)
echo - Ci sono %contafile% file da svuotare
echo(
:VuoiBackup
echo - Creare Backup prima di svuotare i file?
echo [S] (default) crea una cartella di backup con la copia dei file originali
echo [N] svuota direttamente i file
echo(
set /p backup=": "
echo(
if /i "%backup:~,1%" == "N" goto Svuota
:FaiBackup
echo - Creazione backup...
echo(
set nomedir=BACKUP(%date:/=-%@%time:~0,2%-%time:~3,2%-%time:~6,2%)
md "%nomedir%"
for %%F in ("%dir%\*.*") do if not %%~nxF == %~nx0 (
echo backuppato: %%~nxF
@copy "%%F" ".\%nomedir%\%%~nxF" >nul
)
echo(
:Svuota
echo - Svuotamento...
echo(
for %%F in ("%dir%\*.*") do if not %%~nxF == %~nx0 (
type NUL > %%~nxF
echo svuotato: %%~nxF
)
echo(
echo - Fatto!
echo(
pause>nul
- ora, doppio click sul file .bat, e il gioco è fatto (o, quantomeno, dovrebbe esserlo).
- se non serve più il file .bat, chiaramente puoi cestinarlo una volta conclusa l'operazione.
Il coso conterà i file da svuotare contenuti in quella cartella (dove risiede il .bat). Saranno considerati solo i file di tale cartella, escludendo quindi le sottocartelle e relativi altri file (così mi è parso di capire dalla richiesta in discussione). Anche il file .bat stesso sarà chiaramente escluso.
Nel coso ho messo anche la possibilità di creare una cartella di backup ('n si sa mai). Il backup viene eseguito di default. Se non lo si desidera basterà specificarlo (indicando "N") sulla domanda nel prompt.
Questa cartella sarà creata come sottocartella dentro la cartella in questione e avrà un nome del tipo BACKUP(24-09-2016@13-49-40), cioè con un relativo datetimestamp. Qui dentro saranno quindi create le copie dai file originali, prima di essere svuotati.
In fine sarà eseguito lo svuotamento. In sostanza vengono creati dei file di 0 byte con lo stesso nome di quelli presenti che saranno quindi sovrascritti.
Ora, a me funziona, per quanto ho potuto testare io sul mio pc, ma ovviamente non ho fatto grossi test e non ho alcuna garanzia che funzioni regolarmente da altre parti. Non ho nemmeno idea se il sistema tenti di bloccare l'esecuzione o il lancio stesso del file .bat; personalmente ho disattivato tali blocchi sul mio winzoz.
PS: usare con cautela. Nel caso di incidenti arrecati dall'uso del coso, io mi tolgo comunque fuori da ogni responsabilità 
Originariamente inviata da Vincent.Zeno
Permessi di invio
Rispondi quotando
