[VB6] Importare un file di testo

[Archangel333]

Originariamente inviato da oregon
Allora, se non ho capito male, ogni informazione che ti interessa e' posizionata su 14 righe di cui quelle significative sono le prime 3.
In queste 3, la prima e' sempre il nome della ditta da prendere tutto; la seconda inizia sempre con i 5 caratteri del CAP, segue citta', provincia e dopo un trattino (-) numero civico e separato da una virgola (,) l'indirizzo; la terza telefono e fax individuati dalle stringhe "tel:" e "fax:".

Tutte le altre righe non sono utili ...

Si,proprio così.

[oregon]

Allora, per esempio, questo codice inserito nell'evento click di un pulsante

Private Sub Command1_Click()
    Dim fh As Integer
    Dim sk As Integer
    Dim l As String
    Dim p As Long
    Dim v() As String
    
    fh = FreeFile
    
    Open "C:\File.txt" For Input As #fh
    
    Do While Not EOF(fh)
        Line Input #fh, l
        Debug.Print "DITTA: " & l
        
        Line Input #fh, l
        v = Split(l, "-")
        v(1) = Trim$(v(1))
        p = InStr(v(1), ",")
        Debug.Print "INDIRIZZO: " & Trim$(Mid$(v(1), p + 1)) & ", " & Left$(v(1), p - 1)
        Debug.Print "CAP: " & Left$(v(0), 5)
        Debug.Print "CITTA': " & Trim$(Mid$(v(0), 6))
        
        Line Input #fh, l
        v = Split(l, ":")
        Debug.Print "TEL: " & Replace(Left$(v(1), Len(v(1)) - 5), " ", "")
        Debug.Print "FAX: " & Replace(v(2), " ", "")
        
        Debug.Print
        For sk = 1 To 11
            Line Input #fh, l
        Next sk
    Loop
    
    Close #fh
End Sub

dovrebbe visualizzare le informazioni richieste nella finestra di debug. Ovviamente devi cambiare il nome e la posizione del file nella Open.